📄 admin_addmovie.asp

📁 本程序是一款比较完善的图书租赁系统
💻 ASP
字号:
<!--#include file="conn.asp"-->
<!--#include file="ChkErr.asp"-->
<!--#include file="ChkAdmin.asp"-->
<!--#include file="ChkSQL.asp"-->
<!--#include file="ResultMsg.asp"-->
<%
If Request("IsAdd")<>"" Then
	Dim MovieTitle,MovieContent,MovieImg
	Dim Director,Playactor,Issuer
	Dim TypeInfo,VideoStyle,Provider
	Dim Payment,MovieStatus,MovieRank
	
	'判断必要的输入是否存在
	If Request("MovieTitle")="" Then
		Response.Write GetErr(10)
		Response.End 
	End If
	
	'判断字符数量是否超出限制
	If Len(Request("MovieTitle"))>50 Or Len(Request("MovieImg"))>150 Or Len(Request("Director"))>100 Or Len(Request("Playactor"))>100 Then
		Response.Write GetErr(9)
		Response.End
	End If
	
	'过滤SQL字符
	MovieTitle=ChkSQL(Trim(Request("MovieTitle")))
	MovieContent=ChkSQL(Trim(Request("MovieContent")))
	MovieImg=ChkSQL(Trim(Request("MovieImg")))
	Director=ChkSQL(Trim(Request("Director")))
	Playactor=ChkSQL(Trim(Request("Playactor")))
	Issuer=ChkSQL(Trim(Request("Issuer")))
	
	'过滤其他输入
	If IsNumeric(Request("TypeInfo"))=False Then
		TypeInfo=1
	Else
		TypeInfo=Request("TypeInfo")
	End If
	If IsNumeric(Request("VideoStyle"))=False Then
		VideoStyle=1
	Else
		VideoStyle=Request("VideoStyle")
	End If
	If IsNumeric(Request("Provider"))=False Then
		Provider=1
	Else
		Provider=Request("Provider")
	End If
	If IsNumeric(Request("Payment"))=False Then
		Payment=1
	Else
		Payment=Request("Payment")
	End If
	If IsNumeric(Request("MovieRank"))=False Then
		MovieRank=3
	Else
		MovieRank=Request("MovieRank")
	End If
	Select Case Request("MovieStatus")
		Case "Stock"
			MovieStatus=2
		Case "Normal"
			MovieStatus=1
		Case Else
			MovieStatus=2
	End Select
	
	strSQL="INSERT INTO [VideoInfo] (VI_TI_ID_FN,VI_VS_ID_FN,VI_PMT_ID_FN,VI_PI_ID_FN,VI_Title_S,VI_Content_S,VI_Director_S,VI_Playactor_S,VI_Issuer_S,VI_Rank_N,VI_RentCount_N,VI_Count_N,VI_Status_N,VI_AddTime_D,VI_Img_S)"&_
		"VALUES("&TypeInfo&","&VideoStyle&","&Payment&","&Provider&",'"&MovieTitle&"','"&MovieContent&"','"&Director&"','"&Playactor&"','"&Issuer&"','"&MovieRank&"',0,0,'"&MovieStatus&"','"&Now()&"','"&MovieImg&"')"
	objConn.Execute(strSQL)
	Call ResultMsg("影片添加成功！")
	CloseDatabase
Else
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN"
"http://www.w3.org/TR/html4/loose.dtd">
<html>
<head>
<meta name=vs_targetSchema content="http://schemas.microsoft.com/intellisense/ie5">
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>添加新影片</title>
<link href="style.css" rel="stylesheet" type="text/css">
</head>
<body>
<form action=admin_addmovie.asp method=post>
<table class=tableborder1 align=center cellspacing=1 cellpadding=3 width=97% height=25% ID="Table1">
	<tr><th colspan=2 id=tabletitlelink height=25 style=font-weight:normal align=center>添加新影片</th></tr>
	<tr><td class=TableBody2 align=right width=15% >影片名称：<br>（不多于50字）</td><td class=TableBody1 align=left><input type=text maxlength=50 name=MovieTitle size=125></td></tr>
	<tr><td class=TableBody2 align=right width=15% >影片介绍：</td><td class=TableBody1 align=left><textarea cols=125 rows=5 name=MovieContent></textarea></td></tr>
	<tr><td class=TableBody2 align=right width=15% >影片图片：<br>（不多于150字）</td><td class=TableBody1 align=left><input type=text maxlength=150 name=MovieImg size=125></td></tr>
	<tr><td class=TableBody2 align=right width=15% >导演：<br>（不多于100字）</td><td class=TableBody1 align=left><input type=text maxlength=100 name=Director size=125></td></tr>
	<tr><td class=TableBody2 align=right width=15% >主要演员：<br>（不多于100字）</td><td class=TableBody1 align=left><input type=text maxlength=100 name=Playactor size=125></td></tr>
	<tr><td class=TableBody2 align=right width=15% >发行商：<br>（不多于200字）</td><td class=TableBody1 align=left><input type=text maxlength=200 name=Issuer size=125></td></tr>
	<tr><td class=TableBody2 align=right width=15% >影片介质：</td><td class=TableBody1 align=left>
	<%
	'读取影片介质信息供用户选择
	strSQL="SELECT * FROM [TypeInfo]"
	Set objRS=Server.CreateObject("ADODB.RecordSet")
	objRS.Open strSQL,objConn,1,3
	Response.Write "<select name=TypeInfo>"
	For i=1 To objRS.RecordCount
		Response.Write "<option value="&objRS("TI_ID_N")&">" &objRS("TI_Description_S")&"</option>"
		objRS.MoveNext
	Next
	Response.Write "</select>"
	objRS.Close
	%>
	</td></tr>
	<tr><td class=TableBody2 align=right width=15% >影片类型：</td><td class=TableBody1 align=left>
	<%
	'读取影片分类信息供用户选择
	strSQL="SELECT * FROM [VideoStyle]"
	Set objRS=Server.CreateObject("ADODB.RecordSet")
	objRS.Open strSQL,objConn,1,3
	Response.Write "<select name=VideoStyle>"
	For i=1 To objRS.RecordCount
		Response.Write "<option value="&objRS("VS_ID_N")&">" &objRS("VS_Description_S")&"</option>"
		objRS.MoveNext
	Next
	Response.Write "</select>"
	objRS.Close
	%>
	</td></tr>
	<tr><td class=TableBody2 align=right width=15% >供应商：</td><td class=TableBody1 align=left>
	<%
	'读取供应商信息供用户选择
	strSQL="SELECT * FROM [ProviderInfo]"
	Set objRS=Server.CreateObject("ADODB.RecordSet")
	objRS.Open strSQL,objConn,1,3
	Response.Write "<select name=Provider>"
	For i=1 To objRS.RecordCount
		Response.Write "<option value="&objRS("PI_ID_N")&">" &objRS("PI_Name_S")&"</option>"
		objRS.MoveNext
	Next
	Response.Write "</select>"
	objRS.Close
	%>
	</td></tr>
	<tr><td class=TableBody2 align=right width=15% >租价方案：</td><td class=TableBody1 align=left>
	<%
	'读取租价方案供用户选择
	strSQL="SELECT * FROM [Payment]"
	Set objRS=Server.CreateObject("ADODB.RecordSet")
	objRS.Open strSQL,objConn,1,3
	Response.Write "<select name=Payment>"
	For i=1 To objRS.RecordCount
		Response.Write "<option value="&objRS("PMT_ID_N")&">" &objRS("PMT_Description_S")&"</option>"
		objRS.MoveNext
	Next
	Response.Write "</select>"
	objRS.Close
	%>
	</td></tr>
	<tr><td class=TableBody2 align=right width=15% >影片状态：</td><td class=TableBody1 align=left><input type=radio name=MovieStatus value=Stock>进货中<input type=radio name=MovieStatus value=Normal checked>正常</td></tr>
	<tr><td class=TableBody2 align=right width=15% >影片评级：</td><td class=TableBody1 align=left>
		<select name=MovieRank><option>1</option><option>2</option><option>3</option><option>4</option><option>5</option></select>
	</td></tr>
	<tr><td class=TableBody2 align=center colspan=2><input type=submit value=提交>&nbsp;<input type=reset value=重写></td></tr>
</table>
<input type=hidden name=IsAdd value=Yes>
</form>
</body>
</html>
<%End If%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -