admin_listmovie.asp

本程序是一款比较完善的图书租赁系统

<!--#include file="conn.asp"-->
<!--#include file="ChkErr.asp"-->
<!--#include file="ChkAdmin.asp"-->
<!--#include file="ChkSQL.asp"-->
<!--#include file="ResultMsg.asp"-->
<%
Dim SearchCondition,SearchStr
Dim MovieLevel,LevelStatus,AsCondition
Dim SearchCondition2
Dim tmpTD,tmpMovieStatus
tmpTD="<td class=TableBody1 align=center width=11% >"

'获取查询条件
SearchStr=ChkSQL(Trim(Request("SearchStr")))
If IsNumeric(Request("MovieLevel"))=False Then
	MovieLevel=1
Else
	MovieLevel=Request("MovieLevel")
End If

'根据查询条件制定查询字符串
If SearchStr<>"" Then
	'若有主查询条件则应用
	Select Case Request("SearchCondition")
		Case "MovieTitle"
			strSQL="SELECT * FROM [VideoInfo] WHERE VI_Title_S LIKE '%"&SearchStr&"%'"
		Case "MovieContent"
			strSQL="SELECT * FROM [VideoInfo] WHERE VI_Content_S LIKE '%"&SearchStr&"%'"
		Case "Director"
			strSQL="SELECT * FROM [VideoInfo] WHERE VI_Director_S LIKE '%"&SearchStr&"%'"
		Case "Playactor"
			strSQL="SELECT * FROM [VideoInfo] WHERE VI_Playactor_S LIKE '%"&SearchStr&"%'"
		Case "Issuer"
			strSQL="SELECT * FROM [VideoInfo] WHERE VI_Issuer_S LIKE '%"&SearchStr&"%'"
		Case "MovieID"
			If IsNumeric(SearchStr) Then
				strSQL="SELECT * FROM [VideoInfo] WHERE VI_ID_N="&SearchStr
			Else
				Response.Write GetErr(11)
				Response.End
			End If
		Case Else
			strSQL="SELECT * FROM [VideoInfo] WHERE VI_Title_S LIKE '%"&SearchStr&"%'"
	End Select
Else
	'若无主查询条件则默认查询所有
	strSQL="SELECT * FROM [VideoInfo] WHERE VI_ID_N<>NULL "
End If

'附加查询条件
If Request("AsCondition")<>"" Then
	Select Case Request("LevelStatus")
		Case "up"
			strSQL=strSQL&" AND VI_Rank_N>="&MovieLevel
		Case "middle"
			strSQL=strSQL&" AND VI_Rank_N="&MovieLevel
		Case "down"
			strSQL=strSQL&" AND VI_Rank_N<="&MovieLevel
		Case Else
			strSQL=strSQL
	End Select
End If
If Request("AsCondition2")<>"" Then
	Select Case Request("SearchCondition2")
		Case "Stock"
			strSQL=strSQL&" AND VI_Status_N=2"
		Case "Rent"
			strSQL=strSQL&" AND VI_Status_N=3"
		Case "Booked"
			strSQL=strSQL&" AND VI_Status_N=4"
		Case Else
			strSQL=strSQL
	End Select
End If

'查找超期未还的影片
If Request("RentTimeout")<>"" Then
	strSQL="SELECT * FROM [VideoInfo],[Tenancy] WHERE VI_ID_N=TAC_VI_ID_FN AND TAC_Timeout_B=True AND TAC_EndTime_D IS NULL"
End If

Set objRS=Server.CreateObject("ADODB.RecordSet")
objRS.Open strSQL,objConn,1,3
objRS.PageSize=20

If objRS.BOF Or objRS.EOF Then
	'如果没有找到任何影片则输出信息
	Call ResultMsg("对不起，没有找到任何影片！")
	Response.End 
End If
Response.Write "<link href=style.css rel=stylesheet type=text/css>"
%>
<!--#include file="ChangePage.asp"-->
<%
Response.Write "<table class=tableborder1 align=center cellspacing=1 cellpadding=3 width=50% height=25% >"
Response.Write "<tr><th id=tabletitlelink height=25 style=font-weight:normal align=center colspan=9><b>电影列表（点击影片名可显示影片详细信息）</b></th></tr>"
Response.Write "<tr><td class=TableBody2 align=right colspan=9>"
'翻页
Call ChangePage("admin_listmovie.asp")
Response.Write "共<b>"&ObjRS.RecordCount&"</b>部电影</td></tr>"
Response.Write "<tr>"&tmpTD&"影片ID"&tmpTD&"影片名</td>"&tmpTD&"影片评级"&tmpTD&"导演"&tmpTD&"演员"&tmpTD&"发行商"&tmpTD&"状态</tr>"
For i=1 To objRS.PageSize
	'表头
	tmpMovieStatus=""
	Response.Write "<tr>"&tmpTD&objRS("VI_ID_N")&"</td>"&tmpTD&"<a href=modifyMovie.asp?id="&objRS("VI_ID_N")&">"&_
		objRS("VI_Title_S")&"</a></td>"&tmpTD&objRS("VI_Rank_N")&tmpTD&objRS("VI_Director_S")&_
		tmpTD&objRS("VI_Playactor_S")&tmpTD&objRS("VI_Issuer_S")&tmpTD
	'影片状态
	Select Case objRS("VI_Status_N")
		Case 1
			tmpMovieStatus="正常"
		Case 2
			tmpMovieStatus="进货中"
		Case 3
			tmpMovieStatus="已租出"
		Case 4
			tmpMovieStatus="已预订"
		Case Else
			tmpMovieStatus="未知"
	End Select
	Response.Write tmpMovieStatus&"</td></tr>"
	objRS.MoveNext
	If objRS.EOF Then Exit For
Next
Response.Write "</table>"
objRS.Close
Set objRS=Nothing
CloseDatabase
%>