剔出来的.txt

vb+sqlserver实现的人事管理系统

'1 Change_Id  Int 变动编号
Public Sub Add_DepartToTree(TreeView1 As TreeView, _
                           ByVal TmpKey As String)
  Dim Bh As Long
  Dim TmpNode As Node
  '当前选择结点的关键字
  Dim CurKey As String
  '临时数组
  Dim TmpArr_DepartName() As String
  Dim TmpArr_DepartId() As Long
  ReDim TmpArr_DepartName(0)
  ReDim TmpArr_DepartId(0)
  '从关键字中读取当前的部门编号
  Bh = Val(Right(TmpKey, Len(TmpKey) - 1))
  '获取当前部门信息
  MyDepart.GetInfo (Bh)
  '读取当前部门的下一级部门数据
  MyDepart.Load_Depart_ByUpper (Bh)
  '将下一级部门数据赋值到临时数组中
  i = 0
  Do While Arr_DepartName(i) <> ""
    ReDim Preserve TmpArr_DepartName(i + 1)
    TmpArr_DepartName(i) = Arr_DepartName(i)
    ReDim Preserve TmpArr_DepartId(i + 1)
    TmpArr_DepartId(i) = Arr_DepartId(i)
    i = i + 1
  Loop
  
  i = 0
  Do While TmpArr_DepartName(i) <> ""
    '生成对应的关键字，格式为“字母a”＋部门编号
    CurKey = "a" + Trim(Str(TmpArr_DepartId(i)))
    '如果当前部门有下一级部门,则显示文件夹图标
    If MyDepart.HaveSon(TmpArr_DepartId(i)) = True Then
      Set TmpNode = TreeView1.Nodes.Add(TmpKey, _
            tvwChild, CurKey, TmpArr_DepartName(i), 1, 3)
          
      TmpNode.ExpandedImage = 2
    '否则显示叶结点图标
    Else
      Set TmpNode = TreeView1.Nodes.Add(TmpKey, _
            tvwChild, CurKey, TmpArr_DepartName(i), 4, 5)
    End If
    'FocusDepartName、FocusDepartBh和FocusDepartKey分别表示希望选中的部门名称、编号和关键字
    If FocusDepartName <> "" And TmpArr_DepartName(i) = FocusDepartName Then
      TmpNode.Selected = True
      FocusDepartKey = CurKey
    End If
    If FocusDepartBh > 0 And TmpArr_DepartId(i) = FocusDepartBh Then
      TmpNode.Selected = True
      FocusDepartKey = CurKey
    End If
    If FocusDepartKey <> "" And CurKey = FocusDepartKey Then
      TmpNode.Selected = True
    End If
    '以当前部门为参数递归调用
    Call Add_DepartToTree(TreeView1, CurKey)
    i = i + 1
  Loop
End Sub