managehomework.asp

一套完整的学生课程管理系统

<!-- #include file="utility/checkTeacher.asp" -->

<%
	'****************************************
	'目的：			处理作业信息
	'开始时间：		2005-6-7 14:23
	'最后修改时间：	2005-6-7 14:23
	'编写人：		某某某
	'****************************************
	
	'定义相关变量
	dim actionType			'操作类型
	dim teacherID			'教师编号

	dim sql				
	dim rs
	
	'将URL中的值取出并赋给变量
	actionType = Trim(Request.QueryString("actionType"))
	
	'检查参数是否完整
	if(actionType = "") then
		Alert("参数丢失，拒绝操作！")
		GoBack()
		Response.end
	end if
	
	teacherID = Session("userID")
	
	'如果通过以上检查，则判断操作类型并执行对应操作
	Select case (actionType)
		case "addHomework": 	
			addHomework()			'布置新作业
		case "deleteHomework":	
			deleteHomework()		'删除已有作业
		case "dealStuHomework":
			dealStuHomework()		'处理学生提交的作业答案
	end Select
	
	'添加新的作业信息
	Sub addHomework()
		dim courseID
		dim homework
		
		courseID = Request.Form("courseID")
		homework = HtmlEncode2(Trim(Request.Form("homework")))
		
		'检查信息是否填充完整
		if(courseID = "" or homework = "")then
			Alert("信息填充不完整，操作失败！")
			GoBack()
			Response.End
		end if
			
		'判断该教师是否教授该课程
		sql = "select count(*) from course where "
		sql = sql & "tID = " & teacherID
		sql = sql & " and ID = " & courseID	
		
		set rs = ExecuteQuery(sql)

		if(rs(0) = 0) then
			Alert("课程编号非法，拒绝操作！")
			GoBack()
			Response.End
		end if
		
		rs.close()
		set rs = nothing
		
		'通过了所有验证才能添加作业信息
		sql = "insert into courseHomework (courseID,homework) "
		sql = sql & "values ( " & courseID & ",'" & homework & "')"
		ExecuteNonQuery(sql)
		Alert("作业添加成功，请继续其他操作！")
		Go("listHomework.asp")
	End Sub
	
	'删除已有作业信息
	Sub deleteHomework()
		dim homeworkID
		
		homeworkID = Request.QueryString("homeworkID")
		
		'参数是否完整
		if(homeworkID = "")then
			Alert("参数丢失，拒绝操作")
			GoBack()
			Response.end
		end if
		
		'首先判断是否有权限删除对应记录
		sql = "select count(*) from courseHomework,course "
		sql = sql & "where courseHomework.courseID = course.ID "
		sql = sql & "and course.tID = " & teacherID
		
		set rs = ExecuteQuery(sql)
		if(rs(0) = 0) then
			Alert("参数非法，拒绝操作！")
			GoBack()
			Response.end
		end if
		
		rs.close()
		set rs = nothing
		
		'删除作业信息
		sql = "delete from courseHomework where ID = " & homeworkID
		ExecuteNonQuery(sql)
		Alert("作业信息删除成功，请继续其他操作")
		Go("listHomework.asp")
		
	End Sub
	
	'处理学生提交的作业信息
	Sub dealStuHomework()
		dim stuHomeworkID
		dim homeworkRank
		dim stuCommonMark	'是否增加平时成绩
		dim teacherTime		'教师点评时间
		
		stuHomeworkID = Request.QueryString("stuHomeworkID")
		
		homeworkRank = Trim(Request.Form("homeworkRank"))
		stuCommonMark = Request.Form("stuCommonMark")
		teacherTime = Date()
		
		'过滤html字符
		homeworkRank = HtmlEncode2(homeworkRank)
		
		'参数是否完整
		if(stuHomeworkID = "") then
			Alert("参数丢失，拒绝操作！")
			GoBack()
			Response.end
		end if
		
		'判断是否有权限处理这条作业记录
		sql = "select count(*) from stuHomework,courseHomework,course "
		sql = sql & "where courseHomework.courseID = course.ID "
		sql = sql & "and stuHomework.homeworkID = courseHomework.ID "
		sql = sql & "and stuHomework.ID = " & stuHomeworkID & " "
		sql = sql & "and course.tID = " & teacherID

		set rs = ExecuteQuery(sql)
		if(rs(0) = 0) then
			Alert("参数非法，拒绝操作！")
			GoBack()
			Response.end
		end if
		
		rs.close()
		set rs = nothing
		
		'更新教师点评内容
		sql = "update stuHomework set homeworkRank = '" & homeworkRank & "',"
		sql = sql & "teacherTime = '" & teacherTime & "' "
		sql = sql & "and ID = " & stuHomeworkID
		ExecuteNonQuery(sql)
		
		'更新学生平时成绩字段
		if(stuCommonMark <> 0)then
			sql = "update stuCourse set stuCommonMark = stuCommonMark + " 
			sql = sql & stuCommonMark & " where ID = "
			sql = sql & "(select ID from stuCourse where stuID = "
			sql = sql & "(select stuID from stuHomework where ID = " & stuHomeworkID
			sql = sql & ") and courseID = "
			sql = sql & "(select courseID from courseHomework where ID = "
			sql = sql & "(select homeworkID from stuHomework where ID = "
			sql = sql & stuHomeworkID & ")))"
			'Response.write sql
			'Response.end	
			ExecuteNonQuery(sql)
		end if
		
		Alert("信息更新成功，请继续其他操作！")
		Go("listStudentHomework.asp")
	End Sub
%>