managecourse.asp

一套完整的学生课程管理系统

<!-- #include file="utility/check.asp" -->

<%
	'****************************************
	'目的：			处理学生选课信息
	'开始时间：		2005-5-31
	'最后修改时间：	2005-5-31
	'编写人：		某某某
	'****************************************
		
	'首先检查是否有权限
	'也就是用户是否通过审核
	CheckFlag(1)
	
	'定义相关变量
	dim actionType		'操作类型
	dim studentID		'学号
	dim courseID		'课程号
	dim sql				
	dim rs
	
	'将URL中的值取出并赋给变量
	actionType = Request.QueryString("actionType")
	courseID = Request.QueryString("courseID")
	studentID = Session("userID")
	
	'判断制定ID的课程是否允许修改选课状态
	sql = "select canSelect from course where ID = " & courseID
	set rs = ExecuteQuery(sql)
	'判断是否存在课程
	if(rs.EOF) then
		Alert("错误的参数：不存在这门课程！")
		GoBack()
		Response.end
	end if
	'判断课程是否允许修改状态
	if(rs(0) <> 1) then
		Alert("对不起，该课程不允许修改选课状态")
		GoBack()
		Response.end
		'关闭RecordSet，释放对象
		rs.close()
		set rs = nothing
	end if

	
	'如果通过以上检查，则判断操作类型并执行对应操作
	Select case (actionType)
		case "add": 	
			addCourse()				'添加选课信息
		case "delete":	
			deleteCourse()			'删除选课信息
	end Select
	
	'添加新的选课信息到数据库
	Sub addCourse()
	
		'判断学生是否已经选择了该课程
		sql = "select count(*) from stuCourse where stuID = '"  
		sql = sql & studentID 
		sql = sql & "' and courseID = " & courseID
		set rs = ExecuteQuery(sql)
		if(rs(0) <> 0) then
			Alert("您已经选择过该课程，不能重复选择！")
			GoBack()
			rs.close()
			set rs = nothing
			Response.end
		end if
		
		'该课程没有被选择就修改数据库信息以选择该课程
		sql = "insert into stuCourse(stuID,courseID) values('"
		sql = sql & studentID & "',"	
		sql = sql & courseID & ")"
		ExecuteNonQuery(sql)
		Alert("成功选择该课程，请注意该课程的学习！")
		Go("listCourse.asp")
		
	end Sub
	
	Sub deleteCourse()
		sql = "delete from stuCourse where courseID = " & courseID
		'下面这条语句是必须的
		sql = sql & " and stuID = '" & studentID & "'"
		ExecuteNonQuery(sql)
		
		'下面的操作目的是删除对应课程已经提交了的作业信息
		'sql = "delete from "
		'TODO :删除作业信息
		
		
		Alert("您成功删除了这么课程。")
		Go("welcome.htm")
	end Sub
	

%>