create

用于求解大型稀疏线性方程组Ax=b的数值计算库.

#!/bin/csh -f
set HEADER='../include/project_header'
set GAWK='/home/fs1b/karin/bin/gawk'

set file="$1"
if ( "$file" =~ *vbr* ) then
    set SF='vbr'
else if ( "$file" =~ *bco* ) then
    set SF='bco'
else if ( "$file" =~ *bsr* ) then
    set SF='bsr'
else if ( "$file" =~ *bsc* ) then
    set SF='bsc'
else if ( "$file" =~ *csr* ) then
    set SF='csr'
else if ( "$file" =~ *csc* ) then
    set SF='csc'
else if ( "$file" =~ *coo* ) then
    set SF='coo'
else 
    echo "Unknown storage format. Check $0 and/or argument name."
    exit
endif


if ( "$file" =~ *mm* ) then 
    set ROOT_KERNEL="CaABbC"
    set ROOT_TRANSP_KERNEL="CaATBbC"
    set SOURCEFILE="${SF}mm"
    set TARGETFILE="d${SF}mml.c"
    set VECTORDEFS=""
    set WORKDEFS="work"
else if ( "$file" =~ *vm* ) then
    set ROOT_KERNEL="CaABbC"
    set ROOT_TRANSP_KERNEL="CaATBbC"
    set SOURCEFILE="${SF}mm"
    set TARGETFILE="d${SF}vml.c"
    set VECTORDEFS="vector"
    set WORKDEFS="work"
else if ( "$file" =~ *mts* ) then 
    set ROOT_KERNEL="CaDADBbC"
    set ROOT_TRANSP_KERNEL="CaDATDBbC"
    set SOURCEFILE="${SF}mts"
    set TARGETFILE="d${SF}mtsl.c"
    set VECTORDEFS=""
    set WORKDEFS=""
else if ("$file" =~ *vts* ) then
    set ROOT_KERNEL="CaDADBbC"
    set ROOT_TRANSP_KERNEL="CaDATDBbC"
    set SOURCEFILE="${SF}mts"
    set TARGETFILE="d${SF}vtsl.c"
    set VECTORDEFS="vector"
    set WORKDEFS=""
else
    echo "Unknown blas source file. Check $0 and/or argument name."
    exit
endif

set TARGETDIR="../src_lite"
set TARGETFILE="$TARGETDIR/${TARGETFILE}"
if ( ! -d $TARGETDIR ) then
    mkdir $TARGETDIR
endif

set KERNEL=`echo $file | sed -e 's/[^C]*\(C[^.]*\).c/\1/'`
set TRANSP_KERNEL=`echo $KERNEL | sed -e 's/A/AT/'`
echo "Processing kernel $KERNEL for source file $file"
   
if ( -e sedcmd.tmp ) then
   rm -f sedcmd.tmp
endif
echo "s/_${ROOT_KERNEL}_/_${KERNEL}_/" > sedcmd.tmp
echo "s/_${ROOT_TRANSP_KERNEL}_/_${TRANSP_KERNEL}_/" >> sedcmd.tmp
foreach def_file ( `cat ./kernels/$KERNEL` )
   $GAWK -f getdefs.awk Defs/$def_file >> sedcmd.tmp
end
foreach def_file ( $VECTORDEFS $WORKDEFS )
   $GAWK -f getdefs.awk Defs/$def_file >> sedcmd.tmp
end
echo ""  >>  $TARGETFILE
echo ""  >>   $TARGETFILE
eval $GAWK -f trim_include.awk $SOURCEFILE.c | sed -f sedcmd.tmp | sed -f neaten.sed >> $TARGETFILE
echo "Source $file installed in $TARGETFILE."