📄 book_list.asp
字号:
<%option explicit%>
<%
'这是安全模块，如果客户不是管理员用户，立即重定向到首页.
'这样可以防止某些客户直接访问admin下面的文件。
If Session("UserType")<>"A" Then
Response.Redirect "../index.asp"
End If
%>
<!--#INCLUDE FILE="../odbc_connection2.asp"-->
<!--#INCLUDE FILE="../config.asp"-->
<html>
<head>
<title>书籍管理</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link href="../style.css" rel="stylesheet" type="text/css">
</head>
<body>
<%
'下面的page_no变量用来确定显示第几页数据。
Dim page_no
If Session("page_no")="" Then
page_no=1
Session("page_no")=page_no
Elseif Request.QueryString("page_no")<>"" Then
page_no=Cint(Request.QueryString("page_no"))
Session("page_no")=page_no
Else
page_no=Session("page_no")
End If
%>
<h2 align="center">书籍管理</h2>
<table border="0" width="90%" align="center" >
<tr bgcolor="#FFFFFF" align="right">
<td colspan="7"><a href="book_add.asp">添加书籍</a></td>
</tr>
<tr bgcolor="#B7B7B7" height="23" align="center">
<td width="5%">编号</td>
<td width="30%">名称</td>
<td width="15%">作者</td>
<td width="15%">价格</td>
<td width="15%">进书数量</td>
<td width="15%">所属类别</td>
<td width="10%">操作</td>
</tr>
<%
'下面分页显示有关内容
Dim strSql,rs
strSql="Select * From Book Order By SubmitDate Desc"
Set rs=Server.CreateObject("ADODB.Recordset")
rs.Open strSql,db,1 '因为要分页显示，所以用键盘指针
'下面查询记录，如果非空就显示记录
If Not rs.Bof And Not rs.Eof Then
'以下主要为了分页显示
rs.PageSize=PageSize '设置每页显示多少条记录，从config.asp中读取
dim page_total
page_total=rs.PageCount 'page_total会返回总页数，将在下面输出页码时用到
rs.AbsolutePage=page_no '设置当前显示第几页，这里用到了传过来的page_no。
'下面一段利用表格显示当前页的所有记录
Dim I
I=PageSize 'I 用来控制显示当前页记录,注意这里和rs.PageSize要一致。
Do While Not rs.Eof And I>0 '循环直到当前页结束或记录集结尾
I=I-1 '每显示一条，I减1，当变成0时，表示本页结束
%>
<tr bgcolor="#F2F2F2" height="23" valign="middle">
<td align="center"><%=rs("BookId")%></td>
<td align="left">
<a href="book_particular.asp?BookId=<%=rs("BookId")%>" target="_blank"><%=rs("BookName")%></a>
</td>
<td align="center"><%=rs("BookAuthor")%></td>
<td align="center"><%=rs("BookPrice")%></td>
<td align="center"><%=rs("BookNum")%></td>
<td align="center"><%=rs("Kindid")%></td>
<td align="center"><a href="book_delete.asp?BookId=<%=rs("BookId")%>">删除</a></td>
</tr>
<%
rS.MoveNext
Loop
End If
'关闭对象
db.Close
Set db=Nothing
%>
</table>
<%
'以下语句依次写出各页页码，并将非当前页设置超链接，当前页则不设置
Response.Write "<p align='center'><b><font color='#CC0066'>" & page_no & "/" & page_total & "</b></font>页 "
For I=1 To page_total
If I=page_no Then
Response.Write I & " "
Else
Response.Write "<a href='Book_list.asp?page_no=" & I & "'>" & I & "</a> "
End If
Next
%>
</body>
</html>
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -