placebid.asp

实验教学系统 很好用 有学生 老师 管理等模块 便于学校使用

<!-- #include file="auctionlib.asp" -->
<!--#include file="aspemail.inc"-->
<% 
Call DoPageHeader
Call OpenDBConn

sUserName   = Request.Form("UserName")
sPassword   = Request.Form("Password")
iBidPlaced  = FVal(Request.Form("Bid"))
iItemID     = Request.Form("ItemID")

regSQL = ""
regSQL = regSQL & "SELECT COUNT(*) as Total FROM registration WHERE username = " & SQLStr(sUserName) & " AND password = " & SQLStr(sPassword) & " "
Set regRS = GobjConnect.Execute(regSQL)

bidSQL = ""
bidSQL = bidSQL & "SELECT * FROM Auctions WHERE ItemID =" & SQLVal(iItemID)
set bidRS = GobjConnect.Execute(bidSQL)

iBidNeeded = FVal(bidRS.Fields("MinimumIncrement") + bidRS.Fields("CurrentBid"))

	If UserRegistered Then
		If CheckBid Then
			Call PlaceBid
			Call SendOutbidEmail
		End If
	End If


BidRS.Close
Set BidRS = Nothing
Call DoPageFooter
Call CloseDBConn



Sub PlaceBid
	
	uiSQL = ""
	uiSQL = uiSQL & "SELECT * FROM Registration WHERE username = " & SQLStr(sUserName) & " AND password = " & SQLStr(sPassword) & " "
	Set UserRS = GobjConnect.Execute(uiSQL)
	
	
	pbSQL = ""
	pbSQL = pbSQL & " UPDATE Auctions Set "
	pbSQL = pbSQL & " CurrentBid = " & SQLVal(iBidPlaced) 
	pbSQL = pbSQL & " , CurrentBidder = " & SQLVal(UserRS.Fields("ID")) & " "
	pbSQL = pbSQL & " WHERE ItemID = " & bidRS.Fields("ItemID") & " "
	'Response.write pbSQL & "<BR>"
	GobjConnect.Execute(pbSQL)
	
	upbidsSQL = ""
	upBidsSQL = upBidsSQL & "INSERT INTO Bids (ItemID, BidAmount, BidDate, BidderID) "
	upBidsSQL = upBidsSQL & " VALUES( "
	upBidsSQL = upBidsSQL &  SQLVal(iItemID) & ", "
	upBidsSQL = upBidsSQL &  SQLVal(iBidPlaced) & ", "
	upBidsSQL = upBidsSQL &  SQLDate(NOW) & ", "
	upBidsSQL = upBidsSQL &  SQLVal(UserRS.Fields("ID")) & " ) "
	GobjConnect.Execute(upBidsSQL)
	'Response.Write upBidsSQL & "<BR>"
	
	
	Response.Write("<SMALL>您的出价 " & FormatCurrency(iBidPlaced, 2) & " 已经成功，其拍卖物编号是 (" & bidRS.Fields("ItemID"))
	Response.Write(") <B>" & bidRS.Fields("ItemTitle") & "</B><BR> 在时间 " & NOW & " <BR>")
	Response.Write("请打印出此出价的记录为凭证<BR><P>")
	Response.Write("<A HREF=""viewauctions.asp?catID=" & bidRS.Fields("CategoryID") & chr(34) & ">单击这里</A> 回到主目录<BR>")
	Response.Write("<A HREF=""viewitem.asp?ID=" & iItemID & chr(34) & ">单击这里</A> 回到拍卖物 #" & bidRS.Fields("ItemID") & ".<BR></SMALL>")
	
End Sub


Function CheckBid
	
		If iBidPlaced >= iBidNeeded Then
			CheckBid = True
		Else
			Response.Write("<CENTER><SMALL>对不起! 您的出价出现错误<BR>")
			Response.Write("请在浏览器中单击 ""<B>后退</B>"" 按钮再试一次<BR></SMALL></CENTER>")
			CheckBid = False
		End If
		
End Function

Function UserRegistered
	
	If regRS.Fields("Total") = 1 Then
		UserRegistered = True
	Else
		Response.Write("<CENTER><SMALL>输入的 <B>用户名/密码</B>错误<BR>")
		Response.Write("请在浏览器中单击 ""<B>后退</B>"" 按钮再试一次<BR>")
		Response.Write("如果您尚未注册， <A HREF=""register/register.asp"">单击这里</A> 注册成为会员</SMALL></CENTER>")
		UserRegistered = False
	End If
	
	regRS.Close
	Set regRS = Nothing
End Function

%>