borcvsdllunit.pas

CVS IDE plugin for Borland Delphi this is a good program,i like this kind of practise

unit BorCVSdllUnit;

{$IFDEF BCB}
{$OBJEXPORTALL ON}
{$ENDIF BCB}

interface

uses
  Windows,
  ToolsAPI;

// This function needs to be interface-visible, otherwise
// C++Builder 5 complains about a missing EXTDEF symbol
// for this export.
// Do not call this function yourself.
function InitWizard(const BorlandIDEServices: IBorlandIDEServices;
  RegisterProc: TWizardRegisterProc;
  var Terminate: TWizardTerminateProc): Boolean; stdcall;

implementation

uses
  TBorCvsWizardunit;

const
  InvalidIndex = -1;

var
  FExpertIndex: Integer = InvalidIndex;

{ Remove the wizard from the IDE. }

procedure FinalizeWizard;
var
  WizardServices: IOTAWizardServices;
begin
  if FExpertIndex <> InvalidIndex then
  begin
    Assert(Assigned(BorlandIDEServices));

    WizardServices := BorlandIDEServices as IOTAWizardServices;
    Assert(Assigned(WizardServices));

    WizardServices.RemoveWizard(FExpertIndex);

    FExpertIndex := InvalidIndex;
  end;
end;

{ Register the wizard. }

function InitWizard(const BorlandIDEServices: IBorlandIDEServices;
  RegisterProc: TWizardRegisterProc;
  var Terminate: TWizardTerminateProc): Boolean; stdcall;
var
  WizardServices: IOTAWizardServices;
begin
  Result := (BorlandIDEServices <> nil);
  if Result then
  begin
    Assert(ToolsAPI.BorlandIDEServices = BorlandIDEServices);

    Terminate := FinalizeWizard;

    WizardServices := BorlandIDEServices as IOTAWizardServices;
    Assert(Assigned(WizardServices));

    FExpertIndex := WizardServices.AddWizard(TBorCvsWizard.Create as IOTAWizard);

    Result := (FExpertIndex >= 0);
  end;
end;

exports
  InitWizard name WizardEntryPoint;

// ---------------------------------------------

end.