booter_standalonemem.ld

au1200下的boot代码

INPUT(-lau1x00)

OUTPUT_ARCH(mips)

ENTRY(reset)

/**** Start point ****/
/***
caution:this is modified  from booter_standalone.ld,if you want to burn 
it into flash,original ld file should be used
**/
SECTIONS
{
  .text 0x80100000 :
  {
    *(.reset)
    *(.init)
    *(.text)
    _ecode = ABSOLUTE(.) ;	/* End of code 			    */
	*(.rodata)
	*(.rodata.*)

    . = ALIGN(8);
    _etext = ABSOLUTE(.);	/* End of code and read-only data   */
  }

  /**** Initialised data ****/
 	.data   :
  {
    _data = ABSOLUTE(.);	/* Start of initialised data	    */
    _data_actual = ADDR(.data); /*ADDR(.text) + SIZEOF(.text);	 Actual location of data segment */

    *(.ramcode)
    *(.data)

    . = ALIGN(8);

    _gp = ABSOLUTE(. + 0x7ff0); /* point at middle (32Kbytes) of 64Kbyte initialized data		    */

    *(.lit8)
    *(.lit4)
    *(.sdata)

    . = ALIGN(8);

    _edata  = ABSOLUTE(.);	/* End of initialised data	    */
  }

  /**** Uninitialised data ****/

  _fbss = .;			/* Start of unitialised data	    */

  .sbss :
  {
    *(.sbss)
    *(.scommon)
  }
  .bss :
  {
    *(.bss)
    *(COMMON)
  }

  _end = . ;		/* End of unitialised data	    */

  .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
  .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }

  /DISCARD/ :
  {
    *(.reginfo)
  }

  PROVIDE(etext = _etext);
  PROVIDE (edata = .);
  PROVIDE (end = .);
  PROVIDE (__stacktop = _end + 0x010000);}