fet210_ta01.s43

110,120140,210,4 30,440 C语言,汇编源程序

;******************************************************************************
;   MSP-FET430X210 Demo - Timer_A Toggle P1.0, CCR0 Contmode ISR, DCO SMCLK 
;
;   Description; Toggle P1.0 using using software and TA_0 ISR. Toggle rate is 
;   set at 50000 DCO/SMCLK cycles. Default DCO frequency used for TACLK. 
;   Durring the TA_0 ISR P0.1 is toggled and 50000 clock cycles are added to 
;   CCR0.  TA_0 ISR is triggered exactly 50000 cycles. CPU is normally off and
;   used only durring TA_ISR.  
;   ACLK = n/a, MCLK = SMCLK = TACLK = default DCO ~ 800k
;
;                MSP430F2131
;             -----------------
;         /|\|              XIN|-  
;          | |                 |
;          --|RST          XOUT|-
;            |                 |
;            |             P1.0|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   October 2004
;******************************************************************************
#include  "msp430x21x1.h"
;------------------------------------------------------------------------------ 
            ORG     0F000h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #300h,SP                ; Initialize 'x2131 stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupP1     bis.b   #001h,&P1DIR            ; P1.0 output 
SetupC0     mov.w   #CCIE,&CCTL0            ; CCR0 interrupt enabled
            mov.w   #50000,&CCR0            ; 
SetupTA     mov.w   #TASSEL_2+MC_2,&TACTL   ; SMCLK, contmode
                                            ;						  
Mainloop    bis.w   #CPUOFF+GIE,SR          ; CPU off, interrupts enabled
            nop                             ; Required only for debugger
                                            ;
;------------------------------------------------------------------------------ 
TA0_ISR;    Toggle P1.0
;------------------------------------------------------------------------------ 
            xor.b   #001h,&P1OUT            ; Toggle P1.0
            add.w   #50000,&CCR0            ; Add Offset to CCR0
            reti                            ;		 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x21x1          
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFF2h                  ; Timer_A0 Vector
            DW      TA0_ISR                 ; 
            END