module1.bas

VB毕业设计源码 适合VB爱好者 及关大做毕业设计的学生朋友 使用与参考

Attribute VB_Name = "Module1"
Option Explicit

Private Const IP_STATUS_BASE As Long = 11000
Private Const IP_SUCCESS As Long = 0
Private Const IP_BUF_TOO_SMALL As Long = (11000 + 1)
Private Const IP_DEST_NET_UNREACHABLE As Long = (11000 + 2)
Private Const IP_DEST_HOST_UNREACHABLE As Long = (11000 + 3)
Private Const IP_DEST_PROT_UNREACHABLE As Long = (11000 + 4)
Private Const IP_DEST_PORT_UNREACHABLE As Long = (11000 + 5)
Private Const IP_NO_RESOURCES As Long = (11000 + 6)
Private Const IP_BAD_OPTION As Long = (11000 + 7)
Private Const IP_HW_ERROR As Long = (11000 + 8)
Private Const IP_PACKET_TOO_BIG As Long = (11000 + 9)
Private Const IP_REQ_TIMED_OUT As Long = (11000 + 10)
Private Const IP_BAD_REQ As Long = (11000 + 11)
Private Const IP_BAD_ROUTE As Long = (11000 + 12)
Private Const IP_TTL_EXPIRED_TRANSIT As Long = (11000 + 13)
Private Const IP_TTL_EXPIRED_REASSEM As Long = (11000 + 14)
Private Const IP_PARAM_PROBLEM As Long = (11000 + 15)
Private Const IP_SOURCE_QUENCH As Long = (11000 + 16)
Private Const IP_OPTION_TOO_BIG As Long = (11000 + 17)
Private Const IP_BAD_DESTINATION As Long = (11000 + 18)
Private Const IP_ADDR_DELETED As Long = (11000 + 19)
Private Const IP_SPEC_MTU_CHANGE As Long = (11000 + 20)
Private Const IP_MTU_CHANGE As Long = (11000 + 21)
Private Const IP_UNLOAD As Long = (11000 + 22)
Private Const IP_ADDR_ADDED As Long = (11000 + 23)
Private Const IP_GENERAL_FAILURE As Long = (11000 + 50)
Private Const MAX_IP_STATUS As Long = (11000 + 50)
Private Const IP_PENDING As Long = (11000 + 255)
Private Const PING_TIMEOUT As Long = 500
Private Const WS_VERSION_REQD As Long = &H101
Private Const MIN_SOCKETS_REQD As Long = 1
Private Const SOCKET_ERROR As Long = -1
Private Const INADDR_NONE As Long = &HFFFFFFFF
Private Const MAX_WSADescription As Long = 256
Private Const MAX_WSASYSStatus As Long = 128

Private Type WSADATA
   wVersion As Integer
   wHighVersion As Integer
   szDescription(0 To MAX_WSADescription) As Byte
   szSystemStatus(0 To MAX_WSASYSStatus) As Byte
   wMaxSockets As Long
   wMaxUDPDG As Long
   dwVendorInfo As Long
End Type

Private Type ICMP_OPTIONS
   Ttl             As Byte
   Tos             As Byte
   Flags           As Byte
   OptionsSize     As Byte
   OptionsData     As Long
End Type

Public Type ICMP_ECHO_REPLY
   Address         As Long
   status          As Long
   RoundTripTime   As Long
   DataSize        As Long
  'Reserved        As Integer
   DataPointer     As Long
   Options         As ICMP_OPTIONS
   Data            As String * 250
End Type

Private Type HOSTENT
   hName As Long
   hAliases As Long
   hAddrType As Integer
   hLen As Integer
   hAddrList As Long
End Type

Private Declare Function gethostbyname Lib "WSOCK32.DLL" _
  (ByVal hostname As String) As Long
  
Private Declare Sub CopyMemory Lib "kernel32" _
   Alias "RtlMoveMemory" _
  (xDest As Any, _
   xSource As Any, _
   ByVal nbytes As Long)

Private Declare Function lstrlenA Lib "kernel32" _
  (lpString As Any) As Long

Private Declare Function WSAStartup Lib "WSOCK32.DLL" _
   (ByVal wVersionRequired As Long, _
    lpWSADATA As WSADATA) As Long
    
Private Declare Function WSACleanup Lib "WSOCK32.DLL" () As Long

Private Declare Function IcmpCreateFile Lib "icmp.dll" () As Long

Private Declare Function IcmpCloseHandle Lib "icmp.dll" _
   (ByVal IcmpHandle As Long) As Long
   
Private Declare Function IcmpSendEcho Lib "icmp.dll" _
   (ByVal IcmpHandle As Long, _
    ByVal DestinationAddress As Long, _
    ByVal RequestData As String, _
    ByVal RequestSize As Long, _
    ByVal RequestOptions As Long, _
    ReplyBuffer As ICMP_ECHO_REPLY, _
    ByVal ReplySize As Long, _
    ByVal Timeout As Long) As Long
    
Private Declare Function inet_addr Lib "WSOCK32.DLL" _
   (ByVal s As String) As Long

Public Function Ping(sAddress As String, _
                     sDataToSend As String, _
                     ECHO As ICMP_ECHO_REPLY) As Long
  '如果Ping成功，则RoundTripTime = time以毫秒为单位记录了完成整个过程的时间，
  '.Data表示的是返回的数据，Address实际应答的主机的IP地址，
  '.DataSize表示返回数据的长度，Status的值将为0。
  '如果失败，则Status返回一个错误代码。
   Dim hPort As Long
   Dim dwAddress As Long
  '转换IP地址字符串为一个符合因特网规范的long地址
   dwAddress = inet_addr(sAddress)
  '如果dwAddress地址有效
   If dwAddress <> INADDR_NONE Then
     '打开端口
      hPort = IcmpCreateFile()
     '如果成功打开端口
      If hPort Then
        'ping
         Call IcmpSendEcho(hPort, _
                           dwAddress, _
                           sDataToSend, _
                           Len(sDataToSend), _
                           0, _
                           ECHO, _
                           Len(ECHO), _
                           PING_TIMEOUT)
        'ping成功后，返回status
         Ping = ECHO.status
        '关闭端口句柄
         Call IcmpCloseHandle(hPort)
      End If  'If hPort
   Else:
        '可能是地址格式无效
         Ping = INADDR_NONE
   End If
End Function

Public Function GetStatusCode(status As Long) As String
   Dim msg As String
   Select Case status
      Case IP_SUCCESS:               msg = "ip成功"
      Case INADDR_NONE:              msg = "inet_addr:错误的IP格式"
      Case IP_BUF_TOO_SMALL:         msg = "ip缓存太小"
      Case IP_DEST_NET_UNREACHABLE:  msg = "ip目的网络无法抵达"
      Case IP_DEST_HOST_UNREACHABLE: msg = "ip目的主机无法抵达"
      Case IP_DEST_PROT_UNREACHABLE: msg = "ip目的网络无法抵达"
      Case IP_NO_RESOURCES:          msg = "ip无资源"
      Case IP_BAD_OPTION:            msg = "ip错误选项"
      Case IP_HW_ERROR:              msg = "ip hw错误"
      Case IP_PACKET_TOO_BIG:        msg = "ip包太大"
      Case IP_REQ_TIMED_OUT:         msg = "ip请求超时"
      Case IP_BAD_REQ:               msg = "ip错误请求"
      Case IP_BAD_ROUTE:             msg = "ip错误路由"
      Case IP_TTL_EXPIRED_TRANSIT:   msg = "ip ttl expired transit"
      Case IP_TTL_EXPIRED_REASSEM:   msg = "ip ttl expired reassem"
      Case IP_PARAM_PROBLEM:         msg = "ip参数出错"
      Case IP_SOURCE_QUENCH:         msg = "ip资源被破坏"
      Case IP_OPTION_TOO_BIG:        msg = "ip选项太大"
      Case IP_BAD_DESTINATION:       msg = "ip错误目标"
      Case IP_ADDR_DELETED:          msg = "ip地址已被删除"
      Case IP_SPEC_MTU_CHANGE:       msg = "ip spec mtu change"
      Case IP_MTU_CHANGE:            msg = "ip mtu_change"
      Case IP_UNLOAD:                msg = "ip未装载"
      Case IP_ADDR_ADDED:            msg = "ip地址已加载"
      Case IP_GENERAL_FAILURE:       msg = "ip一般错误"
      Case IP_PENDING:               msg = "ip持续"
      Case PING_TIMEOUT:             msg = "ping超时"
      Case Else:                     msg = "返回了未知消息"
   End Select
   GetStatusCode = CStr(status) & "   [ " & msg & " ]"
End Function


Public Function GetIPFromHostName(ByVal sHostName As String) As String
  '将主机名转换为IP地址
   Dim nbytes As Long
   Dim ptrHosent As Long  'hostent结构的地址
   Dim ptrName As Long    'name指针的地址
   Dim ptrAddress As Long 'address指针的地址
   Dim ptrIPAddress As Long
   Dim sAddress As String
   sAddress = Space$(4)
   ptrHosent = gethostbyname(sHostName & vbNullChar)
   If ptrHosent <> 0 Then
     '分配指针的地址与偏移量
     'ptrName是主机的官方名，如果使用DNS或类似的解析系统，则它是完全合格域名
     '（FQDN：Fully Qualified Domain Name），这会导致服务器返回一个应答信息。
     '如果使用本地主机文件，则它是IP地址后的第一个入口。
      ptrName = ptrHosent
     '以空字符结尾的主机地址，该地址是HOSENT的开始地址偏移了12个字节后的地址。
     '注意：这里只返回第一个地址。要想返回更多的信息，定义sAddress为一个字符串数组。
     '然后循环处理返回的4字节的ptrIPAddress成员。
      ptrAddress = ptrHosent + 12
     '获得IP地址
      CopyMemory ptrName, ByVal ptrName, 4
      CopyMemory ptrAddress, ByVal ptrAddress, 4
      CopyMemory ptrIPAddress, ByVal ptrAddress, 4
      CopyMemory ByVal sAddress, ByVal ptrIPAddress, 4
      GetIPFromHostName = IPToText(sAddress)
   End If
End Function

Private Function IPToText(ByVal IPAddress As String) As String

   IPToText = CStr(Asc(IPAddress)) & "." & _
              CStr(Asc(Mid$(IPAddress, 2, 1))) & "." & _
              CStr(Asc(Mid$(IPAddress, 3, 1))) & "." & _
              CStr(Asc(Mid$(IPAddress, 4, 1)))
End Function

Public Sub SocketsCleanup()

   If WSACleanup() <> 0 Then
       MsgBox "终止Windows Sockets时发生了错误", vbExclamation
   End If
End Sub

Public Function SocketsInitialize() As Boolean
   Dim WSAD As WSADATA
   
   SocketsInitialize = WSAStartup(WS_VERSION_REQD, WSAD) = IP_SUCCESS
End Function