psp_scanner.l

mini http server,可以集成嵌入到程序中,实现简单的web功能

/*____________________________________________________________________________*\
 *

 Copyright (c) 1997-2003 John Roy, Holger Zimmermann. All rights reserved.

 These sources, libraries and applications are
 FREE FOR COMMERCIAL AND NON-COMMERCIAL USE
 as long as the following conditions are adhered to.

 Redistribution and use in source and binary forms, with or without
 modification, are permitted provided that the following conditions
 are met:

 1. Redistributions of source code must retain the above copyright
    notice, this list of conditions and the following disclaimer. 

 2. Redistributions in binary form must reproduce the above copyright
    notice, this list of conditions and the following disclaimer in
    the documentation and/or other materials provided with the
    distribution.

 3. The name of the author may not be used to endorse or promote products
    derived from this software without specific prior written permission. 

 THIS SOFTWARE IS PROVIDED ``AS IS'' AND ANY EXPRESSED OR IMPLIED
 WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
 OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
 IN NO EVENT SHALL THE AUTHORS OR ITS CONTRIBUTORS BE LIABLE FOR ANY
 DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
 GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
 STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
 OF THE POSSIBILITY OF SUCH DAMAGE.

 *____________________________________________________________________________*|
 *
 * $Source: /cvsroot/pi3web/Pi3Web_200/Source/Pi3Perl/PspParser/psp_scanner.l,v $
 * $Date: 2003/05/13 18:42:12 $
 *
 Description:
\*____________________________________________________________________________*/

%{
#include <fstream.h>
#include <string.h>
#include <stdio.h>
#include "psp_parser.h"
#include "psp_scanner.h"

%}

%x ST_IN_TAG
%x ST_IN_PSP
%x ST_IN_EXPR
%x ST_IN_SCRP
%x ST_IN_DIRE
%x ST_INCLUDE
%x ST_QUOTED

%option c++
%option stack
%option yylineno
%option noyywrap

NO_WS_AND_TAG		[^ \n\r\t%]*
NO_END_TAG			[^ \n\r\t>]*
WHITESPACE			[ \n\r\t]+
QUOTED_FNAME		[^\"]*

%%
<INITIAL>[^<#\n]*					*pi3lval = (int)pi3text; return PLAIN;
<INITIAL>"<"[^<%\n]*				*pi3lval = (int)pi3text; return PLAIN;
<INITIAL>\n							*pi3lval = (int)pi3text; return NL;
<INITIAL>"<%"						*pi3lval = (int)pi3text; yyless(0); BEGIN(ST_IN_TAG); return START_TAG;
<INITIAL>"#!"*						*pi3lval = (int)pi3text; return SHEBANG;

<ST_IN_TAG>"%>"						*pi3lval = (int)pi3text; BEGIN(INITIAL); return END_TAG;
<ST_IN_TAG>{WHITESPACE}"%>"			*pi3lval = (int)pi3text; BEGIN(INITIAL); return END_TAG;

<ST_IN_TAG>"<%"{WHITESPACE}			*pi3lval = (int)pi3text; BEGIN(ST_IN_SCRP); return SCRIPTLET_START;
<ST_IN_SCRP>{WHITESPACE}			*pi3lval = (int)pi3text; return WHITESPACE;
<ST_IN_SCRP>{NO_WS_AND_TAG}			*pi3lval = (int)pi3text; return SCRIPTLET;
<ST_IN_SCRP>"%"{NO_END_TAG}			*pi3lval = (int)pi3text; return SCRIPTLET;
<ST_IN_SCRP>{WHITESPACE}"%>"		*pi3lval = (int)pi3text; BEGIN(ST_IN_TAG); PI3LESS(pi3text,3); return SCRIPTLET_END;

<ST_IN_TAG>"<%@"{WHITESPACE}		*pi3lval = (int)pi3text; BEGIN(ST_IN_DIRE); return DIRECTIVE_START;
<ST_IN_DIRE>"include"				*pi3lval = (int)pi3text; return DIR_INCLUDE;
<ST_IN_DIRE>"page"					*pi3lval = (int)pi3text; return DIR_PAGE;

<ST_IN_DIRE>{WHITESPACE}			*pi3lval = (int)pi3text; return WHITESPACE;
<ST_IN_DIRE>"parsedLength"			*pi3lval = (int)pi3text; return DIR_PARSLEN;
<ST_IN_DIRE>"file"					*pi3lval = (int)pi3text; BEGIN(ST_INCLUDE); return DIR_INCFILE;

<ST_INCLUDE>{WHITESPACE}			*pi3lval = (int)pi3text; return WHITESPACE;
<ST_INCLUDE>"="						return pi3text[0];
<ST_INCLUDE>\"						BEGIN(ST_QUOTED); return pi3text[0];
<ST_INCLUDE>{QUOTED_FNAME} {

    if ( include_stack_ptr >= MAX_INCLUDE_DEPTH )
		{
		*pi3lval = (int)pi3text;
		return ERROR_INCLUDES_TOO_DEEPLY;
		}

	ifstream *pi3in = new ifstream(makeAbsolute(pi3text), ios::nocreate);
    if ( !pi3in || !pi3in->is_open() )
		{
		*pi3lval = (int)pi3text;
	    return ERROR_CANT_OPEN_INCLUDE;
		};

	strcpy((fname_buf), pi3text);
	include_stack[include_stack_ptr++] = YY_CURRENT_BUFFER;
	yy_switch_to_buffer( yy_create_buffer( pi3in, YY_BUF_SIZE ) );
    BEGIN(INITIAL);
	return PUSH_INCLUDE;
    }

<ST_IN_DIRE>"="						return pi3text[0];
<ST_IN_DIRE>\"						BEGIN(ST_QUOTED); return pi3text[0];
<ST_QUOTED>"true"					*pi3lval = 1; return BOOL; 
<ST_QUOTED>"false"					*pi3lval = 0; return BOOL;
<ST_QUOTED>\"						BEGIN(ST_IN_DIRE); return pi3text[0];
<ST_IN_DIRE>{WHITESPACE}"%>"		*pi3lval = (int)pi3text; BEGIN(ST_IN_TAG); PI3LESS(pi3text,3); return DIRECTIVE_END;

<ST_IN_TAG>"<%="{WHITESPACE}		*pi3lval = (int)pi3text; BEGIN(ST_IN_EXPR); return EXPRESSION_START;
<ST_IN_EXPR>{WHITESPACE}			*pi3lval = (int)pi3text; return WHITESPACE;
<ST_IN_EXPR>{NO_WS_AND_TAG}			*pi3lval = (int)pi3text; return EXPRESSION;
<ST_IN_EXPR>"%"{NO_END_TAG}			*pi3lval = (int)pi3text; return EXPRESSION;
<ST_IN_EXPR>{WHITESPACE}"%>"		*pi3lval = (int)pi3text; BEGIN(ST_IN_TAG); PI3LESS(pi3text,3); return EXPRESSION_END;

<ST_IN_TAG,ST_IN_SCRP,ST_IN_DIRE,ST_IN_EXPR><<EOF>>	 BEGIN(INITIAL);

<INITIAL><<EOF>> {
	if ( --include_stack_ptr < 0 )
		{
		yyterminate();
		}
	else
		{
		yy_delete_buffer( YY_CURRENT_BUFFER );
		yy_switch_to_buffer( include_stack[include_stack_ptr] );
		BEGIN(ST_QUOTED);
		return POP_INCLUDE;
		}
	}
%%


/**
* Test main
**/
#if 0
int main(int argc, char *argv[]) {

class MyPSPParser : public PspFlexLexer
{
public:
	MyPSPParser( const char *ifname = 0 ) :
		PspFlexLexer( ifname )
	{
	};
	virtual int doShebang(const char *txt) { printf("SHEBANG: %s\n", txt); return 0; };
	virtual int doPlain(const char *txt) { printf("PLAIN: %s\n", txt); return 0; };
	virtual int doScriptlet(const char *txt) { printf("SCRIPTLET: %s\n", txt); return 0; };
	virtual int doExpression(const char *txt) { printf("EXPRESSION: %s\n", txt); return 0; };
	virtual int doError(const char *msg) { printf("ERROR: %s\n", msg); return 0; };
	virtual const char *makeAbsolute(const char *path) { printf("MAKEABSOLUTE: %s\n", path); return 0; };
};
	if (argc < 2) return 1;

	MyPSPParser scanner(argv[1]);
    scanner.exec();

	return 0;
}
#endif

/**
* Scanner error callback
**/
int pi3error(char *msg) {
	return 1;
}


/**
* Wrapper functions for indirect call
* of class members by C-style parser
**/
int pi3lex(int *pi3lval, void *YYLEX_PARAM) {
	return SG->yylex(pi3lval);
}

int cb_shebang(void *YYLEX_PARAM, const char *txt) {
	return SG->doShebang(txt);
};

int cb_plain(void *YYLEX_PARAM, const char *txt) {
	return SG->doPlain(txt);
};

int cb_scriptlet(void *YYLEX_PARAM, const char *txt) {
	return SG->doScriptlet(txt);
};

int cb_expression(void *YYLEX_PARAM, const char *txt) {
	return SG->doExpression(txt);
};

int cb_error(void *YYLEX_PARAM, const char *msg) {
	return SG->doError(msg);
};

int cb_parsedlen(void *YYLEX_PARAM, int set) {
	return SG->setParsedLen(set);
};

const char *cb_abspath(void *YYLEX_PARAM, const char *path) {
	return SG->makeAbsolute(path);
};

int get_lineno(void *YYLEX_PARAM) {
	return SG->lineno();
}


/**
* Psp Scanner class member functions
**/
PspFlexLexer::PspFlexLexer( const char *ifname ) :
	inFileName( ifname ),
	i( 0 ),
	iParsedLen( 0 ),
	pp( new p_globals( this ) ),
	include_stack_ptr( 0 ),
	iPass( 0 )
{
	istream *arg_yyin = (ifname) ? (istream *)new ifstream(ifname) : &cin;
	yyFlexLexer(arg_yyin, 0);
	switch_streams(arg_yyin, 0);
	yylineno = 1;
}

PspFlexLexer::~PspFlexLexer() {
	((ifstream *)yyin)->close();
    delete( pp );
}

int PspFlexLexer::exec() {
	return pi3parse((pPG)pp);
}

int PspFlexLexer::prepare_next_pass() {
	include_stack_ptr = 0;
	yy_push_state(INITIAL);
	((ifstream *)yyin)->close();
	((ifstream *)yyin)->open(inFileName);
	switch_streams(yyin, 0);
	yylineno = 1;
	return ++(iPass);
}

/**
* Never call the yylex() inherited from the base class
**/
int yyFlexLexer::yylex() {
	pi3error("Error: yyFlexLexer::yylex() called.");
	return -1;
}