boot.asm

音频数据采集与IIR处理例程

        .title  "Flash bootup utility for 6713 dsk"
        .option D,T
        .length 102
        .width  140
     

PAGE_SIZE	  .equ    0x80	    ;flash page size in byte
BOOT_SIZE     .equ    0x400       ;bootup code size in byte
FLASH_START   .equ    0x90000000  ;flash start address
BOOT_START    .equ    0x00000000  ;L2 sram start address

CODE_SIZE     .equ    0xF800      ;application code size in byte
CODE_START    .equ    0x800       ;application code start address

IO_PORT       .equ    0x90080000  ;address of I/O port, only top byte has valid data 
EMIF_GCR 	  .equ    0x01800000  ;EMIF global control     
EMIF_CE1      .equ    0x01800004  ;address of EMIF CE1 control reg. 
EMIF_CE0      .equ    0x01800008  ;EMIF CE0control          
EMIF_SDCTRL   .equ    0x01800018  ;EMIF SDRAM control     
EMIF_SDRP     .equ    0x0180001c  ;EMIF SDRM refresh period 
EMIF_CE1_8    .equ    0xffffff03  ;
EMIF_CE1_16   .equ    0xffffff13  ;
EMIF_CE1_32   .equ    0xffffff23  ;
EMIF_CE0_V    .equ    0x00000090  ;EMIF CE0 control   ;0x90
EMIF_SDCTRL_V .equ    0x53116000  ;EMIF SDRAM control ;0x73380000    



 .sect ".boot_load" 
 .global _boot
 .global _flash_prog
 .global _wait

 .ref _c_int00
 
_boot:
            mvkl  EMIF_GCR,A4    ;EMIF_GCR address ->A4
      ||    mvkl  0x3068,B4      

            mvkh  EMIF_GCR,A4
      ||    mvkh  0x3068,B4  
                            
            stw   B4,*A4                

            mvkl  EMIF_CE0,A4       ;EMIF_CE0 address ->A4
      ||    mvkl  EMIF_CE0_V,B4     ;
            mvkh  EMIF_CE0,A4
      ||    mvkh  EMIF_CE0_V,B4
            stw   B4,*A4 
      
            mvkl  EMIF_CE1,A4       ;EMIF_CE1 address ->A4
      ||    mvkl  EMIF_CE1_16,B4     ;
            mvkh  EMIF_CE1,A4
      ||    mvkh  EMIF_CE1_16,B4
            stw   B4,*A4  
                          
      ||    mvkl  EMIF_SDCTRL,A4    ;EMIF_SDCTRL address ->A4
      ||    mvkl  EMIF_SDCTRL_V,B4     ;

            mvkh  EMIF_SDCTRL,A4
      ||    mvkh  EMIF_SDCTRL_V,B4     
      
            stw   B4,*A4                
      ||    mvkl  EMIF_SDRP,A4      ;EMIF_SDRP address ->A4
      ||    mvkl  0x61a,B4    ;

            mvkh  EMIF_SDRP,A4
      ||    mvkh  0x61a,B4
            
            stw   B4,*A4
 

         mvkl  FLASH_START+0x800,B4 ;flash start address ->B4
         mvkh  FLASH_START+0x800,B4   
       

            mvkl  CODE_START,A4 ;apps code start address ->A4
            mvkh  CODE_START,A4
            zero  A1
 
_boot_loop2:
            ldb   *B4++,B5
            mvkl  CODE_SIZE,B6 ;

            add   1,A1,A1          ;A1+=1,inc outer counter
      ||    mvkh  CODE_SIZE,B6
       
            cmplt  A1,B6,B0
            nop    
            stb   B5,*A4++
      [B0]  b     _boot_loop2
            nop   5
        
            mvkl .S2 _c_int00, B0
            mvkh .S2 _c_int00, B0
            B    .S2 B0
            nop   5
; 
; end of the bootup routine