ftexteditor.class

Gambas is a graphical development environment based on a Basic interpreter, like Visual Basic. It us

' Gambas class file

PUBLIC Name AS String
PUBLIC Path AS String
PUBLIC Editor AS GambasEditor

PRIVATE $bModify AS Boolean

PUBLIC SUB _new(sPath AS String)

  DIM sText AS String

  Path = sPath
  Name = File.Name(Path)
  Editor = edtEditor

  ReadConfig

  Project.InitMove(ME)

  sText = File.Load(sPath)
  'IF Right(sText) <> "\n" THEN sText = sText & "\n"
  edtEditor.Text = sText

  SetReadOnly

  $bModify = FALSE
  edtEditor.Reset
  edtEditor.SetFocus

  DrawTitle

END


PUBLIC SUB ReadConfig()

  DIM iInd AS Integer
  DIM iColor AS Integer
  DIM hTheme AS Integer[]

  edtEditor.Frozen = TRUE

  edtEditor.Font = Font[Settings["/Editor/Font", Project.DEFAULT_FONT]]

  hTheme = FOption.DefaultTheme

  FOR iInd = 0 TO FEditor.NBR_COLOR - 1

    iColor = Val(Settings["/Editor/Color[" & CStr(iInd) & "]", "-1"])
    IF iColor = -1 THEN iColor = hTheme[iInd]
    edtEditor.Colors[iInd] = iColor

  NEXT

  edtEditor.ShowChange = Settings["/Editor/ShowChange", TRUE]

  edtEditor.Frozen = FALSE

END



PUBLIC FUNCTION Save() AS Boolean

  'Project.Config.WriteString("/Window" &/ Name &/ "Pos",
  '  CStr(ME.X) & "," & CStr(ME.Y) & "," & CStr(ME.Width) & "," & CStr(ME.Height))

  IF NOT $bModify THEN RETURN

  Save.Begin(Path)

  File.Save(Path, edtEditor.Text)
  edtEditor.Reset
  $bModify = FALSE
  DrawTitle

  Save.End()

CATCH

  RETURN Save.Error()

END


PRIVATE SUB DrawTitle()

  DIM sTitle AS String

  sTitle = File.Name(Path) & " " & CStr(edtEditor.Line + 1) & ":" & CStr(edtEditor.Column + 1)
  IF $bModify THEN sTitle = sTitle & " [" & ("modified") & "]"
  ME.Title = sTitle '& " - " & Project.Name

END


PUBLIC SUB Modify(OPTIONAL bReset AS Boolean)

  IF $bModify <> bReset THEN RETURN

  $bModify = NOT bReset
  DrawTitle

END


PUBLIC FUNCTION IsModified() AS Boolean

  RETURN $bModify

END



PUBLIC SUB Form_Resize()

  edtEditor.Move(0, 0, ME.ClientW, ME.ClientH)
  'lblCursor.Move(0, ME.ClientH - lblCursor.Height)

END


PUBLIC SUB edtEditor_Change()

  Modify

END


PUBLIC SUB edtEditor_Cursor()

  'PRINT edtEditor.Line; edtEditor.Column
  'lblCursor.Text = CStr(edtEditor.Line + 1) & " : " & CStr(edtEditor.Column + 1)
  DrawTitle

END


'PUBLIC SUB Form_KeyPress(Ascii AS String, Code AS Integer, State AS Integer)
'
'  IF Code = Asc("S") AND State = Mouse.Control THEN
'    ME.Save
'  ENDIF
'
'END


PUBLIC SUB Form_Activate()

  Project.Activate(ME)

END


PUBLIC SUB Goto(iLine AS Integer, OPTIONAL iColumn AS Integer = -1)

  DEC iLine
  IF iColumn < 0 THEN iColumn = edtEditor.Column
  edtEditor.Goto(iLine, iColumn)

END


PUBLIC SUB GotoCenter(iLine AS Integer, OPTIONAL iColumn AS Integer = -1)

  Goto(iLine, iColumn)
  edtEditor.EnsureVisible

END


PUBLIC SUB edtEditor_Menu()

  mnuEditor.Popup

END


PUBLIC SUB mnuSave_Click()

  Save

END


' PUBLIC SUB mnuFind_Click()
'
'   DIM sSel AS String
'   DIM iPos AS Integer
'
'   sSel = Left$(Trim(edtEditor.Selection.Text), 64)
'   iPos = Instr(sSel, gb.NewLine)
'   IF iPos THEN sSel = Left$(sSel, iPos - 1)
'
'   Project.FindForm.Find(sSel)
'
' END
'
'
' PUBLIC SUB mnuFindNext_Click()
'
'   Project.FindForm.FindNext
'
' END
'
'
' PUBLIC SUB mnuFindPrevious_Click()
'
'   Project.FindForm.FindPrevious
'
' END


PUBLIC SUB Rename(sNewName AS String, sNewPath AS String)

  Name = sNewName
  Path = sNewPath 'File.Dir(Path) &/ sNewName & "." & File.Ext(Path)
  DrawTitle

END


PUBLIC SUB mnuCut_Click()

  edtEditor.Cut

END

PUBLIC SUB mnuCopy_Click()

  edtEditor.Copy

END

PUBLIC SUB mnuPaste_Click()

  edtEditor.Paste

END

PUBLIC SUB mnuUndo_Click()

  edtEditor.Undo

END

PUBLIC SUB mnuRedo_Click()

  edtEditor.Redo

END


PUBLIC SUB mnuGotoLine_Click()

  DIM iLine AS Integer

  iLine = FGotoLine.Run(edtEditor.Line + 1)
  IF iLine <= 0 THEN RETURN
  GotoCenter(iLine)

END


' PUBLIC SUB mnuWordWrap_Click()
'
'   edtEditor.Wrap = NOT edtEditor.Wrap
'   mnuWordWrap.Checked = edtEditor.Wrap
'
' END


PUBLIC SUB mnuSelectAll_Click()

  edtEditor.Selection

END


PRIVATE SUB SetReadOnly()

  edtEditor.ReadOnly = Project.ReadOnly OR Project.Running

END

PUBLIC SUB OnProjectDebug()

  SetReadOnly

END


PUBLIC SUB mnuFind_Click()

  DIM sSel AS String
  DIM iPos AS Integer
  DIM sText AS String

  sSel = Left$(Trim(edtEditor.Selection.Text), 256)
  iPos = Instr(sSel, gb.NewLine)
  IF iPos THEN sSel = Left$(sSel, iPos - 1)

  FFind.Find(sSel)

END


PUBLIC SUB mnuFindNext_Click()

  FFind.FindNext

END


PUBLIC SUB mnuFindPrevious_Click()

  FFind.FindPrevious

END