fopenproject.class

Gambas is a graphical development environment based on a Basic interpreter, like Visual Basic. It us

' Gambas class file

STATIC PRIVATE $sPath AS String

PRIVATE selOpen AS FSupSelector

STATIC PUBLIC FUNCTION Run() AS String

  DIM hForm AS FOpenProject

  hForm = NEW FOpenProject

  IF hForm.ShowModal() THEN RETURN $sPath

END


PUBLIC SUB _new()

  INC Application.Busy

  Config.LoadWindow(ME, "/FOpenProject")

  selOpen = NEW FSupSelector(ME)

  selOpen.DialogType = FSupSelector.SHOW_PROJECT
  'selOpen.Root = System.Home
  selOpen.ShowHomeTab = TRUE
  selOpen.ShowRootTab = TRUE
  selOpen.Key = "/OpenProject"
  selOpen.ButtonWidth = btnOK.Width
  selOpen.OKButton = btnOK
  selOpen.Init()

  'imgCorner.Raise
  btnOK.Raise
  btnCancel.Raise

  DEC Application.Busy

END


PUBLIC SUB Form_Resize()

  btnCancel.Move(ME.ClientW - btnCancel.Width - 8, ME.ClientH - btnCancel.Height - 8)
  btnOK.Move(btnCancel.X, btnCancel.Y - btnOK.Height - 8)

  selOpen.Move(8, 8, ME.ClientW - 16, ME.ClientH - 16)

  'imgCorner.Move(ME.ClientW - imgCorner.W, ME.ClientH - imgCorner.H)

END

PUBLIC SUB btnCancel_Click()

  ME.Close

END

PUBLIC SUB btnOK_Click()

  IF NOT selOpen.Validate() THEN RETURN
  'IF NOT selOpen.Path THEN RETURN
  $sPath = selOpen.Path

  Config.SaveWindow(ME, "/FOpenProject")
  ME.Close(TRUE)

END