fgambas.class

Gambas is a graphical development environment based on a Basic interpreter, like Visual Basic. It us

' Gambas class file

STATIC PRIVATE $cAnim AS NEW Collection
STATIC PRIVATE $hPict[8] AS Picture

PRIVATE $sAnim AS String
PRIVATE $iWait AS Integer
PRIVATE $MX AS Integer
PRIVATE $MY AS Integer

STATIC PUBLIC SUB _init()

  DIM iInd AS Integer

  $cAnim["Blink"] = "1,0,1,0"
  $cAnim["Blink2"] = "3,4,3,0"
  $cAnim["Depressive"] = "2,6,7,-8,6,2,0"
  $cAnim["Happy"] = "5,0,5,0"

  FOR iInd = 0 TO 7
    $hPict[iInd] = Picture["img/anim/gambas" & CStr(iInd + 1) & ".png"]
  NEXT

END


PUBLIC SUB _new()

  Config.LoadWindow(ME, "/FGambas")

END


PUBLIC SUB Form_Close()

  Config.SaveWindow(ME, "/FGambas")

END


PUBLIC SUB Animate(sAnim AS String)

  IF NOT ME.Visible THEN RETURN

  $sAnim = $sAnim & $cAnim[sAnim]
  $iWait = 0
  ME.Raise

END


PUBLIC SUB timAnim_Timer()

  DIM iPos AS Integer
  DIM iCmd AS Integer
  DIM eRnd AS Float

  IF $iWait > 0 THEN
    DEC $iWait
    RETURN
  ENDIF

  IF NOT $sAnim THEN
    eRnd = Rnd
    IF eRnd < 0.02 THEN
      $sAnim = $cAnim["Blink"]
    ELSE IF eRnd < 0.04 THEN
      $sAnim = $cAnim["Blink2"]
    ELSE
      RETURN
    ENDIF
  ENDIF

  iPos = Instr($sAnim, ",")
  IF iPos = 0 THEN iPos = Len($sAnim) + 1
  iCmd = Val(Left$($sAnim, iPos - 1))
  $sAnim = Mid$($sAnim, iPos + 1)

  IF iCmd < 0 THEN
    $iWait = Abs(iCmd) - 1
    RETURN
  ENDIF

  ME.Mask = $hPict[iCmd]

END

PUBLIC SUB Form_MouseDown()

  $MX = Mouse.ScreenX - ME.X
  $MY = Mouse.ScreenY - ME.Y

END

PUBLIC SUB Form_MouseMove()

  ME.Move(Mouse.ScreenX - $MX, Mouse.ScreenY - $MY)

END

PUBLIC SUB Form_Hide()

  timAnim.Enabled = FALSE

END

PUBLIC SUB Form_Show()

  timAnim.Enabled = TRUE

END