ftoolbox.class

Gambas is a graphical development environment based on a Basic interpreter, like Visual Basic. It us

' Gambas class file

PRIVATE $sTool AS String

PRIVATE CONST WIDTH AS Integer = 40

PRIVATE $cToolBar AS NEW Collection
PRIVATE $sToolBar AS String
PRIVATE $sLastToolBar AS String

PRIVATE $W AS Integer
PRIVATE $H AS Integer

PRIVATE $sLastLib AS String
PRIVATE $iSize AS Integer
PRIVATE $bAnimate AS Boolean

PUBLIC SUB _new()

  DIM iInd AS Integer
  DIM hCtrl AS Control

  ME.Move(Desktop.W - ME.W, 0)
  Config.LoadWindow(ME, "/FToolBox")

  ReadConfig
  SetTool

END


PRIVATE FUNCTION AddToolBar(sToolBar AS String, sType AS String) AS FToolBar

  DIM hToolBar AS FToolBar

  IF NOT $cToolBar.Exist(sToolBar) THEN

    hToolBar = NEW FToolBar(sToolBar, sType, ME) AS "ToolBar"
    $cToolBar[sToolBar] = hToolBar

    IF NOT $sToolbar THEN $sToolBar = sToolBar

  ENDIF

  RETURN $cToolBar[sToolBar]

END


PRIVATE SUB MoveToolbar(OPTIONAL bAnim AS Boolean)

  DIM hToolBar AS FToolBar
  DIM Y AS Integer
  DIM iInd AS Integer
  DIM bCurrent AS Boolean

  FOR EACH hToolBar IN $cToolBar

    bCurrent = $cToolBar.Key = $sToolBar
    hToolBar.ShowToolBar(TRUE)

    IF bAnim AND $bAnimate THEN
      IF ((hToolBar.Y < Y) AND $cToolBar.Key = $sLastToolBar) OR ((hToolBar.Y > Y) AND bCurrent) THEN
        FOR iInd = hToolBAR.Y TO Y STEP 8 * Sgn(Y - hToolBar.Y)
          hToolBar.Y = iInd
          WAIT 0.001
        NEXT
      ENDIF
    ENDIF

    hToolBar.Move(0, Y, ME.ClientW, ME.ClientH)
    'hToolBar.ShowToolBar(bCurrent)

    IF $cToolBar.Key = $sToolBar THEN
      Y = Y + ME.CLientH - $cToolBar.Count * FToolBar.HEIGHT
    ENDIF
    Y = Y + FToolBar.HEIGHT

  NEXT

  FOR EACH hToolBar IN $cToolBar

    bCurrent = $cToolBar.Key = $sToolBar
    hToolBar.ShowToolBar(bCurrent)

  NEXT

END


PUBLIC SUB RefreshToolbar()

  DIM hToolBar AS FToolBar
  DIM sLib AS String
  DIM sCtrl AS String
  DIM sNewLib AS String
  DIM aLib AS String[]

  IF Project.Libraries THEN

    FOR EACH sLib IN Project.Libraries
      sNewLib = sNewLib & sLib & " "
    NEXT
    sNewLib = Trim(sNewLib)

  ENDIF

  IF $sLastLib THEN
    IF sNewLib = $sLastLib THEN RETURN
  ENDIF

  FOR EACH hToolBar IN $cToolBar
    hToolBar.Delete
  NEXT

  $cToolBar.Clear
  $sToolBar = ""

  'AddTool(SELECT_TOOL)
  'SetTool()

  IF Project.Libraries THEN

    FOR EACH sLib IN Project.Libraries

      IF NOT CComponent.All.Exist(sLib) THEN CONTINUE

      WITH CComponent.All[sLib]

        FOR EACH sCtrl IN .Controls
          AddToolBar(.Group, .Type).Add(sCtrl)
        NEXT

        'CControl.AddClasses(.Controls, sLib)

      END WITH

    NEXT

    TRY SelectToolbar("Form")

  ENDIF

  $sLastLib = sNewLib

END


PRIVATE SUB ClearToolBar()
  
  $sLastLib = ""
  RefreshToolBar
  
END



PUBLIC SUB Form_Close()

  Config.SaveWindow(ME, "/FToolBox")

END


PUBLIC SUB SelectToolBar(sToolBar AS String)

 IF NOT $cToolBar.Exist(sToolBar) THEN RETURN
  $sLastToolBar = $sToolBar
  $sToolBar = sToolBar
  MoveToolBar(ME.Visible)

END



PUBLIC SUB Form_Resize()

  MoveToolbar

END


PUBLIC FUNCTION GetTool() AS String

  IF NOT $sToolBar THEN RETURN
  RETURN $cToolBar[$sToolBar].GetTool()

END


PUBLIC SUB SetTool()

  IF NOT $sToolBar THEN RETURN
  $cToolBar[$sToolBar].SetTool()

END


' PUBLIC SUB ToolBar_Change()
'
'   PRINT "ToolBar_Change: "; LAST.Name
'
' END


PUBLIC SUB ReadConfig()
  
  DIM iSize AS Integer
  
  iSize = Settings["/ToolBar/IconSize", 32]
  IF iSize <> $iSize THEN
    $iSize = iSize
    ClearToolBar
  ENDIF
  
  $bAnimate = Settings["/ToolBar/Animate", TRUE]
  
END