foutput.class

Gambas is a graphical development environment based on a Basic interpreter, like Visual Basic. It us

' Gambas class file

PUBLIC Shown AS Boolean

PRIVATE $iPos AS Integer
PRIVATE $bWelcome AS Boolean

PUBLIC SUB _new()

  Config.LoadWindow(ME, "/FOutput")
  ReadConfig

END


PUBLIC SUB Form_Resize()

  txtOutput.Move(0, 0, ME.CLientW, ME.ClientH)

END

PUBLIC SUB Clear()

  txtOutput.Clear
  $iPos = 0

  IF NOT $bWelcome THEN

    txtOutput.Insert(("Welcome to the Gambas console.\nTo evaluate any expression, type '?' followed by\nthe expression, then hit return.\n\n"))
    $iPos = txtOutput.Length

    $bWelcome = TRUE

  ENDIF

END


PUBLIC SUB Insert(sText AS String, OPTIONAL bCurrent AS Boolean)

  IF NOT bCurrent THEN txtOutput.Pos = txtOutput.Length
  txtOutput.Insert(sText)
  $iPos = txtOutput.Pos

  IF NOT ME.Visible THEN
    Shown = TRUE
    ME.Show
  ENDIF

END

PUBLIC SUB ReadConfig()

  txtOutput.Font = Font[Settings["/Editor/Font", Project.DEFAULT_FONT]]
  txtOutput.BackColor = val(Settings["/Editor/Color[0]", str(FOption.DefaultTheme[0])])
  txtOutput.ForeColor = val(Settings["/Editor/Color[1]", str(FOption.DefaultTheme[1])])

END

PUBLIC SUB Form_Hide()

  Config.SaveWindow(ME, "/FOutput")

END

PUBLIC SUB txtOutput_KeyPress()

  DIM sText AS String
  DIM iPos AS Integer
  DIM sVal AS String

  IF Key.Code = Key["Enter"] OR Key.Code = Key["Return"] THEN

    TRY sText = Conv$(txtOutput.Text, Desktop.Charset, System.Charset)

    iPos = RInstr(sText, "\n", txtOutput.Pos)
    sText = Mid$(sText, iPos + 1, txtOutput.Pos - iPos)

    IF FDebug.IsRunning() THEN

      IF $iPos > iPos THEN sText = Mid$(sText, $iPos - iPos + 1)

      txtOutput.Insert("\n")
      FDebug.Send(sText & "\n")
      'Key.Cancel = TRUE
      STOP EVENT

    ELSE IF Left$(sText) = "?" THEN

      sText = Mid$(sText, 2)
      IF NOT sText THEN RETURN

      IF Project.Running THEN

        txtOutput.Insert("\n")
        FDebug.Command("!" & sText, TRUE)
        'Key.Cancel = TRUE
        STOP EVENT

      ELSE

        TRY sVal = Str(Eval(sText & "\n"))
        IF Error THEN sVal = Error.Text
        TRY txtOutput.Insert("\n" & Conv(sVal, System.Charset, Desktop.Charset) & "\n")
        'Key.Cancel = TRUE
        STOP EVENT

      ENDIF

    ENDIF

  ELSE IF Key.Control THEN

    IF Key.Code = Key["L"] THEN
      Clear
    'ELSE IF Code = Key["C"] THEN
    '  Project.DebugForm.Stop
    '  RETURN FALSE
    ENDIF

  ENDIF

END