fmain.class

Gambas is a graphical development environment based on a Basic interpreter, like Visual Basic. It us

' Gambas class file

PRIVATE $hConn AS Connection

PUBLIC SUB btnConnect_Click()

  DIM sName AS String

  TRY $hConn.Close

  sName = txtName.Text

  WITH $hConn
    .Type = cmbType.Text
    .Host = txtHost.Text
    .Login = txtUser.Text
    .Password = txtPassword.Text
  END WITH

  IF chkCreate.Value THEN

    $hConn.Open    
    IF NOT $hConn.Databases.Exist(sName) THEN
      $hConn.Databases.Add(sName)
    ENDIF
    $hConn.Close
  
  ENDIF
  
  $hConn.Name = sName
  $hConn.Open
  
  frmDatabase.Enabled = TRUE
  frmRequest.Enabled = TRUE
  
CATCH

  Message.Error(Error.Text)

END

PUBLIC SUB btnCreate_Click()

  DIM hTable AS Table
  
  hTable = $hConn.Tables.Add("test")
  
  hTable.Fields.Add("id", gb.Integer)
  hTable.Fields.Add("firstname", gb.String, 16)
  hTable.Fields.Add("name", gb.String, 32)
  hTable.Fields.Add("birth", gb.Date)
  hTable.Fields.Add("active", gb.Boolean)
  hTable.Fields.Add("salary", gb.Float)

  hTable.PrimaryKey = ["id"]
  
  hTable.Update

CATCH

  Message.Error(Error.Text) 

END

PUBLIC SUB btnDelete_Click()

  $hConn.Tables.Remove("test")
  
CATCH

  Message.Error(Error.Text) 

END

PUBLIC SUB btnFill_Click()

  DIM iInd AS Integer
  DIM rTest AS Result
  
  INC Application.Busy
  
  $hConn.Begin
  
  rTest = $hConn.Create("test")
  
  FOR iInd = 1 TO 10000
  
    rTest!id = iInd
    rTest!firstname = [ "Paul", "Pierre", "Jacques", "Antoine", "Mathieu" ][Int(Rnd(5))]
    rTest!name = "Name #" & iInd
    rTest!birth = CDate("01/01/1970") + Int(Rnd(10000))
    rTest!active = Int(Rnd(2))
    rTest!salary = Rnd(1000, 10000)
  
    rTest.Update
  
  NEXT
  
  $hConn.Commit
  
FINALLY

  DEC Application.Busy
  
CATCH

  $hConn.Rollback
  Message.Error(Error.Text)

END

PUBLIC SUB btnRun_Click()

  DIM rData AS Result
  DIM hForm AS FRequest
  
  rData = $hConn.Exec(txtRequest.Text)
  hForm = NEW FRequest($hConn, rData)
  hForm.Show

CATCH

  Message.Error(Error.Text)

END

PUBLIC SUB Form_Open()

  $hConn = NEW Connection

END

PUBLIC SUB Form_Close()

  $hConn.Close

END