genfixregs.awk

C++ 编写的EROS RTOS

#
# Copyright (C) 1998, 1999, Jonathan S. Shapiro.
#
# This file is part of the EROS Operating System.
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2,
# or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
#

# program to generate fixregs.h from LAYOUT file

BEGIN {
  nmask = 0;
  nfx = 0;
  nunit = 0;
}

/^mask/ {
  thismask = (2 ** $4);
  width = $5;

  value = 0;
  
#  print "thismask " thismask " width " width;
  for (i = 0; i < width; i++) {
    value += thismask;
    thismask *= 2;
  }

#  print "value " value;
  
  mask[nmask] = sprintf("#define MASK_%s_%-16s  0x%08xu\n", $2, $3, value);
  maskshift[nmask] = sprintf("#define SHIFT_%s_%-16s 0x%08xu\n", $2, $3, $4);
  nmask++;
}  

/^fix/	{
  fix[nfx] = sprintf("  %-10s %s;\n", $5, $2);
  nfx++;
}

/^unit/	{
  unit[nunit] = sprintf("#define UNIT_%-18s 0x%xu\n", $2, 2**nunit);
  nunit++;
}

END	{
  printf("#ifndef __FIXREGS_H__\n");	
  printf("#define __FIXREGS_H__\n\n");	

  printf("/* This file is automatically generated and is hereby\n");
  printf("   placed in the public domain */\n\n");

  for (i = 0; i < nunit; i++)
    printf(unit[i]);

  printf("\n");

  for (i = 0; i < nmask; i++)
    printf(mask[i]);

  printf("\n");

  for (i = 0; i < nmask; i++)
    printf(maskshift[i]);
    
  printf("\ntypedef struct fixregs_t {\n");	

  for (i = 0; i < nfx; i++)
    printf(fix[i]);

  printf("} fixregs_t;\n");

  printf("\n#endif /* __FIXREGS_H__ */\n");	
}