📄 startup.s
字号:
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;CPSR 寄存器 设置;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Standard definitions[定义]of Mode bits and Interrupt (I & F) flags in PSRs [PSRS寄存器]
; PSRs寄存器的模式位和中断标志（I&F）位的标准定义; [注：在周立功的书定义为PSR又叫CPSR]定义如下:
; 31 30 29 28 27 26 25 24 23......8 7 6 5 4 3 2 1 0
; N Z C V I F T M4 M3 M2 M1 M0
; N=负或小于0 Z=零 C=进位/借位
; M4,M3,M2,M1,M0
; 10000=用户模式
; 10001=快速中断模式
; 10010=通用中断模式
; 10011=操作系统保护模式
; 10111=支持虚拟内存或存贮保护模式（中止，对ARM7没什么用）
; 11011=支持硬件协处理器的软件仿真（未定义）
; 11111=操作系统的特权任务
I_Bit EQU 0x80 ;when I bit is set, IRQ is disabled[禁止]
F_Bit EQU 0x40 ; when F bit is set, FIQ is disabled
Mode_USR EQU 0x10 ;用户模式
Mode_FIQ EQU 0x11 ;FIQ 模式
Mode_IRQ EQU 0x12 ;IRQ 模式
Mode_SVC EQU 0x13 ;
Mode_ABT EQU 0x17 ;
Mode_UND EQU 0x1B ;未定义
Mode_SYS EQU 0x1F ;系统模式
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;堆 栈 设 置;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;定义堆栈的大小
UND_Stack_Size EQU 0x00000000
SVC_Stack_Size EQU 0x00000008
ABT_Stack_Size EQU 0x00000000
FIQ_Stack_Size EQU 0x00000000
IRQ_Stack_Size EQU 0x00000100
USR_Stack_Size EQU 0x00000400
Stack_Size EQU (UND_Stack_Size + SVC_Stack_Size + ABT_Stack_Size + \
FIQ_Stack_Size + IRQ_Stack_Size + USR_Stack_Size)
AREA STACK, NOINIT, READWRITE, ALIGN=3
Stack_Mem SPACE Stack_Size
Stack_Top EQU Stack_Mem + Stack_Size
Heap_Size EQU 0x00000000
AREA HEAP, NOINIT, READWRITE, ALIGN=3
Heap_Mem SPACE Heap_Size
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;VPBDIV分频器设置;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; VPBDIV分频器，仅1：0两位有效
; 00=VPB总线时钟为处理器的1/4
; 01=VPB总线时钟与处理器的相同
; 10=VPB总线时钟为处理器的1/2
; 11=保留，写入此值无效，保持先前的值
VPBDIV EQU 0xE01FC100 ; VPBDIV 地址
VPBDIV_SETUP EQU 1
VPBDIV_Val EQU 0x00000001
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;PLL锁相环设置;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;PLL接收时钟为10~25MHz，由倍频器将之倍频后再由分频器分频到想要工作频率，即处理器频率
;PLLCON寄存器控制激活
;PLLCFG寄存器控制倍频和分频
;PLLSTAT状态寄存器
;PLLFEED馈送寄存器
;PLLCON基地址为0xE01FC080,其它三个地址依次排列地址间隔为4
PLL_BASE EQU 0xE01FC080 ; PLL 基地址
PLLCON_OFS EQU 0x00 ; PLL Control Offset
PLLCFG_OFS EQU 0x04 ; PLL Configuration Offset
PLLSTAT_OFS EQU 0x08 ; PLL Status Offset
PLLFEED_OFS EQU 0x0C ; PLL Feed Offset
;令处理时钟为Fc,倍频M,分频为P,原始时钟为Fs,倍频后的时钟为Fo
;时钟的计算公式:Fc=Fs * M;且Fc=Fo/2P. [注意Fo在156M~320M之间],Fo=Fs * M * 2 * P
;操作顺序
;---使能PLL;PLLCON_PLLE=1;
; ---设置M和P，即PLLCFG=P<<5 | M;
; ---发送馈送序列PLLFEED=0xAA;PLLFEED=0x55,
; ---等待PLL锁定while(!(PLLSTAT_PLOCK)){;}
; ---使能并连接PLLCON=3
; ---发送馈送序列PLLFEED=0xAA;PLLFEED=0x55,
;PLLCON的0位PLLE使能，1位PLLC连接
;M位于PPLCFG4：0位 M=[想得到的时钟]/[晶振时钟]-1 ;之所以减去1是因为0表示1，1表示2，3表示4....
;P位于PPLCFG6：5位 P=[倍频时钟]/[2*想得到的时钟]-1，但时[倍频时钟]在156M~320M之间，减1与M相同
;PLLSTAT的M与P位与PLLCFG相同，8位PLLE，9位PLLC，10位PLOCK[锁定状态1为锁定否则未锁定]，其它的保留
;PLLFEED连续写入0xAA,0x55才能使PLLCON,PLLCFG起着用。
PLLCON_PLLE EQU (1<<0) ; PLL Enable
PLLCON_PLLC EQU (1<<1) ; PLL Connect
PLLCFG_MSEL EQU (0x01<<0) ; PLL Multiplier
PLLCFG_PSEL EQU (0x03<<5) ; PLL Divider
PLLSTAT_PLOCK EQU (1<<10) ; PLL Lock Status
PLL_SETUP EQU 1
PLLCFG_Val EQU 0x00000024
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;存储加速器设置;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Memory Accelerator Module (MAM) definitions
MAM_BASE EQU 0xE01FC000 ; MAM Base Address
MAMCR_OFS EQU 0x00 ; MAM Control Offset
MAMTIM_OFS EQU 0x04 ; MAM Timing Offset
MAM_SETUP EQU 1
MAMCR_Val EQU 0x00000002
MAMTIM_Val EQU 0x00000004
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;程 序 真 正 入 口;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
AREA RESET, CODE, READONLY
ARM
; Exception Vectors ====Vectors异常
; Mapped to Address 0.===映射地址为0
; Absolute addressing mode must be used.====必须用绝对地址模式
; Dummy Handlers are implemented as infinite loops which can be modified.====执行无穷循环的伪句柄被以修改
Vectors LDR PC, Reset_Addr
LDR PC, Undef_Addr
LDR PC, SWI_Addr
LDR PC, PAbt_Addr
LDR PC, DAbt_Addr
NOP ; Reserved Vector
; LDR PC, IRQ_Addr
LDR PC, [PC, #-0x0FF0] ; Vector from VicVectAddr
LDR PC, FIQ_Addr
Reset_Addr DCD Reset_Handler
Undef_Addr DCD Undef_Handler
SWI_Addr DCD SWI_Handler
PAbt_Addr DCD PAbt_Handler
DAbt_Addr DCD DAbt_Handler
DCD 0 ; Reserved Address
IRQ_Addr DCD IRQ_Handler
FIQ_Addr DCD FIQ_Handler
Undef_Handler B Undef_Handler
SWI_Handler B SWI_Handler
PAbt_Handler B PAbt_Handler
DAbt_Handler B DAbt_Handler
IRQ_Handler B IRQ_Handler
FIQ_Handler B FIQ_Handler
; 复位句柄
EXPORT Reset_Handler
Reset_Handler
; 设置VPBDIV
IF VPBDIV_SETUP <> 0
LDR R0, =VPBDIV
LDR R1, =VPBDIV_Val
STR R1, [R0]
ENDIF
; 设置PLL
IF PLL_SETUP <> 0
LDR R0, =PLL_BASE
MOV R1, #0xAA
MOV R2, #0x55
; Configure and Enable PLL
MOV R3, #PLLCFG_Val
STR R3, [R0, #PLLCFG_OFS]
MOV R3, #PLLCON_PLLE
STR R3, [R0, #PLLCON_OFS]
STR R1, [R0, #PLLFEED_OFS]
STR R2, [R0, #PLLFEED_OFS]
; Wait until PLL Locked
PLL_Loop LDR R3, [R0, #PLLSTAT_OFS]
ANDS R3, R3, #PLLSTAT_PLOCK
BEQ PLL_Loop
; Switch to PLL Clock
MOV R3, #(PLLCON_PLLE:OR:PLLCON_PLLC)
STR R3, [R0, #PLLCON_OFS]
STR R1, [R0, #PLLFEED_OFS]
STR R2, [R0, #PLLFEED_OFS]
ENDIF ; PLL_SETUP
; 设置MAM
IF MAM_SETUP <> 0
LDR R0, =MAM_BASE
MOV R1, #MAMTIM_Val
STR R1, [R0, #MAMTIM_OFS]
MOV R1, #MAMCR_Val
STR R1, [R0, #MAMCR_OFS]
ENDIF ; MAM_SETUP
; 存贮器映射(当中断向量是在RAM里时)
MEMMAP EQU 0xE01FC040 ; Memory Mapping Control====映射控制
IF :DEF:REMAP
LDR R0, =MEMMAP
IF :DEF:RAM_MODE
MOV R1, #2
ELSE
MOV R1, #1
ENDIF
STR R1, [R0]
ENDIF
; 初始化中断系统
; ...
; 为每个模式设置堆栈
LDR R0, =Stack_Top
; 进入未定义指令模式并设置其指
MSR CPSR_c, #Mode_UND:OR:I_Bit:OR:F_Bit
MOV SP, R0
SUB R0, R0, #UND_Stack_Size
; 进入Abort模式并设置其指
MSR CPSR_c, #Mode_ABT:OR:I_Bit:OR:F_Bit
MOV SP, R0
SUB R0, R0, #ABT_Stack_Size
; 进入FIQ模式并设置其指针
MSR CPSR_c, #Mode_FIQ:OR:I_Bit:OR:F_Bit
MOV SP, R0
SUB R0, R0, #FIQ_Stack_Size
; 进入IRQ模式并设置其指针
MSR CPSR_c, #Mode_IRQ:OR:I_Bit:OR:F_Bit
MOV SP, R0
SUB R0, R0, #IRQ_Stack_Size
; 进入管理模式并设置其指针
MSR CPSR_c, #Mode_SVC:OR:I_Bit:OR:F_Bit
MOV SP, R0
SUB R0, R0, #SVC_Stack_Size
; 进入用户模式和设置其堆栈指针
MSR CPSR_c, #Mode_USR
MOV SP, R0
SUB SL, SP, #USR_Stack_Size
; 进入C程序
IMPORT __main
LDR R0, =__main
BX R0
; 用户初始化堆栈
AREA |.text|, CODE, READONLY
IMPORT __use_two_region_memory
EXPORT __user_initial_stackheap
__user_initial_stackheap
LDR R0, = Heap_Mem
LDR R1, =(Stack_Mem + USR_Stack_Size)
LDR R2, = (Heap_Mem + Heap_Size)
LDR R3, = Stack_Mem
BX LR
END⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -