hup.inetd

伯克利做的SFTP安全文件传输协议

#! /bin/csh -f
# script to send the HUP signal to inetd, which causes it
#   to re-read /etc/inetd.conf (its configuration file)
# assumes the existence of psall, a script to get the
#   list of processes
# Note: Inetd often has to be hup'ed at least twice when it
#   must rebind ports, due to TCP un-listen semantics.

# in SafeTP, this script lives in the same directory as psall
set path = ($path .)

# make up a temporary file name (the '$$' expands to current pid)
set tmp = /tmp/hup.inetd.temp.$$

# find the pid of the inetd process
psall | grep inetd | grep root | grep -v grep | grep -v hup.inetd > $tmp
if ( `wc -l < $tmp` == "0" ) then
  echo "error: I didn't find any process that appears to be"
  echo "       inetd.  Maybe the psall script isn't working?"
  rm $tmp
  exit 2
endif

if ( `wc -l < $tmp` != "1" ) then
  echo "error: I am confused as to which of these is inetd:"
  cat $tmp
  # don't remove tmp because it may be useful diagnostically
  exit 2
endif

set line = `cat $tmp`
set pidtokill = ${line[2]}
echo sending HUP to process $pidtokill

if ( ! { kill -HUP $pidtokill } ) then
# hopefully 'kill' already reported the failure
  exit 2
endif
rm $tmp