📄 reg.asp

📁 正版创力4.1SQL商业版!!!ASP版。
💻 ASP
字号:
<!--#include file="Setting.asp"-->
<!--#include file="../Inc/Cl_Md5.asp"-->
<%
Dim Action
Action = Lcase(Trim(request("Action")))
Select Case Action
Case "save","savemodify"
	Reg_Save
Case Else
	Reg_Main
End Select
Response.write Template.ReplaceAllFlag(TempStr)
CloseAllObj

Sub Reg_Main()
	Dim Rs,SQL
	Dim ID,ClassID,LinkType,SiteName,SiteUrl,LogoUrl,SiteAdmin,Email,SiteIntro
	ID = Cl.GetClng(Request("ID"))
	If Action = "modify" Then
		Set Rs=Cl.Execute("select * from Cl_LinkSite where ID=" & ID)
		if Rs.bof and Rs.eof then
			Rs.close : set Rs=Nothing
			Call Cl.OutErr(0,"<br /><li>找不到指定的站点！</li>")
		end If
		LinkType		= Rs("LinkType")
		ClassID			= Rs("ClassID")
		SiteName		= Server.HTMLEnCode(Rs("SiteName"))
		SiteUrl			= Server.HTMLEnCode(Rs("SiteUrl"))
		LogoUrl			= Server.HTMLEnCode(Rs("LogoUrl"))
		SiteAdmin		= Server.HTMLEnCode(Rs("SiteAdmin"))
		Email			= Server.HTMLEnCode(Rs("Email"))
		SiteIntro		= Server.HTMLEnCode(Rs("SiteIntro"))
		Rs.close : set Rs=Nothing
	Else
		if Cl.Web_Setting(12)="No" then Call Cl.OutErr(0,"<br /><li>管理员没有开放友情链接申请！</li>")
		LinkType		= 1
		ClassID			= 0
		SiteName		= ""
		SiteUrl			= "http://"
		LogoUrl			= "http://"
		SiteAdmin		= ""
		Email			= ""
		SiteIntro		= ""
	End if
	TempStr = Template.Read(TemplateReg)
	TempStr = Replace(TempStr,"{$ShowLinkClass_Option}",ShowLinkClass_Option(0,0))
	TempStr = Replace(TempStr,"{$LinkType}",LinkType)
	TempStr = Replace(TempStr,"{$SiteName}",SiteName)
	TempStr = Replace(TempStr,"{$SiteUrl}",SiteUrl)
	TempStr = Replace(TempStr,"{$LogoUrl}",LogoUrl)
	TempStr = Replace(TempStr,"{$SiteAdmin}",SiteAdmin)
	TempStr = Replace(TempStr,"{$Email}",Email)
	TempStr = Replace(TempStr,"{$SiteIntro}",SiteIntro)
	TempStr = Replace(TempStr,"{$isshowcode}",LCase(Cl.Web_Setting(42)))
	If LCase(Cl.Web_Setting(42))="yes" then
		TempStr = Replace(TempStr,"{$getcode}",Replace(Cl.GetCode("LinkRegCode"),Chr(34),"\"&Chr(34)))
	Else
		TempStr = Replace(TempStr,"{$getcode}","")
	End If
	TempStr = Replace(TempStr,"{$ID}",ID)
	TempStr = Replace(TempStr,"{$action}",Action)
End Sub

Sub Reg_Save()
	Dim Rs,SQL
	Dim ID,LinkType,ClassID,SiteName,SiteUrl,LogoUrl,SiteAdmin,Email,SiteIntro
	Dim OldSitePassword,SitePassword,SitePwdConfirm,LinkRegCode
	LinkType		= Cl.GetClng(request("LinkType"))
	ClassID			= Cl.GetClng(request("ClassID"))
	SiteName		= Trim(request("SiteName"))
	SiteUrl			= Trim(request("SiteUrl"))
	LogoUrl			= Trim(request("LogoUrl"))
	SiteAdmin		= Trim(request("SiteAdmin"))
	Email			= Trim(request("Email"))
	OldSitePassword	= Trim(request("OldSitePassword"))
	SitePassword	= Trim(request("SitePassword"))
	SitePwdConfirm	= Trim(request("SitePwdConfirm"))
	SiteIntro		= Trim(request("SiteIntro"))
	LinkRegCode		= Trim(request("LinkRegCode"))
	if Cl.Web_Setting(42)="Yes" and Not Cl.CodeIsTrue(LinkRegCode,"LinkRegCode") then
		Call Cl.OutMsg(0,"<br /><li>验证码检验失败！</li>","-1")
	end If
	If Action="save" Then
		if Cl.Web_Setting(12)="No" then Call Cl.OutErr(0,"<br /><li>管理员没有开放友情链接申请！</li>")
		if Session("RegLingSite")="OK" then
			Call Cl.OutMsg(0,"你已经申请过，请不要重复申请！","Index.asp")
		end if
		if SitePassword="" then
			Call Cl.OutMsg(0,"<br /><li>网站密码不能为空！</li>","-1")
		end if
	Else
		if OldSitePassword="" then
			Call Cl.OutMsg(0,"<br /><li>旧网站密码不能为空！</li>","-1")
		end if
	End If
	If LinkType<>1 And LinkType<>2 Then LinkType = 1
	if LinkType=1 and (LogoUrl="" or LogoUrl="http://") then
		Call Cl.OutMsg(0,"<br /><li>网站LOGO不能为空！</li>","-1")
	end if
	if SiteName="" then
		Call Cl.OutMsg(0,"<br /><li>网站名称不能为空！</li>","-1")
	end if
	if SiteUrl="" then
		Call Cl.OutMsg(0,"<br /><li>网站地址不能为空！</li>","-1")
	end if
	if SiteAdmin="" then
		Call Cl.OutMsg(0,"<br /><li>管理员姓名不能为空！</li>","-1")
	end if
	if Email="" then
		Call Cl.OutMsg(0,"<br /><li>Email不能为空！</li>","-1")
	else
		if Cl.ChkEmail(Email)=false then
			Call Cl.OutMsg(0,"<br /><li>Email地址错误!</li>","-1")
		end If
	end if
	if SitePwdConfirm<>SitePassword then
		Call Cl.OutMsg(0,"<br /><li>新网站密码与确认密码不一致！</li>","-1")
	end if
	if SiteIntro="" then
		Call Cl.OutMsg(0,"<br /><li>网站简介不能为空！</li>","-1")
	end If
	If Action="modify" then
		SQL = "select * from Cl_LinkSite where ID=" & CLng(ID)
		set Rs = Server.CreateObject("Adodb.RecordSet")
		OpenConn : Rs.open SQL,Conn,1,3
		if Rs.bof and Rs.eof then
			Rs.close:set Rs=Nothing
			Call Cl.OutErr(0,"<br /><li>找不到站点！</li>")
		end if
		if Md5(OldSitePassword,16)<>Rs("SitePassword") then
			Rs.close:set Rs=Nothing
			Call Cl.OutErr(0,"<br /><li>你输入的旧网站密码不对，没有权限修改！</li>")
		end If
		if SitePassword<>"" then
			Rs("SitePassword") = Md5(SitePassword,16)
		end if
	Else
		SQL = "select top 1 * from Cl_LinkSite where SiteName='" & Cl.CheckStr(SiteName) & "' and SiteUrl='" & Cl.CheckStr(SiteUrl) & "'"
		set Rs=Server.CreateObject("Adodb.RecordSet")
		OpenConn : Rs.open SQL,Conn,1,3
		if not (Rs.bof and Rs.eof) then
			Rs.close:set Rs=Nothing
			Call Cl.OutErr(0,"<br /><li>你申请的网站已经存在！请不要重复申请！</li>")
		End if
		Rs.Addnew
		Rs("OrderID")	= GetLinkOrderID
		Rs("SitePassword") = Md5(SitePassword,16)
	End If
	Rs("LinkType")	= LinkType
	Rs("ClassID")	= ClassID
	Rs("SiteName")	= SiteName
	Rs("SiteUrl")	= SiteUrl
	Rs("LogoUrl")	= LogoUrl
	Rs("SiteAdmin")	= SiteAdmin
	Rs("Email")		= Email
	Rs("SiteIntro")	= SiteIntro
	Rs("IsGood")	= False
	Rs("IsOK")		= False
	Rs("IsIndex")	= 0
	Rs.update
	Rs.close : set Rs=Nothing
	If Action="modify" Then
		Call Cl.OutMsg(0,"修改友情链接成功！请等待管理员审核通过。","Index.asp")
	Else
		Session("RegLingSite")="OK"
		Call Cl.OutMsg(0,"申请友情链接成功！请等待管理员审核通过。","Index.asp")
	End if
End Sub

Function ShowLinkClass_Option(ShowType,CurrentID)
	dim rsClass,sqlClass,strTemp,tmpDepth,i
	if ShowType=0 then
		strTemp="<option value='0'"
		if CurrentID=0 then strTemp=strTemp & " selected"
		strTemp=strTemp & ">不指定分类</option>"
	end if
	dim arrShowLine(20)
	for i=0 to ubound(arrShowLine)
		arrShowLine(i)=False
	next
	sqlClass="Select * From Cl_LinkClass order by RootID,OrderID"
	set rsClass=Cl.Execute(sqlClass)
	if rsClass.bof and rsClass.eof then
		strTemp=strTemp & "<option value=''>无任何分类</option>"
	else
		do while not rsClass.eof
			tmpDepth=rsClass("Depth")
			if rsClass("NextID")>0 then
				arrShowLine(tmpDepth)=True
			else
				arrShowLine(tmpDepth)=False
			end if
			if ShowType=2 then
				if Not Cl.ChkUserGroupID(rsClass("AddPurview"),Cl.UserGroupID) then
					strTemp=strTemp & "<option value='-1'"
				else
					strTemp=strTemp & "<option value='" & rsClass("ClassID") & "'"
				end if
			else
				strTemp=strTemp & "<option value='" & rsClass("ClassID") & "'"
			end if
			if CurrentID>0 and rsClass("ClassID")=CurrentID then
				 strTemp=strTemp & " selected"
			end if
			strTemp=strTemp & ">"
			if tmpDepth>0 then
				for i=1 to tmpDepth
					strTemp=strTemp & "&nbsp;&nbsp;"
					if i=tmpDepth then
						if rsClass("NextID")>0 then
							strTemp=strTemp & "├&nbsp;"
						else
							strTemp=strTemp & "└&nbsp;"
						end if
					else
						if arrShowLine(i)=True then
							strTemp=strTemp & "│"
						else
							strTemp=strTemp & "&nbsp;"
						end if
					end if
				next
			end if
			strTemp=strTemp & rsClass("ClassName")
			if ShowType=2 and Not Cl.ChkUserGroupID(rsClass("AddPurview"),Cl.UserGroupID) then
				strTemp=strTemp & " *"
			end if
			strTemp=strTemp & "</option>"
			rsClass.movenext
		loop
	end if
	rsClass.close:set rsClass=Nothing
	ShowLinkClass_Option=strTemp
End Function

Function GetLinkOrderID()
	Dim strOrderID,i
	Dim Rs
	Set Rs=Cl.Execute("select Max(OrderID) from Cl_LinkSite")
	strOrderID=rs(0)
	if Not Isnumeric(strOrderID) then strOrderID=0
	if strOrderID<5 then
		GetLinkOrderID=5
	else
		For i=5 to strOrderID
			Set rs=Cl.Execute("select ID,OrderID from Cl_LinkSite where OrderID="&Clng(i)&"")
			if rs.bof and rs.eof then
				strOrderID=i
				Exit for
			end if
		Next
		GetLinkOrderID=strOrderID
	end if
	Set Rs=Nothing
End Function
%>
<%
'==================================================
'CreateLive CMS Version 4.0
'							Powered by Aspoo.Net
'
'邮箱: support@aspoo.cn		Info@aspoo.cn
'ＱＱ: 3315263				596197794
'网站: www.aspoo.cn			www.aspoo.com
'论坛: bbs.aspoo.cn			bbs.aspoo.com
'
'Copyright (C) 2005-2007 Aspoo.Net All Rights Reserved.
'==================================================
%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -