list.asp

正版创力4.1SQL商业版!!!ASP版。

<!--#include file="../Conn.asp"-->
<!--#include file="../Inc/Cl_Const.asp"-->
<!--#include file="../Inc/Cl_Function_Public.asp"-->
<%
Const ChannelID=0

Cl.Path = Cl.Language.selectSingleNode("//CurrentPath").text & "<a href='" & Cl.Web_info(4) & "'>" & Cl.Web_info(0) & "</a> &gt;&gt; 用户列表"
Cl.Title= Cl.Web_info(1) & " &gt;&gt; 用户列表"

Dim OrderType
OrderType	=Cl.GetClng(request("OrderType"))
if OrderType=0 Then OrderType=1
FileName = "List.asp?OrderType=" & OrderType

Call ShowUserList()

Response.write Template.ReplaceAllFlag(TempStr)

'分页显示所有用户
Sub ShowUserList()
	Dim rsUser,sqlUser,sTemp,i,UserIM
	Dim sHTML,sContentHTML,ListHTML,LoopStr,ReplaceStr

	Call Template.Load(-2,11)
	TempStr		= Template.Html
	LoopStr		= Template.GetPartContent(TempStr,"[Cl_Loop]","[/Cl_Loop]")
	ReplaceStr	= "[Cl_Loop]" & LoopStr & "[/Cl_Loop]"

	Rem 查询用户列表
	sqlUser = "select " & Db.UserID & "," & Db.UserName & ","&Db.UserReName&"," & Db.UserEmail & "," & Db.UserSex & "," & Db.UserFace & "," & Db.UserFaceWidth & "," & Db.UserFaceHeight & "," & Db.UserIM & "," & Db.UserJoinDate & "," & Db.UserLastLogin & "," & Db.UserLogins & "," & Db.UserLastIP & "," & Db.DataCount & "," & Db.UserGroupID & "," & Db.UserPoint & "," & Db.UserMoney & "," & Db.ChargeType & "," & Db.BeginDate & "," & Db.ValidNum & "," & Db.UserLock & " from " & Db.UserTable & ""
	select case OrderType
	case 1 : sqlUser = sqlUser & " order by " & Db.DataCount & " desc"
	case 2 : sqlUser = sqlUser & " order by " & Db.UserJoinDate & " desc"
	case 3 : sqlUser = sqlUser & " order by UserID desc"
	end select
	set rsUser=Cl.Execute(sqlUser)
	if rsUser.bof and rsUser.eof then
		TotalPut=0
		sContentHTML = ""
	else
		Dim rsTotalPut
		Set rsTotalPut= Cl.Execute_U("Select count(" & Db.UserID & ") from " & Db.UserTable & "")
		TotalPut = rsTotalPut(0)
		rsTotalPut.Close : Set rsTotalPut=Nothing
		if (TotalPut mod PageSize)=0 then
			TotalPages = TotalPut \ PageSize
		else
			TotalPages = TotalPut \ PageSize + 1
		end if
		if CurrentPage > TotalPages then CurrentPage=TotalPages
		if CurrentPage < 2 Then
			CurrentPage=1
		else
			rsUser.move (CurrentPage-1)*PageSize
		End if
		For i=1 To PageSize
			UserIM = Split(rsUser(Db.UserIM),"|||")
			sTemp = LoopStr
			sTemp = Replace(sTemp,"{$userid}",rsUser(Db.UserID))
			sTemp = Replace(sTemp,"{$username}",rsUser(Db.UserName))
			sTemp = Replace(sTemp,"{$usersex}",Cl.GetUsersex(rsUser(Db.UserSex)))
			sTemp = Replace(sTemp,"{$useremail}",rsUser(Db.UserEmail))
			sTemp = Replace(sTemp,"{$userqq}",UserIM(1))
			sTemp = Replace(sTemp,"{$usermsn}",UserIM(3))
			sTemp = Replace(sTemp,"{$userhomepage}",UserIM(0))
			sTemp = Replace(sTemp,"{$userjoindage}",rsUser(Db.UserJoinDate)&"")
			sTemp = Replace(sTemp,"{$datacount}",rsUser(Db.DataCount))
			sTemp = Replace(sTemp,"{$userdatanum}",rsUser(Db.DataCount))
			UserIM = Empty
			sContentHTML = sContentHTML & sTemp
			rsUser.movenext
			if rsUser.Eof Then Exit For
		Next
	end if
	rsUser.close:set rsUser=Nothing
	TempStr=Replace(TempStr,ReplaceStr,sContentHTML)
	if TotalPut>0 then
		TempStr = Replace(TempStr,"{$showpage}",Cl.ShowPage(FileName,TotalPut,PageSize,"个","用户"))
	else
		TempStr = Replace(TempStr,"{$showpage}","")
	end if
End Sub
%>
<%
'===================================================
' CreateLive CMS Version 4.0
'							Powered by Aspoo.CoM
'===================================================
' Mail: [e-mail], [e-mail]
' Q  Q: 3315263, 596197794
' Msn : [e-mail], [e-mail]
' Web : http://www.aspoo.com, http://www.aspoo.net
' Bbs : http://bbs.aspoo.com, http://bbs.aspoo.net
' Copyright (C) 2005-2007 Aspoo.CoM All Rights Reserved.
'===================================================
%>