datagridcombobox.vb

VB.NET开发的进销存系统,数据库SQLSERVER

Option Strict On
Option Explicit On 
Imports System.Collections
Imports System.ComponentModel
Imports System.Drawing
Imports System.Windows.Forms
Imports System.Data

Public Class DataGridComboBox
    '与DataGridTextBox类相类似地定义一个在下拉框列类中使用的ComboBox
    Inherits ComboBox
    Public Sub New()
        MyBase.New()
        Me.DropDownStyle = ComboBoxStyle.DropDownList
    End Sub
    Public isInEditOrNavigateMode As Boolean = True
End Class
Public Class DataGridComboBoxColumn
    Inherits DataGridColumnStyle
    ' 与用户界面相关的变量    
    Private xMargin As Integer = 2
    Private yMargin As Integer = 1
    Private Combo As DataGridComboBox
    Private _DisplayMember As String
    Private _ValueMember As String
    ' 用于跟踪编辑状态变化的变量
    Private OldVal As String = String.Empty
    Private InEdit As Boolean = False
    '构造函数 – 实例的DisplayMember, ValueMember值为由父类传来的integer类型的值
    Public Sub New(ByRef DataSource As DataTable,ByVal DisplayMember As Integer,ByVal ValueMember As Integer)
        Combo = New DataGridComboBox
        _DisplayMember = DataSource.Columns.Item(index:=DisplayMember).ToString
        _ValueMember = DataSource.Columns.Item(index:=ValueMember).ToString
        With Combo
            .Visible = False
            .DataSource = DataSource
            .DisplayMember = _DisplayMember
            .ValueMember = _ValueMember
        End With
    End Sub
    '构造函数– 实例的DisplayMember, ValueMember 是String类型的值
    Public Sub New(ByRef DataSource As DataTable,ByVal DisplayMember As String,ByVal ValueMember As String)
        Combo = New DataGridComboBox
        With Combo
            .Visible = False
            .DataSource = DataSource
            .DisplayMember = DisplayMember
            .ValueMember = ValueMember
        End With
    End Sub
    '------------------------------------------------------

    '从 DataGridColumnStyle类继承下来的方法

    '------------------------------------------------------

    ' 焦点离开combobox格后的改变
    Protected Overloads Overrides Sub Abort(ByVal RowNum As Integer)
        Debug.WriteLine("Abort()")
        RollBack()
        HideComboBox()
        EndEdit()
    End Sub

    ' 接受改变
    Protected Overloads Overrides Function Commit(ByVal DataSource As CurrencyManager, ByVal RowNum As Integer) As Boolean
        HideComboBox()
        If Not InEdit Then
            Return True
        End If
        Try
            Dim Value As Object = Combo.SelectedValue
            If NullText.Equals(Value) Then
                Value = Convert.DBNull
            End If
            SetColumnValueAtRow(DataSource, RowNum, Value)
        Catch e As Exception
            RollBack()
            Return False
        End Try
        EndEdit()
        Return True
    End Function
    ' 移开聚焦
    Protected Overloads Overrides Sub ConcedeFocus()
        Combo.Visible = False
    End Sub
    ' 编辑单元格
    Protected Overloads Overrides Sub Edit(ByVal Source As CurrencyManager, ByVal Rownum As Integer, ByVal Bounds As Rectangle, ByVal [ReadOnly] As Boolean, ByVal InstantText As String, ByVal CellIsVisible As Boolean)
        Combo.Text = String.Empty
        Dim OriginalBounds As Rectangle = Bounds
        OldVal = Combo.Text
        If CellIsVisible Then
            Bounds.Offset(xMargin, yMargin)
            Bounds.Width -= xMargin * 2
            Bounds.Height -= yMargin
            Combo.Bounds = Bounds
            Combo.Visible = True
        Else
            Combo.Bounds = OriginalBounds
            Combo.Visible = False
        End If
        Combo.SelectedValue = GetText(GetColumnValueAtRow(Source, Rownum))
        If Not InstantText Is Nothing Then
            Combo.SelectedValue = InstantText
        End If
        Combo.RightToLeft = Me.DataGridTableStyle.DataGrid.RightToLeft
        Combo.Focus()
        If InstantText Is Nothing Then
            Combo.SelectAll()
        Else
            Dim [End] As Integer = Combo.Text.Length
            Combo.Select([End], 0)
        End If
        If Combo.Visible Then
            DataGridTableStyle.DataGrid.Invalidate(OriginalBounds)
        End If
        InEdit = True
    End Sub
    Protected Overloads Overrides Function GetMinimumHeight() As Integer
        ' 设置combobox的最小高度
        Return Combo.PreferredHeight + yMargin
    End Function
    Protected Overloads Overrides Function GetPreferredHeight(ByVal g As Graphics, ByVal Value As Object) As Integer
        Debug.WriteLine("GetPreferredHeight()")
        Dim NewLineIndex As Integer = 0
        Dim NewLines As Integer = 0
        Dim ValueString As String = Me.GetText(Value)
        Do
            While NewLineIndex <> -1
                NewLineIndex = ValueString.IndexOf("r\n", NewLineIndex + 1)
                NewLines += 1
            End While
        Loop
        Return FontHeight * NewLines + yMargin
    End Function
    Protected Overloads Overrides Function GetPreferredSize(ByVal g As Graphics, ByVal Value As Object) As Size
        Dim Extents As Size = Size.Ceiling(g.MeasureString(GetText(Value), Me.DataGridTableStyle.DataGrid.Font))
        Extents.Width += xMargin * 2 + DataGridTableGridLineWidth
        Extents.Height += yMargin
        Return Extents
    End Function
    Protected Overloads Overrides Sub Paint(ByVal g As Graphics, ByVal Bounds As Rectangle, ByVal Source As CurrencyManager, ByVal RowNum As Integer)
        Paint(g, Bounds, Source, RowNum, False)
    End Sub
    Protected Overloads Overrides Sub Paint(ByVal g As Graphics, ByVal Bounds As Rectangle, ByVal Source As CurrencyManager, ByVal RowNum As Integer, ByVal AlignToRight As Boolean)
        Dim Text As String = GetText(GetColumnValueAtRow(Source, RowNum))
        PaintText(g, Bounds, Text, AlignToRight)
    End Sub
    Protected Overloads Sub Paint(ByVal g As Graphics, ByVal Bounds As Rectangle, ByVal Source As CurrencyManager, ByVal RowNum As Integer, ByVal BackBrush As Brush, ByVal ForeBrush As Brush, ByVal AlignToRight As Boolean)
        Dim Text As String = GetText(GetColumnValueAtRow(Source, RowNum))
        PaintText(g, Bounds, Text, BackBrush, ForeBrush, AlignToRight)
    End Sub
    Protected Overloads Overrides Sub SetDataGridInColumn(ByVal Value As DataGrid)
        MyBase.SetDataGridInColumn(Value)
        If Not (Combo.Parent Is Value) Then
            If Not (Combo.Parent Is Nothing) Then
                Combo.Parent.Controls.Remove(Combo)
            End If
        End If
        If Not (Value Is Nothing) Then Value.Controls.Add(Combo)
    End Sub
    Protected Overloads Overrides Sub UpdateUI(ByVal Source As CurrencyManager, ByVal RowNum As Integer, ByVal InstantText As String)
        Combo.Text = GetText(GetColumnValueAtRow(Source, RowNum))
        If Not (InstantText Is Nothing) Then
            Combo.Text = InstantText
        End If
    End Sub
    '----------------------------------------------------------------------

    ' 辅助方法

    '----------------------------------------------------------------------
    Private ReadOnly Property DataGridTableGridLineWidth() As Integer
        Get
            If Me.DataGridTableStyle.GridLineStyle = DataGridLineStyle.Solid Then
                Return 1
            Else
                Return 0
            End If
        End Get
    End Property
    Private Sub EndEdit()
        InEdit = False
        Invalidate()
    End Sub
    Private Function GetText(ByVal Value As Object) As String
        If Value Is System.DBNull.Value Then Return NullText
        If Not Value Is Nothing Then
            Return Value.ToString
        Else
            Return String.Empty
        End If
    End Function
    Private Sub HideComboBox() '隐藏Combobox
        If Combo.Focused Then
            Me.DataGridTableStyle.DataGrid.Focus()
        End If
        Combo.Visible = False
    End Sub
    Private Sub RollBack()
        Combo.Text = OldVal
    End Sub
    Private Sub PaintText(ByVal g As Graphics, ByVal Bounds As Rectangle, ByVal Text As String, ByVal AlignToRight As Boolean)
        Dim BackBrush As Brush = New SolidBrush(Me.DataGridTableStyle.BackColor)
        Dim ForeBrush As Brush = New SolidBrush(Me.DataGridTableStyle.ForeColor)
        PaintText(g, Bounds, Text, BackBrush, ForeBrush, AlignToRight)
    End Sub
    Private Sub PaintText(ByVal g As Graphics, ByVal TextBounds As Rectangle, ByVal Text As String, ByVal BackBrush As Brush, ByVal ForeBrush As Brush, ByVal AlignToRight As Boolean)
        Dim Rect As Rectangle = TextBounds
        Dim RectF As RectangleF = RectF.op_Implicit(Rect) ' 转为RectangleF类型
        Dim Format As StringFormat = New StringFormat
        If AlignToRight Then
            Format.FormatFlags = StringFormatFlags.DirectionRightToLeft
        End If
        Select Case Me.Alignment
            Case Is = HorizontalAlignment.Left
                Format.Alignment = StringAlignment.Near
            Case Is = HorizontalAlignment.Right
                Format.Alignment = StringAlignment.Far
            Case Is = HorizontalAlignment.Center
                Format.Alignment = StringAlignment.Center
        End Select
        Format.FormatFlags = Format.FormatFlags Or StringFormatFlags.NoWrap
        g.FillRectangle(Brush:=BackBrush, Rect:=Rect)
        Rect.Offset(0, yMargin)
        Rect.Height -= yMargin
        g.DrawString(Text, Me.DataGridTableStyle.DataGrid.Font, ForeBrush, RectF, Format)
        Format.Dispose()
    End Sub
End Class