frmhwdbrc.frm

制造业产供销与往来系统源码,包括进销存及全部控件！

Dim mCurColOldValue As String
Dim mOldHwDbRcYear As String

Dim OHwDbRc As HwDbRc
Dim OHwDbRcs As HwDbRcs

Private Sub Flex_AfterEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long)
On Error GoTo Errorhandle

SetControlToFlex

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_BeforeEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, Cancel As Boolean)
On Error GoTo Errorhandle
   
   mCurColOldValue = Trim(Flex(FlexHwDbRc).TextMatrix(Flex(FlexHwDbRc).Row, Flex(FlexHwDbRc).Col))

   If Tlbaction(TlbHwDbRc).Tag = "" Then
      Cancel = True
   End If

   If Tlbaction(TlbHwDbRc).Tag <> "" Then
      Select Case Flex(FlexHwDbRc).ColKey(Col)
      Case "HWDBRCCODE"
            
      Case "HWDBRCMC"
            If OHwDbRc Is Nothing Then
               Cancel = True
            End If
            
      End Select
            
   End If

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_Click(Index As Integer)
On Error GoTo Errorhandle

   If Tlbaction(TlbHwDbRc).Tag = "" Then
      Exit Sub
   End If
   
   If OHwDbRc Is Nothing Then
      Exit Sub
   End If

   Select Case Index
   Case FlexHwDbRc
         If Flex(Index).Col = Flex(Index).ColIndex("HWDBRCISSTOP") Then
            If Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexHwDbRc).Col) = "" Then
               Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexHwDbRc).Col) = "√"
            Else
               Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexHwDbRc).Col) = ""
            End If
         End If
   End Select

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyDown(Index As Integer, KeyCode As Integer, Shift As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexKeyDown Flex(Index), KeyCode

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyDownEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, KeyCode As Integer, ByVal Shift As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexKeyDown Flex(Index), KeyCode

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyPressEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, KeyAscii As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexInputCheck Me, Flex(Index), KeyAscii

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_RowColChange(Index As Integer)
On Error GoTo Errorhandle

    Select Case Index
        Case FlexHwDbRc
            If Flex(Index).Rows > 2 And Flex(FlexHwDbRc).Row <> Flex(FlexHwDbRc).Rows - 1 Then
                Set OHwDbRc = OHwDbRcs(CStr(Flex(FlexHwDbRc).RowData(Flex(FlexHwDbRc).Row)))
            Else
                Set OHwDbRc = Nothing
            End If
    End Select
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub SetControlToFlex()
   Dim mCurCol As Integer
   Dim mCurRow As Integer
On Error GoTo Errorhandle

   If Tlbaction(TlbHwDbRc).Tag = "" Then
      Exit Sub
   End If
   
   mCurRow = Flex(FlexHwDbRc).Row
   mCurCol = Flex(FlexHwDbRc).Col
   
   Select Case Flex(FlexHwDbRc).ColKey(Flex(FlexHwDbRc).Col)
   Case "HWDBRCCODE"
         If OHwDbRc Is Nothing Then
            AddNewRecord
         Else
            OHwDbRc.HwDbRcCode = Trim(Flex(FlexHwDbRc).TextMatrix(mCurRow, mCurCol))
         End If
   
   Case "HWDBRCMC"
         If Not OHwDbRc Is Nothing Then
            OHwDbRc.HwDbRcMc = Trim(Flex(FlexHwDbRc).TextMatrix(mCurRow, mCurCol))
         End If
   
   End Select


Exit Sub
Errorhandle:
   Flex(FlexHwDbRc).TextMatrix(mCurRow, mCurCol) = mCurColOldValue
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddNewRecord()
On Error GoTo Errorhandle

   If Trim(Flex(FlexHwDbRc).TextMatrix(Flex(FlexHwDbRc).Row, Flex(FlexHwDbRc).Col)) <> "" Then
      Set OHwDbRc = New HwDbRc
      OHwDbRc.HwDbRcCode = Trim(Flex(FlexHwDbRc).TextMatrix(Flex(FlexHwDbRc).Row, Flex(FlexHwDbRc).Col))
      OHwDbRcs.Add OHwDbRc
      Flex(FlexHwDbRc).RowData(Flex(FlexHwDbRc).Rows - 1) = OHwDbRc.HwDbRc_Key
      Flex(FlexHwDbRc).AddItem ""
   End If

Exit Sub
Errorhandle:
   Set OHwDbRc = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Load()
On Error GoTo Errorhandle
   
   Flex(FlexHwDbRc).Editable = flexEDKbdMouse
   
   Flex(FlexHwDbRc).ColKey(1) = "HWDBRCCODE"
   Flex(FlexHwDbRc).ColKey(2) = "HWDBRCMC"
   Flex(FlexHwDbRc).ColKey(3) = "HWDBRCISSTOP"
   
   gPublicCommon.PublicFunction.LoadFormSet Me, Tlbaction(TlbHwDbRc), Img(ImgHwDbRc), SBar(SBarHwDbRc)
   
   gPublicCommon.gForms(UCase(Me.Name)).ControlStatus.Add "", Flex(FlexHwDbRc)
   gPublicCommon.PublicFunction.EnableControl Me, ""
   
   LoadDataIntoGrid
   
   
Exit Sub
Errorhandle:
    MsgBox Err.Description
End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
   Dim mButton As Button
On Error GoTo Errorhandle

   Set mButton = gPublicFunction.GetToolBarButton(Me, KeyCode)
   
   If Not mButton Is Nothing Then
      Tlbaction_ButtonClick TlbHwDbRc, mButton
   End If
  
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub
Private Sub LoadDataIntoGrid()
    Dim ItemStr As String
    Dim m_HwDbRc As HwDbRc
On Error GoTo Errorhandle
    
    Flex(FlexHwDbRc).Rows = 1
    Flex(FlexHwDbRc).AddItem ""
   
    Set OHwDbRcs = New HwDbRcs
    OHwDbRcs.FillbyDb
    
    For Each m_HwDbRc In OHwDbRcs
       ItemStr = vbTab & m_HwDbRc.HwDbRcCode & vbTab & m_HwDbRc.HwDbRcMc & vbTab & IIf(m_HwDbRc.HwDbRcIsStop = 1, "√", "")
       Flex(FlexHwDbRc).AddItem ItemStr, Flex(FlexHwDbRc).Rows - 1
       Flex(FlexHwDbRc).RowData(Flex(FlexHwDbRc).Rows - 2) = m_HwDbRc.HwDbRc_Key
    Next
    
    If Flex(FlexHwDbRc).Rows > 2 Then
      Flex(FlexHwDbRc).Row = 1
      Set OHwDbRc = OHwDbRcs(CStr(Flex(FlexHwDbRc).RowData(1)))
    Else
      Set OHwDbRc = Nothing
    End If
    
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddRecord(RecordName As String)
On Error GoTo Errorhandle

   Flex(FlexHwDbRc).Row = Flex(FlexHwDbRc).Rows - 1
   Flex(FlexHwDbRc).Col = Flex(FlexHwDbRc).ColIndex("HWDBRCCODE")
   gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwDbRc), RecordName
    
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub CancelRecord(RecordName As String)
On Error GoTo Errorhandle

   If Tlbaction(TlbHwDbRc).Tag <> "" Then
      gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwDbRc), RecordName
      LoadDataIntoGrid
   End If
    
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Delrecord(RecordName As String)
On Error GoTo Errorhandle

   If OHwDbRcs Is Nothing Then
       Exit Sub
   End If
   
   If OHwDbRc Is Nothing Then
       Exit Sub
   End If
   
   If Flex(FlexHwDbRc).Rows <= 2 Then
       Exit Sub
   End If
            
   If MsgBox("您真的要删除吗？", vbYesNo) = vbYes Then
      OHwDbRcs.Remove CStr(OHwDbRc.HwDbRc_Key)
      gPublicFunction.RemoveFlexItem Flex(FlexHwDbRc).Row, Flex(FlexHwDbRc)
      If Flex(FlexHwDbRc).Rows = 2 Then
          Set OHwDbRc = Nothing
      Else
          Set OHwDbRc = OHwDbRcs(CStr(Flex(FlexHwDbRc).RowData(Flex(FlexHwDbRc).Row)))
      End If
   End If

Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SaveRecord(RecordName As String)
On Error GoTo Errorhandle
   
   SetValueToObject RecordName
   OHwDbRcs.DbSave
   gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwDbRc), RecordName
    
Exit Sub
Errorhandle:
    Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SetValueToObject(ObjectName As String)
   Dim I As Integer
On Error GoTo Errorhandle

   For I = 1 To Flex(FlexHwDbRc).Rows - 2
      Set OHwDbRc = OHwDbRcs.Item(CStr(Flex(FlexHwDbRc).RowData(I)))
      OHwDbRc.HwDbRcCode = Trim(Flex(FlexHwDbRc).TextMatrix(I, Flex(FlexHwDbRc).ColIndex("HWDBRCCODE")))
      OHwDbRc.HwDbRcMc = Trim(Flex(FlexHwDbRc).TextMatrix(I, Flex(FlexHwDbRc).ColIndex("HWDBRCMC")))
      OHwDbRc.HwDbRcIsStop = IIf(Trim(Flex(FlexHwDbRc).TextMatrix(I, Flex(FlexHwDbRc).ColIndex("HWDBRCISSTOP"))) <> "", 1, 0)
   Next
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Unload(Cancel As Integer)
On Error GoTo Errorhandle

    Set OHwDbRc = Nothing
    Set OHwDbRcs = Nothing
    
    gPublicCommon.PublicFunction.SaveFormSet Me
    
    Exit Sub
Errorhandle:
    MsgBox Err.Description
End Sub

Private Sub Tlbaction_ButtonClick(Index As Integer, ByVal Button As MSComctlLib.Button)
    Dim Action, RecordName As String
On Error GoTo Errorhandle

    Action = (Mid(Button.Key, 1, 3))
    RecordName = Button.Key
    
   If Trim(Flex(FlexHwDbRc).EditText) <> "" Then
      Flex(FlexHwDbRc).TextMatrix(Flex(FlexHwDbRc).Row, Flex(FlexHwDbRc).Col) = Trim(Flex(FlexHwDbRc).EditText)
   End If
        
    Select Case Action
        Case "EDI"
             AddRecord RecordName
        Case "CAN"
             CancelRecord RecordName
        Case "SAV"
             SaveRecord RecordName
        Case "DEF"
             Delrecord RecordName
        Case "EXI"
             Unload Me
    End Select
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Form_Resize()
On Error GoTo Errorhandle
    
   gPublicCommon.PublicFunction.ResizeForm Me
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub