frmhwck.frm

制造业产供销与往来系统源码,包括进销存及全部控件！

Dim OHwCk As HwCk
Dim OHwCks As HwCks

Private Sub Flex_AfterEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long)
On Error GoTo Errorhandle

SetControlToFlex

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_BeforeEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, Cancel As Boolean)
On Error GoTo Errorhandle
   
   mCurColOldValue = Trim(Flex(FlexHwCk).TextMatrix(Flex(FlexHwCk).Row, Flex(FlexHwCk).Col))

   If Tlbaction(TlbHwCk).Tag = "" Then
      Cancel = True
   End If

   If Tlbaction(TlbHwCk).Tag <> "" Then
      Select Case Flex(FlexHwCk).ColKey(Col)
      Case "HWCKCODE"
            
      Case "HWCKMC"
            If OHwCk Is Nothing Then
               Cancel = True
            End If
            
      End Select
            
   End If
   

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_Click(Index As Integer)
On Error GoTo Errorhandle

   If Tlbaction(TlbHwCk).Tag = "" Then
      Exit Sub
   End If
   
   If OHwCk Is Nothing Then
      Exit Sub
   End If

   Select Case Index
   Case FlexHwCk
         If Flex(Index).Col = Flex(Index).ColIndex("HWCKISSTOP") Then
            If Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexHwCk).Col) = "" Then
               Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexHwCk).Col) = "√"
            Else
               Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexHwCk).Col) = ""
            End If
         End If
   End Select

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyDown(Index As Integer, KeyCode As Integer, Shift As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexKeyDown Flex(Index), KeyCode

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyDownEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, KeyCode As Integer, ByVal Shift As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexKeyDown Flex(Index), KeyCode

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyPressEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, KeyAscii As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexInputCheck Me, Flex(Index), KeyAscii

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_RowColChange(Index As Integer)
On Error GoTo Errorhandle

    Select Case Index
        Case FlexHwCk
            If Flex(Index).Rows > 2 And Flex(FlexHwCk).Row <> Flex(FlexHwCk).Rows - 1 Then
                Set OHwCk = OHwCks(CStr(Flex(FlexHwCk).RowData(Flex(FlexHwCk).Row)))
            Else
                Set OHwCk = Nothing
            End If
    End Select
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub SetControlToFlex()
   Dim mCurCol As Integer
   Dim mCurRow As Integer
On Error GoTo Errorhandle

   If Tlbaction(TlbHwCk).Tag = "" Then
      Exit Sub
   End If
   
   mCurRow = Flex(FlexHwCk).Row
   mCurCol = Flex(FlexHwCk).Col
   
   Select Case Flex(FlexHwCk).ColKey(Flex(FlexHwCk).Col)
   Case "HWCKCODE"
         If OHwCk Is Nothing Then
            AddNewRecord
         Else
            OHwCk.HwCkCode = Trim(Flex(FlexHwCk).TextMatrix(mCurRow, mCurCol))
         End If
   
   Case "HWCKMC"
         If Not OHwCk Is Nothing Then
            OHwCk.HwCkMc = Trim(Flex(FlexHwCk).TextMatrix(mCurRow, mCurCol))
         End If
   
   End Select


Exit Sub
Errorhandle:
   Flex(FlexHwCk).TextMatrix(mCurRow, mCurCol) = mCurColOldValue
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddNewRecord()
On Error GoTo Errorhandle

   If Trim(Flex(FlexHwCk).TextMatrix(Flex(FlexHwCk).Row, Flex(FlexHwCk).Col)) <> "" Then
      Set OHwCk = New HwCk
      OHwCk.HwCkCode = Trim(Flex(FlexHwCk).TextMatrix(Flex(FlexHwCk).Row, Flex(FlexHwCk).Col))
      OHwCks.Add OHwCk
      Flex(FlexHwCk).RowData(Flex(FlexHwCk).Rows - 1) = OHwCk.HwCk_Key
      Flex(FlexHwCk).AddItem ""
   End If

Exit Sub
Errorhandle:
   Set OHwCk = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Load()
On Error GoTo Errorhandle
   
   Flex(FlexHwCk).Editable = flexEDKbdMouse
   
   Flex(FlexHwCk).ColKey(1) = "HWCKCODE"
   Flex(FlexHwCk).ColKey(2) = "HWCKMC"
   Flex(FlexHwCk).ColKey(3) = "HWCKISSTOP"
   
   gPublicCommon.PublicFunction.LoadFormSet Me, Tlbaction(TlbHwCk), Img(ImgHwCk), SBar(SBarHwCk)
   
   gPublicCommon.gForms(UCase(Me.Name)).ControlStatus.Add "", Flex(FlexHwCk)
   gPublicCommon.PublicFunction.EnableControl Me, ""
   
   LoadDataIntoGrid
   
Exit Sub
Errorhandle:
    MsgBox Err.Description
End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
   Dim mButton As Button
On Error GoTo Errorhandle

   Set mButton = gPublicFunction.GetToolBarButton(Me, KeyCode)
   
   If Not mButton Is Nothing Then
      Tlbaction_ButtonClick TlbHwCk, mButton
   End If
  
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub LoadDataIntoGrid()
    Dim ItemStr As String
    Dim m_HwCk As HwCk
On Error GoTo Errorhandle
        
    Flex(FlexHwCk).Rows = 1
    Flex(FlexHwCk).AddItem ""
   
    Set OHwCks = New HwCks
    OHwCks.FillbyDb
    
    For Each m_HwCk In OHwCks
       ItemStr = vbTab & m_HwCk.HwCkCode & vbTab & m_HwCk.HwCkMc & vbTab & IIf(m_HwCk.HwCkIsStop = 1, "√", "")
       Flex(FlexHwCk).AddItem ItemStr, Flex(FlexHwCk).Rows - 1
       Flex(FlexHwCk).RowData(Flex(FlexHwCk).Rows - 2) = m_HwCk.HwCk_Key
    Next
    
    If Flex(FlexHwCk).Rows > 2 Then
      Flex(FlexHwCk).Row = 1
      Set OHwCk = OHwCks(CStr(Flex(FlexHwCk).RowData(1)))
    Else
      Set OHwCk = Nothing
    End If
           
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddRecord(RecordName As String)
On Error GoTo Errorhandle

   Flex(FlexHwCk).Row = Flex(FlexHwCk).Rows - 1
   Flex(FlexHwCk).Col = Flex(FlexHwCk).ColIndex("HWCKCODE")
   gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwCk), RecordName
    
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub CancelRecord(RecordName As String)
On Error GoTo Errorhandle

   If Tlbaction(TlbHwCk).Tag <> "" Then
      gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwCk), RecordName
      LoadDataIntoGrid
   End If
    
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Delrecord(RecordName As String)
On Error GoTo Errorhandle

   If OHwCks Is Nothing Then
       Exit Sub
   End If
   
   If OHwCk Is Nothing Then
       Exit Sub
   End If
   
   If Flex(FlexHwCk).Rows <= 2 Then
       Exit Sub
   End If
    
   If MsgBox("您真的要删除吗？", vbYesNo) = vbYes Then
      OHwCks.Remove CStr(OHwCk.HwCk_Key)
      gPublicFunction.RemoveFlexItem Flex(FlexHwCk).Row, Flex(FlexHwCk)
      If Flex(FlexHwCk).Rows = 2 Then
          Set OHwCk = Nothing
      Else
          Set OHwCk = OHwCks(CStr(Flex(FlexHwCk).RowData(Flex(FlexHwCk).Row)))
      End If
   End If

Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SaveRecord(RecordName As String)
On Error GoTo Errorhandle
   
   SetValueToObject RecordName
   OHwCks.DbSave
   gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwCk), RecordName
    
Exit Sub
Errorhandle:
    Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SetValueToObject(ObjectName As String)
   Dim I As Integer
On Error GoTo Errorhandle

   For I = 1 To Flex(FlexHwCk).Rows - 2
      Set OHwCk = OHwCks.Item(CStr(Flex(FlexHwCk).RowData(I)))
      OHwCk.HwCkCode = Trim(Flex(FlexHwCk).TextMatrix(I, Flex(FlexHwCk).ColIndex("HWCKCODE")))
      OHwCk.HwCkMc = Trim(Flex(FlexHwCk).TextMatrix(I, Flex(FlexHwCk).ColIndex("HWCKMC")))
      OHwCk.HwCkIsStop = IIf(Trim(Flex(FlexHwCk).TextMatrix(I, Flex(FlexHwCk).ColIndex("HWCKISSTOP"))) <> "", 1, 0)
   Next
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Unload(Cancel As Integer)
On Error GoTo Errorhandle

    Set OHwCk = Nothing
    Set OHwCks = Nothing
    
    gPublicCommon.PublicFunction.SaveFormSet Me
    
    Exit Sub
Errorhandle:
    MsgBox Err.Description
End Sub


Private Sub Tlbaction_ButtonClick(Index As Integer, ByVal Button As MSComctlLib.Button)
    Dim Action, RecordName As String
On Error GoTo Errorhandle

    Action = (Mid(Button.Key, 1, 3))
    RecordName = Button.Key
    
   If Trim(Flex(FlexHwCk).EditText) <> "" Then
      Flex(FlexHwCk).TextMatrix(Flex(FlexHwCk).Row, Flex(FlexHwCk).Col) = Trim(Flex(FlexHwCk).EditText)
   End If
        
    Select Case Action
        Case "EDI"
             AddRecord RecordName
        Case "CAN"
             CancelRecord RecordName
        Case "SAV"
             SaveRecord RecordName
        Case "DEF"
             Delrecord RecordName
        Case "EXI"
             Unload Me
    End Select
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Form_Resize()
On Error GoTo Errorhandle
    
   gPublicCommon.PublicFunction.ResizeForm Me
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub