frmcwbz.frm

制造业产供销与往来系统源码,包括进销存及全部控件！

Private Sub Flex_AfterEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long)
On Error GoTo Errorhandle

SetControlToFlex

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_BeforeEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, Cancel As Boolean)
On Error GoTo Errorhandle
   
   mCurColOldValue = Trim(Flex(FlexCwBz).TextMatrix(Flex(FlexCwBz).Row, Flex(FlexCwBz).Col))

   If Tlbaction(TlbCwBz).Tag = "" Then
      Cancel = True
   End If

   If Tlbaction(TlbCwBz).Tag <> "" Then
      Select Case Flex(FlexCwBz).ColKey(Col)
      Case "CWBZCODE"
            
      Case "CWBZMC"
            If OCwBz Is Nothing Then
               Cancel = True
            End If
            
      Case "CWBZEXRA"
            If OCwBz Is Nothing Then
               Cancel = True
            End If
      End Select
            
   End If
   

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_Click(Index As Integer)
On Error GoTo Errorhandle

   If Tlbaction(TlbCwBz).Tag = "" Then
      Exit Sub
   End If
   
   If OCwBz Is Nothing Then
      Exit Sub
   End If

   Select Case Index
   Case FlexCwBz
         If Flex(Index).Col = Flex(Index).ColIndex("CWBZISSTOP") Then
            If Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexCwBz).Col) = "" Then
               Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexCwBz).Col) = "√"
            Else
               Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexCwBz).Col) = ""
            End If
         End If
   End Select

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyDown(Index As Integer, KeyCode As Integer, Shift As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexKeyDown Flex(Index), KeyCode

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyDownEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, KeyCode As Integer, ByVal Shift As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexKeyDown Flex(Index), KeyCode

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyPressEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, KeyAscii As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexInputCheck Me, Flex(Index), KeyAscii

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_RowColChange(Index As Integer)
On Error GoTo Errorhandle

    Select Case Index
        Case FlexCwBz
            If Flex(Index).Rows > 2 And Flex(FlexCwBz).Row <> Flex(FlexCwBz).Rows - 1 Then
                Set OCwBz = OCwBzs(CStr(Flex(FlexCwBz).RowData(Flex(FlexCwBz).Row)))
            Else
                Set OCwBz = Nothing
            End If
    End Select
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub SetControlToFlex()
   Dim mCurCol As Integer
   Dim mCurRow As Integer
On Error GoTo Errorhandle

   If Tlbaction(TlbCwBz).Tag = "" Then
      Exit Sub
   End If
   
   mCurRow = Flex(FlexCwBz).Row
   mCurCol = Flex(FlexCwBz).Col
   
   Select Case Flex(FlexCwBz).ColKey(Flex(FlexCwBz).Col)
   Case "CWBZCODE"
         If OCwBz Is Nothing Then
            AddNewRecord
         Else
            OCwBz.CwbzCode = Trim(Flex(FlexCwBz).TextMatrix(mCurRow, mCurCol))
         End If
   
   Case "CWBZMC"
         If Not OCwBz Is Nothing Then
            OCwBz.CwbzMc = Trim(Flex(FlexCwBz).TextMatrix(mCurRow, mCurCol))
         End If
   
   Case "CWBZEXRA"
         If Not OCwBz Is Nothing Then
            OCwBz.CwbzExra = Val(Flex(FlexCwBz).TextMatrix(Flex(FlexCwBz).Row, mCurCol))
         End If
   
   End Select


Exit Sub
Errorhandle:
   Flex(FlexCwBz).TextMatrix(mCurRow, mCurCol) = mCurColOldValue
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddNewRecord()
On Error GoTo Errorhandle

   If Trim(Flex(FlexCwBz).TextMatrix(Flex(FlexCwBz).Row, Flex(FlexCwBz).Col)) <> "" Then
      Set OCwBz = New CwBz
      OCwBz.CwbzCode = Trim(Flex(FlexCwBz).TextMatrix(Flex(FlexCwBz).Row, Flex(FlexCwBz).Col))
      OCwBzs.Add OCwBz
      Flex(FlexCwBz).RowData(Flex(FlexCwBz).Rows - 1) = OCwBz.Cwbz_Key
      Flex(FlexCwBz).AddItem ""
   End If

Exit Sub
Errorhandle:
   Set OCwBz = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Load()
On Error GoTo Errorhandle
   
   Flex(FlexCwBz).Editable = flexEDKbdMouse
   
   Flex(FlexCwBz).ColKey(1) = "CWBZCODE"
   Flex(FlexCwBz).ColKey(2) = "CWBZMC"
   Flex(FlexCwBz).ColKey(3) = "CWBZEXRA"
   Flex(FlexCwBz).ColKey(4) = "CWBZISSTOP"
   
   gPublicFunction.LoadFormSet Me, Tlbaction(TlbCwBz), Img(ImgCwBz), SBar(SBarCwBz)
   
   gPublicCommon.gForms(UCase(Me.Name)).ControlStatus.Add "", Flex(FlexCwBz)
   gPublicCommon.PublicFunction.EnableControl Me, ""
   
   LoadDataIntoGrid
   
Exit Sub
Errorhandle:
    MsgBox Err.Description
End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
   Dim mButton As Button
On Error GoTo Errorhandle

   Set mButton = gPublicFunction.GetToolBarButton(Me, KeyCode)
   
   If Not mButton Is Nothing Then
      Tlbaction_ButtonClick TlbCwBz, mButton
   End If
  
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub LoadDataIntoGrid()
    Dim ItemStr As String
    Dim m_CwBz As CwBz
On Error GoTo Errorhandle

    Flex(FlexCwBz).Rows = 1
    Flex(FlexCwBz).AddItem ""
   
    Set OCwBzs = New CwBzs
    OCwBzs.FillbyDb
    
    For Each m_CwBz In OCwBzs
       ItemStr = vbTab & m_CwBz.CwbzCode & vbTab & m_CwBz.CwbzMc & vbTab & CStr(m_CwBz.CwbzExra) & vbTab & IIf(m_CwBz.CwbzIsStop = 1, "√", "")
       Flex(FlexCwBz).AddItem ItemStr, Flex(FlexCwBz).Rows - 1
       Flex(FlexCwBz).RowData(Flex(FlexCwBz).Rows - 2) = m_CwBz.Cwbz_Key
    Next
    
    If Flex(FlexCwBz).Rows > 2 Then
      Flex(FlexCwBz).Row = 1
      Set OCwBz = OCwBzs(CStr(Flex(FlexCwBz).RowData(1)))
    Else
      Set OCwBz = Nothing
    End If
    
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddRecord(RecordName As String)
On Error GoTo Errorhandle

   Flex(FlexCwBz).Row = Flex(FlexCwBz).Rows - 1
   Flex(FlexCwBz).Col = Flex(FlexCwBz).ColIndex("CWBZCODE")
   gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbCwBz), RecordName

Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub CancelRecord(RecordName As String)
On Error GoTo Errorhandle

   If Tlbaction(TlbCwBz).Tag <> "" Then
      gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbCwBz), RecordName
      LoadDataIntoGrid
   End If
    
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Delrecord(RecordName As String)
On Error GoTo Errorhandle
            
   If OCwBzs Is Nothing Then
       Exit Sub
   End If
   
   If OCwBz Is Nothing Then
       Exit Sub
   End If
   
   If Flex(FlexCwBz).Rows <= 2 Then
       Exit Sub
   End If
            
   If MsgBox("您真的要删除吗？", vbYesNo) = vbYes Then
      OCwBzs.Remove CStr(OCwBz.Cwbz_Key)
      gPublicFunction.RemoveFlexItem Flex(FlexCwBz).Row, Flex(FlexCwBz)
      If Flex(FlexCwBz).Rows = 2 Then
          Set OCwBz = Nothing
      Else
          Set OCwBz = OCwBzs(CStr(Flex(FlexCwBz).RowData(Flex(FlexCwBz).Row)))
      End If
   End If

Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SaveRecord(RecordName As String)
On Error GoTo Errorhandle
   
   SetValueToObject RecordName
   OCwBzs.DbSave
   gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbCwBz), RecordName
    
Exit Sub
Errorhandle:
    Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SetValueToObject(ObjectName As String)
   Dim I As Integer
On Error GoTo Errorhandle

   For I = 1 To Flex(FlexCwBz).Rows - 2
      Set OCwBz = OCwBzs.Item(CStr(Flex(FlexCwBz).RowData(I)))
      OCwBz.CwbzCode = Trim(Flex(FlexCwBz).TextMatrix(I, Flex(FlexCwBz).ColIndex("CWBZCODE")))
      OCwBz.CwbzMc = Trim(Flex(FlexCwBz).TextMatrix(I, Flex(FlexCwBz).ColIndex("CWBZMC")))
      OCwBz.CwbzExra = Val(Flex(FlexCwBz).TextMatrix(I, Flex(FlexCwBz).ColIndex("CWBZEXRA")))
      OCwBz.CwbzIsStop = IIf(Trim(Flex(FlexCwBz).TextMatrix(I, Flex(FlexCwBz).ColIndex("CWBZISSTOP"))) <> "", 1, 0)
   Next
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Unload(Cancel As Integer)
On Error GoTo Errorhandle

    Set OCwBz = Nothing
    Set OCwBzs = Nothing
    
    gPublicCommon.PublicFunction.SaveFormSet Me
    
    Exit Sub
Errorhandle:
    MsgBox Err.Description
End Sub

Private Sub Tlbaction_ButtonClick(Index As Integer, ByVal Button As MSComctlLib.Button)
    Dim Action, RecordName As String
On Error GoTo Errorhandle

    Action = (Mid(Button.Key, 1, 3))
    RecordName = Button.Key
    
   If Trim(Flex(FlexCwBz).EditText) <> "" Then
      Flex(FlexCwBz).TextMatrix(Flex(FlexCwBz).Row, Flex(FlexCwBz).Col) = Trim(Flex(FlexCwBz).EditText)
   End If
        
    Select Case Action
        Case "EDI"
             AddRecord RecordName
        Case "CAN"
             CancelRecord RecordName
        Case "SAV"
             SaveRecord RecordName
        Case "DEF"
             Delrecord RecordName
        Case "EXI"
             Unload Me
    End Select
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Form_Resize()
On Error GoTo Errorhandle
    
   gPublicCommon.PublicFunction.ResizeForm Me
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub