frmhwiorc.frm

制造业产供销与往来系统源码,包括进销存及全部控件！

Dim OHwIoRcs As HwIoRcs

Private Sub Flex_AfterEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long)
On Error GoTo Errorhandle

SetControlToFlex

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_BeforeEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, Cancel As Boolean)
On Error GoTo Errorhandle
   
   mCurColOldValue = Trim(Flex(FlexHwIoRc).TextMatrix(Flex(FlexHwIoRc).Row, Flex(FlexHwIoRc).Col))

   If Tlbaction(TlbHwIoRc).Tag = "" Then
      Cancel = True
   End If

   If Tlbaction(TlbHwIoRc).Tag <> "" Then
      Select Case Flex(FlexHwIoRc).ColKey(Col)
      Case "HWIORCCODE"
            
      Case "HWIORCMC"
            If OHwIoRc Is Nothing Then
               Cancel = True
            End If
            
      End Select
            
   End If
   

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_Click(Index As Integer)
On Error GoTo Errorhandle

   If Tlbaction(TlbHwIoRc).Tag = "" Then
      Exit Sub
   End If
   
   If OHwIoRc Is Nothing Then
      Exit Sub
   End If

   Select Case Index
   Case FlexHwIoRc
         If Flex(Index).Col = Flex(Index).ColIndex("HWIORCISSTOP") Then
            If Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexHwIoRc).Col) = "" Then
               Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexHwIoRc).Col) = "√"
            Else
               Flex(Index).TextMatrix(Flex(Index).Row, Flex(FlexHwIoRc).Col) = ""
            End If
         End If
   End Select

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyDown(Index As Integer, KeyCode As Integer, Shift As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexKeyDown Flex(Index), KeyCode

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyDownEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, KeyCode As Integer, ByVal Shift As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexKeyDown Flex(Index), KeyCode

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_KeyPressEdit(Index As Integer, ByVal Row As Long, ByVal Col As Long, KeyAscii As Integer)
On Error GoTo Errorhandle

gPublicFunction.FlexInputCheck Me, Flex(Index), KeyAscii

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Flex_RowColChange(Index As Integer)
On Error GoTo Errorhandle

    Select Case Index
        Case FlexHwIoRc
            If Flex(Index).Rows > 2 And Flex(FlexHwIoRc).Row <> Flex(FlexHwIoRc).Rows - 1 Then
                Set OHwIoRc = OHwIoRcs(CStr(Flex(FlexHwIoRc).RowData(Flex(FlexHwIoRc).Row)))
            Else
                Set OHwIoRc = Nothing
            End If
    End Select
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub SetControlToFlex()
   Dim mCurCol As Integer
   Dim mCurRow As Integer
On Error GoTo Errorhandle

   If Tlbaction(TlbHwIoRc).Tag = "" Then
      Exit Sub
   End If
   
   mCurRow = Flex(FlexHwIoRc).Row
   mCurCol = Flex(FlexHwIoRc).Col
   
   Select Case Flex(FlexHwIoRc).ColKey(Flex(FlexHwIoRc).Col)
   Case "HWIORCCODE"
         If OHwIoRc Is Nothing Then
            AddNewRecord
         Else
            OHwIoRc.HwIoRcCode = Trim(Flex(FlexHwIoRc).TextMatrix(mCurRow, mCurCol))
         End If
   
   Case "HWIORCMC"
         If Not OHwIoRc Is Nothing Then
            OHwIoRc.HwIoRcMc = Trim(Flex(FlexHwIoRc).TextMatrix(mCurRow, mCurCol))
         End If
   
   End Select


Exit Sub
Errorhandle:
   Flex(FlexHwIoRc).TextMatrix(mCurRow, mCurCol) = mCurColOldValue
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddNewRecord()
On Error GoTo Errorhandle

   If Trim(Flex(FlexHwIoRc).TextMatrix(Flex(FlexHwIoRc).Row, Flex(FlexHwIoRc).Col)) <> "" Then
      Set OHwIoRc = New HwIoRc
      OHwIoRc.HwIoRcCode = Trim(Flex(FlexHwIoRc).TextMatrix(Flex(FlexHwIoRc).Row, Flex(FlexHwIoRc).Col))
      OHwIoRcs.Add OHwIoRc
      Flex(FlexHwIoRc).RowData(Flex(FlexHwIoRc).Rows - 1) = OHwIoRc.HwIoRc_Key
      Flex(FlexHwIoRc).AddItem ""
   End If

Exit Sub
Errorhandle:
   Set OHwIoRc = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Load()
On Error GoTo Errorhandle
  
   Flex(FlexHwIoRc).Editable = flexEDKbdMouse
   
   Flex(FlexHwIoRc).ColKey(1) = "HWIORCCODE"
   Flex(FlexHwIoRc).ColKey(2) = "HWIORCMC"
   Flex(FlexHwIoRc).ColKey(3) = "HWIORCISSTOP"
   
   gPublicCommon.PublicFunction.LoadFormSet Me, Tlbaction(TlbHwIoRc), Img(ImgHwIoRc), SBar(SBarHwIoRc)
   
   gPublicCommon.gForms(UCase(Me.Name)).ControlStatus.Add "", Flex(FlexHwIoRc)
   gPublicCommon.PublicFunction.EnableControl Me, ""
   
   LoadDataIntoGrid
   
   
Exit Sub
Errorhandle:
    MsgBox Err.Description
End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
   Dim mButton As Button
On Error GoTo Errorhandle

   Set mButton = gPublicFunction.GetToolBarButton(Me, KeyCode)
   
   If Not mButton Is Nothing Then
      Tlbaction_ButtonClick TlbHwIoRc, mButton
   End If
  
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub LoadDataIntoGrid()
    Dim ItemStr As String
    Dim m_HwIoRc As HwIoRc
On Error GoTo Errorhandle
         
    Flex(FlexHwIoRc).Rows = 1
    Flex(FlexHwIoRc).AddItem ""
   
    Set OHwIoRcs = New HwIoRcs
    OHwIoRcs.FillbyDb
    
    For Each m_HwIoRc In OHwIoRcs
       ItemStr = vbTab & m_HwIoRc.HwIoRcCode & vbTab & m_HwIoRc.HwIoRcMc & vbTab & IIf(m_HwIoRc.HwIoRcIsStop = 1, "√", "")
       Flex(FlexHwIoRc).AddItem ItemStr, Flex(FlexHwIoRc).Rows - 1
       Flex(FlexHwIoRc).RowData(Flex(FlexHwIoRc).Rows - 2) = m_HwIoRc.HwIoRc_Key
    Next
    
    If Flex(FlexHwIoRc).Rows > 2 Then
      Flex(FlexHwIoRc).Row = 1
      Set OHwIoRc = OHwIoRcs(CStr(Flex(FlexHwIoRc).RowData(1)))
    Else
      Set OHwIoRc = Nothing
    End If
    
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddRecord(RecordName As String)
On Error GoTo Errorhandle
   
   Flex(FlexHwIoRc).Row = Flex(FlexHwIoRc).Rows - 1
   Flex(FlexHwIoRc).Col = Flex(FlexHwIoRc).ColIndex("HWIORCCODE")
   gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwIoRc), RecordName

Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub CancelRecord(RecordName As String)
On Error GoTo Errorhandle

   If Tlbaction(TlbHwIoRc).Tag <> "" Then
      gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwIoRc), RecordName
      LoadDataIntoGrid
   End If

Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Delrecord(RecordName As String)
On Error GoTo Errorhandle

   If OHwIoRcs Is Nothing Then
       Exit Sub
   End If
   
   If OHwIoRc Is Nothing Then
       Exit Sub
   End If
   
   If Flex(FlexHwIoRc).Rows <= 2 Then
       Exit Sub
   End If
    
   If MsgBox("您真的要删除吗？", vbYesNo) = vbYes Then
      OHwIoRcs.Remove CStr(OHwIoRc.HwIoRc_Key)
      gPublicFunction.RemoveFlexItem Flex(FlexHwIoRc).Row, Flex(FlexHwIoRc)
      If Flex(FlexHwIoRc).Rows = 2 Then
          Set OHwIoRc = Nothing
      Else
          Set OHwIoRc = OHwIoRcs(CStr(Flex(FlexHwIoRc).RowData(Flex(FlexHwIoRc).Row)))
      End If
   End If

Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SaveRecord(RecordName As String)
On Error GoTo Errorhandle
   
   SetValueToObject RecordName
   OHwIoRcs.DbSave
   gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwIoRc), RecordName
    
Exit Sub
Errorhandle:
    Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SetValueToObject(ObjectName As String)
   Dim I As Integer
On Error GoTo Errorhandle

   For I = 1 To Flex(FlexHwIoRc).Rows - 2
      Set OHwIoRc = OHwIoRcs.Item(CStr(Flex(FlexHwIoRc).RowData(I)))
      OHwIoRc.HwIoRcCode = Trim(Flex(FlexHwIoRc).TextMatrix(I, Flex(FlexHwIoRc).ColIndex("HWIORCCODE")))
      OHwIoRc.HwIoRcMc = Trim(Flex(FlexHwIoRc).TextMatrix(I, Flex(FlexHwIoRc).ColIndex("HWIORCMC")))
      OHwIoRc.HwIoRcIsStop = IIf(Trim(Flex(FlexHwIoRc).TextMatrix(I, Flex(FlexHwIoRc).ColIndex("HWIORCISSTOP"))) <> "", 1, 0)
   Next
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Unload(Cancel As Integer)
On Error GoTo Errorhandle

    Set OHwIoRc = Nothing
    Set OHwIoRcs = Nothing
    
    gPublicCommon.PublicFunction.SaveFormSet Me
    
    Exit Sub
Errorhandle:
    MsgBox Err.Description
End Sub

Private Sub Tlbaction_ButtonClick(Index As Integer, ByVal Button As MSComctlLib.Button)
    Dim Action, RecordName As String
On Error GoTo Errorhandle

    Action = (Mid(Button.Key, 1, 3))
    RecordName = Button.Key
    
   If Trim(Flex(FlexHwIoRc).EditText) <> "" Then
      Flex(FlexHwIoRc).TextMatrix(Flex(FlexHwIoRc).Row, Flex(FlexHwIoRc).Col) = Trim(Flex(FlexHwIoRc).EditText)
   End If
        
    Select Case Action
        Case "EDI"
             AddRecord RecordName
        Case "CAN"
             CancelRecord RecordName
        Case "SAV"
             SaveRecord RecordName
        Case "DEF"
             Delrecord RecordName
        Case "EXI"
             Unload Me
    End Select
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Form_Resize()
On Error GoTo Errorhandle
    
   gPublicCommon.PublicFunction.ResizeForm Me
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub