cwsms.cls

制造业产供销与往来系统源码,包括进销存及全部控件！

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "Cwsms"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit

Dim OCwsms As Collection

Public Property Get Count() As Integer

Count = OCwsms.Count
    
End Property

Public Sub Add(OCwsm As Cwsm)

Dim vKey As Integer, vCwsm As Cwsm

For Each vCwsm In OCwsms
   If vCwsm.Cwsm_Key > vKey Then
      vKey = vCwsm.Cwsm_Key
   End If
Next

vKey = vKey + 1

OCwsm.Cwsm_Key = vKey
OCwsms.Add OCwsm, CStr(vKey)

End Sub

Public Function Item(Vindex) As Cwsm
Attribute Item.VB_UserMemId = 0

   Set Item = OCwsms.Item(Vindex)

End Function

Public Sub Remove(Vindex, Optional NeedDel As Integer = 1)

If NeedDel = 1 Then
   Dim mCwsm As Cwsm
   Set mCwsm = OCwsms(Vindex)
   mCwsm.DbDel
End If
   
OCwsms.Remove (Vindex)
      
End Sub

Public Sub ClearAll()

Dim i, Vcount As Integer
Vcount = OCwsms.Count

For i = 1 To Vcount
   OCwsms.Remove (1)
Next

End Sub

Public Sub Fillbydb(Optional Wherestr As String = "", Optional Orderstr As String = "CwsmCode")
   Dim OCwsm As Cwsm
   Dim Rs As DbRs
   Dim SqlStr As String
   Dim vKey As Integer
On Error GoTo ErrorHandle

   ClearAll
   
   SqlStr = "SELECT CwsmCode,CWSMMC,CWSMSL,CWSMNO FROM CwsmREC "
   
   If Wherestr <> "" Then
      SqlStr = SqlStr + " where " + Wherestr
   End If
   
   If Orderstr <> "" Then
      SqlStr = SqlStr + " order by " + Orderstr
   End If
   
   Set Rs = New DbRs
   
   Rs.Fillbydb SqlStr
   Rs.MoveFirst
   
   vKey = 1

   Do Until Rs.EOF
      Set OCwsm = New Cwsm
      OCwsm.Cwsm_Key = vKey
      OCwsm.BatchLet Rs!CwsmCode, Rs!CwsmMc, Rs!CwsmSl, Rs!CwsmNo
      OCwsms.Add OCwsm, CStr(vKey)
      Rs.MoveNext
      vKey = vKey + 1
   Loop

   Set Rs = Nothing

Exit Sub
ErrorHandle:
   Set Rs = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Public Function NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
Attribute NewEnum.VB_MemberFlags = "40"

  Set NewEnum = OCwsms.[_NewEnum]
  
End Function

Private Sub Class_Initialize()

Set OCwsms = New Collection

End Sub

Private Sub Class_Terminate()

Set OCwsms = Nothing

End Sub

Public Property Get Name() As String

Name = "Cwsms"

End Property

Public Sub DbSave()
   Dim mNotSaved As Collection
   Dim mCwsm As Cwsm
On Error GoTo ErrorHandle
   
   Set mNotSaved = New Collection
   
   gDbCommon.Conn.BeginTrans
   
   For Each mCwsm In OCwsms
      If mCwsm.Cwsm_id = -1 Then
         mNotSaved.Add mCwsm
      End If
      mCwsm.DbSave
   Next
   
   gDbCommon.Conn.CommitTrans
   
   Set mNotSaved = Nothing

Exit Sub
ErrorHandle:
   For Each mCwsm In mNotSaved
      mCwsm.Cwsm_id = -1
   Next
   Set mNotSaved = Nothing
   gDbCommon.Conn.RollbackTrans
End Sub