cwqj.cls

制造业产供销与往来系统源码,包括进销存及全部控件！

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CwQj"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit

Dim M_CwqjYear As String
Dim M_CwqjCode As String
Dim M_CwqjBegDat As String
Dim M_CwqjEndDat As String
Dim M_CwQjNo As Double

Dim M_CwQj_id As Integer
Dim M_CwQj_Key As Long

Private Sub Class_Initialize()

M_CwQj_id = -1

End Sub

Public Property Get CwqjYear() As String

CwqjYear = M_CwqjYear

End Property

Public Property Get CwqjCode() As String

CwqjCode = M_CwqjCode

End Property

Public Property Get CwqjBegDat() As String

CwqjBegDat = M_CwqjBegDat

End Property

Public Property Get CwqjEndDat() As String

CwqjEndDat = M_CwqjEndDat

End Property

Public Property Get CwQjNo() As Double

CwQjNo = M_CwQjNo

End Property

Public Property Get CwQj_id() As Integer

    CwQj_id = M_CwQj_id

End Property

Public Property Get CwQj_Key() As Long

    CwQj_Key = M_CwQj_Key

End Property

Public Property Let CwqjYear(VCwqjYear As String)

If Trim(VCwqjYear) = "" Then
   Err.Raise Number:=vbObjectError + 1, Description:="财务年度不能为空！"
   Exit Property
End If
    
M_CwqjYear = VCwqjYear

End Property

Public Property Let CwqjCode(VCwqjCode As String)

If Trim(VCwqjCode) = "" Then
   Err.Raise vbObjectError + 1, , "财务月份不能为空！"
   Exit Property
End If

If VCwqjCode <> M_CwqjCode Then
    If M_CwQj_id = -1 Or VCwqjCode <> M_CwqjCode Then
       If gPublicFunction.ExistFlg("FROM CWQJREC WHERE CwqjCode='" + VCwqjCode + "'") = 1 Then
          Err.Raise Number:=vbObjectError + 1, Description:="已有财务月份:" & VCwqjCode
          Exit Property
       End If
    End If
    M_CwqjCode = VCwqjCode
End If

End Property

Public Property Let CwqjBegDat(VCwqjBegDat As String)

If Trim(VCwqjBegDat) = "" Then
   Err.Raise vbObjectError + 1, , "财务月份起始日期不能为空！"
   Exit Property
End If

If gPublicFunction.IsDateValid(VCwqjBegDat) = 0 Then
   Err.Raise vbObjectError + 1, , "录入的日期无效！"
   Exit Property
End If

M_CwqjBegDat = VCwqjBegDat

End Property

Public Property Let CwqjEndDat(VCwqjEndDat As String)

If Trim(VCwqjEndDat) = "" Then
   Err.Raise vbObjectError + 1, , "财务月份结束日期不能为空！"
   Exit Property
End If

If gPublicFunction.IsDateValid(VCwqjEndDat) = 0 Then
   Err.Raise vbObjectError + 1, , "录入的日期无效！"
   Exit Property
End If

If VCwqjEndDat < M_CwqjBegDat Then
   Err.Raise vbObjectError + 1, , "财务月份结束日期不能小于起始日期！"
   Exit Property
End If

M_CwqjEndDat = VCwqjEndDat

End Property

Public Property Let CwQj_id(vCwQj_id As Integer)

M_CwQj_id = vCwQj_id

End Property

Public Property Let CwQj_Key(vCwQj_Key As Long)

M_CwQj_Key = vCwQj_Key

End Property

Public Sub DbSave()
   Dim Cmd As ADODB.Command
   Dim mSqlStr As String
On Error GoTo ErrorHandle


   Set Cmd = New ADODB.Command
   Set Cmd.ActiveConnection = gDbCommon.Conn
   
   If M_CwQj_id = -1 Then
   
       Cmd.CommandText = "{CALL CWQJREC_INSERT(?,?,?,?,?)}"
       
       Cmd.Parameters(0) = M_CwqjYear
       Cmd.Parameters(1) = M_CwqjCode
       Cmd.Parameters(2) = M_CwqjBegDat
       Cmd.Parameters(3) = M_CwqjEndDat
       Cmd.Parameters(4).Direction = adParamOutput
       
       Cmd.Execute
       
       M_CwQj_id = 1
   
       M_CwQjNo = Cmd.Parameters(4)
      
   Else
   
       Cmd.CommandText = "{CALL CWQJREC_UPDATE(?,?,?,?)}"
       
       Cmd(0) = M_CwQjNo
       
       Cmd(1) = M_CwqjCode
       Cmd(2) = M_CwqjBegDat
       Cmd(3) = M_CwqjEndDat
       
       Cmd.Execute
   
   End If
   
   Set Cmd = Nothing

Exit Sub
ErrorHandle:
   Set Cmd = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Public Sub DbDel()
   Dim Cmd As ADODB.Command
   
   gPublicFunction.CheckCanBeDelete "CWQJREC", "CWQJNO", CStr(M_CwQjNo)
   
On Error GoTo ErrorHandle

   Set Cmd = New ADODB.Command
   
   Set Cmd.ActiveConnection = gDbCommon.Conn
   
   Cmd.CommandText = "{call CwQjrec_delete(?)}"
   
   Cmd.Parameters(0) = M_CwQjNo
   
   gDbCommon.Conn.BeginTrans
   Cmd.Execute
   gDbCommon.Conn.CommitTrans
   
   Set Cmd = Nothing

Exit Sub
ErrorHandle:
   Set Cmd = Nothing
   gDbCommon.Conn.RollbackTrans
End Sub

Public Function Requery(VCwqjCode As String) As Integer
   Dim Rs As DbRs
On Error GoTo ErrorHandle

   Set Rs = New DbRs
   
   Rs.Fillbydb ("select CwqjYear,CwqjCode,CwQjBEGDAT,CWQJENDDAT,CwQjNo from CwQjrec where CwqjCode='" + VCwqjCode + "'")
   Requery = -1
   If Not Rs.EOF Then
      Requery = 1
      BatchLet Rs!CwqjYear, Rs!CwqjCode, Rs!CwqjBegDat, Rs!CwqjEndDat, Rs!CwQjNo
   End If
 
   Set Rs = Nothing

Exit Function
ErrorHandle:
   Set Rs = Nothing
End Function

Public Sub BatchLet(ParamArray Properties())

M_CwqjYear = Properties(0)
M_CwqjCode = Properties(1)
M_CwqjBegDat = Properties(2)
M_CwqjEndDat = Properties(3)
M_CwQjNo = Properties(4)

M_CwQj_id = 1

End Sub

Public Property Get Name() As String

Name = "CwQj"

End Property