cwbzs.cls

制造业产供销与往来系统源码,包括进销存及全部控件！

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CwBzs"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit

Dim OCwBzs As Collection

Public Property Get Count() As Integer

Count = OCwBzs.Count
    
End Property

Public Sub Add(OCwBz As CwBz)

Dim vKey As Integer, vCwBz As CwBz

For Each vCwBz In OCwBzs
   If vCwBz.Cwbz_Key > vKey Then
      vKey = vCwBz.Cwbz_Key
   End If
Next

vKey = vKey + 1

OCwBz.Cwbz_Key = vKey
OCwBzs.Add OCwBz, CStr(vKey)

End Sub

Public Function Item(Vindex) As CwBz
Attribute Item.VB_UserMemId = 0

   Set Item = OCwBzs.Item(Vindex)

End Function

Public Sub Remove(Vindex, Optional NeedDel As Integer = 1)

If NeedDel = 1 Then
   Dim mCwBz As CwBz
   Set mCwBz = OCwBzs(Vindex)
   mCwBz.DbDel
End If
   
OCwBzs.Remove (Vindex)
      
End Sub

Public Sub ClearAll()

Dim i, Vcount As Integer
Vcount = OCwBzs.Count

For i = 1 To Vcount
   OCwBzs.Remove (1)
Next

End Sub

Public Sub Fillbydb(Optional Wherestr As String = "", Optional Orderstr As String = "CwbzCode")
   Dim OCwBz As CwBz
   Dim Rs As DbRs
   Dim SqlStr As String
   Dim vKey As Integer
On Error GoTo ErrorHandle

   ClearAll
   
   SqlStr = "SELECT CwbzCode,CwBzMC,CwBzExra,CWBZISSTOP,CwBzNO FROM CwBzREC "
   
   If Wherestr <> "" Then
      SqlStr = SqlStr + " where " + Wherestr
   End If
   
   If Orderstr <> "" Then
      SqlStr = SqlStr + " order by " + Orderstr
   End If
   
   Set Rs = New DbRs
   
   Rs.Fillbydb SqlStr
   Rs.MoveFirst
   
   vKey = 1

   Do Until Rs.EOF
      Set OCwBz = New CwBz
      OCwBz.Cwbz_Key = vKey
      OCwBz.BatchLet Rs!CwbzCode, Rs!CwbzMc, Rs!CwbzExra, Rs!CwbzIsStop, Rs!CwbzNo
      OCwBzs.Add OCwBz, CStr(vKey)
      Rs.MoveNext
      vKey = vKey + 1
   Loop

   Set Rs = Nothing

Exit Sub
ErrorHandle:
   Set Rs = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Public Function NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
Attribute NewEnum.VB_MemberFlags = "40"

  Set NewEnum = OCwBzs.[_NewEnum]
  
End Function

Private Sub Class_Initialize()

Set OCwBzs = New Collection

End Sub

Private Sub Class_Terminate()

Set OCwBzs = Nothing

End Sub

Public Property Get Name() As String

Name = "CwBzs"

End Property

Public Sub DbSave()
   Dim mNotSaved As Collection
   Dim mCwBz As CwBz
On Error GoTo ErrorHandle
   
   Set mNotSaved = New Collection
   
   gDbCommon.Conn.BeginTrans
   
   For Each mCwBz In OCwBzs
      If mCwBz.Cwbz_id = -1 Then
         mNotSaved.Add mCwBz
      End If
      mCwBz.DbSave
   Next
   
   gDbCommon.Conn.CommitTrans
   
   Set mNotSaved = Nothing

Exit Sub
ErrorHandle:
   For Each mCwBz In mNotSaved
      mCwBz.Cwbz_id = -1
   Next
   Set mNotSaved = Nothing
   gDbCommon.Conn.RollbackTrans
   Err.Raise vbObjectError + 1, , gDbCommon.Conn.Errors(0)
End Sub