frmhwid.frm

制造业产供销与往来系统源码,包括进销存及全部控件！

Private Sub Clearcontrol()
On Error GoTo Errorhandle

   Text(TxtHwIdhDocno).Text = ""
   Text(TxtHwIdh_CwqjCode).Text = ""
   Combo(CBxHwIdh_HwIoRcCode).Text = ""
   
   Text(TxtTotalQty).Text = ""
   Text(TxtTotalAmt).Text = ""
   
   Flex(FlexHwId).Rows = 1
   Flex(FlexHwId).AddItem ""
   
   Text(TxtHwIdhDocno).SetFocus
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SaveRecord(RecordName As String)
On Error GoTo Errorhandle
   
   SetValueToObject
   oHwIdh.Save
   
   gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwId), RecordName

Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub SetValueToObject()
   Dim mHwId As HwId
   Dim I As Integer
On Error GoTo Errorhandle

   oHwIdh.HwIdhType = 1
   oHwIdh.HwIdhDocno = Trim(Text(TxtHwIdhDocno).Text)
   oHwIdh.HwIdhDat = gPublicFunction.ConvDateToString(Text(TxtHwIdhDat).Text)
   oHwIdh.HwIdh_CwQjCode = Trim(Text(TxtHwIdh_CwqjCode).Text)
   oHwIdh.HwIdh_HwIoRcCode = Trim(Combo(CBxHwIdh_HwIoRcCode).Text)
   oHwIdh.HwIdhForm = UCase(Me.Name)
   
   For I = 1 To Flex(FlexHwId).Rows - 2
      Set mHwId = oHwIdh.HwIds(CStr(Flex(FlexHwId).RowData(I)))
      mHwId.HwId_HwBmCode = Trim(Flex(FlexHwId).TextMatrix(I, Flex(FlexHwId).ColIndex("HWBMCODE")))
      mHwId.HwId_HwDwCode = Trim(Flex(FlexHwId).TextMatrix(I, Flex(FlexHwId).ColIndex("HWDWCODE")))
      mHwId.HwId_HwDwConv = Val(Flex(FlexHwId).TextMatrix(I, Flex(FlexHwId).ColIndex("HWID_HWDWCONV")))
      mHwId.HwId_HwCkMc = Trim(Flex(FlexHwId).TextMatrix(I, Flex(FlexHwId).ColIndex("HWCKMC")))
      mHwId.HwIdQty = Val(Flex(FlexHwId).TextMatrix(I, Flex(FlexHwId).ColIndex("HWIDQTY")))
      mHwId.HwIdPrice = Val(Flex(FlexHwId).TextMatrix(I, Flex(FlexHwId).ColIndex("HWIDPRICE")))
      mHwId.HwIdAmt = Val(Flex(FlexHwId).TextMatrix(I, Flex(FlexHwId).ColIndex("HWIDAMT")))
      mHwId.HwIdBz = Trim(Flex(FlexHwId).TextMatrix(I, Flex(FlexHwId).ColIndex("HWIDBZ")))
   Next
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub DelRecord(RecordName As String)
On Error GoTo Errorhandle


   Select Case UCase(RecordName)
   Case "DEL"
   
         If oHwIdh Is Nothing Then
            Err.Raise vbObjectError + 1, , "无单据，不能进行删除！"
            Exit Sub
         End If
      
         If MsgBox("您真的要删除当前整张单据吗？", vbYesNo + vbQuestion) = vbYes Then
            oHwIdh.Del
            Set oHwId = Nothing
            Set oHwIdh = Nothing
            Clearcontrol
         End If
   
   Case "DEF"
   
         If Flex(FlexHwId).Row = Flex(FlexHwId).Rows - 1 Then
            Exit Sub
         End If
      
         If MsgBox("您真的要删除单据当前行吗？", vbYesNo + vbQuestion) = vbYes Then
            oHwIdh.HwIds.Remove CStr(oHwId.HwIdKey)
            Flex(FlexHwId).RemoveItem Flex(FlexHwId).Row
            If Flex(FlexHwId).Rows = 2 Then
               Set oHwId = Nothing
               Set oHwIdh = Nothing
               Clearcontrol
               gPublicFunction.SetToolbarStatu Me, Tlbaction(TlbHwId), "CAN"
            Else
               If Flex(FlexHwId).Row = Flex(FlexHwId).Rows - 1 Then
                  Flex(FlexHwId).Row = Flex(FlexHwId).Row - 1
               End If
               Set oHwId = oHwIdh.HwIds(CStr(Flex(FlexHwId).RowData(Flex(FlexHwId).Row)))
            End If
         End If
      
   End Select
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Flex_RowColChange(Index As Integer)
On Error GoTo Errorhandle

   Select Case Index
   Case FlexHwId
   
         If Flex(FlexHwId).Row <> Flex(FlexHwId).Rows - 1 Then
            Set oHwId = oHwIdh.HwIds(CStr(Flex(FlexHwId).RowData(Flex(FlexHwId).Row)))
         Else
            Set oHwId = Nothing
         End If
   
   End Select
   
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub SetValueToControl()
On Error GoTo Errorhandle

   Text(TxtHwIdhDocno).Text = oHwIdh.HwIdhDocno
   Text(TxtHwIdhDat).Text = gPublicFunction.ConvStringToDate(oHwIdh.HwIdhDat)
   Text(TxtHwIdh_CwqjCode).Text = oHwIdh.HwIdh_CwQjCode
   Combo(CBxHwIdh_HwIoRcCode).Text = oHwIdh.HwIdh_HwIoRcCode
   LoadDataIntoGrid
   
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Unload(Cancel As Integer)
On Error GoTo Errorhandle

   Set oHwIdhs = Nothing
   Set oHwIdh = Nothing
   Set oHwId = Nothing
   
   gPublicFunction.SaveFormSet Me
    
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub muEdit_Click(Index As Integer)
On Error GoTo Errorhandle

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Text_KeyDown(Index As Integer, KeyCode As Integer, Shift As Integer)
On Error GoTo Errorhandle

   gPublicFunction.FormKeyDown Me, KeyCode, Shift, Text(Index)

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Text_KeyPress(Index As Integer, KeyAscii As Integer)
On Error GoTo Errorhandle

   gPublicFunction.InputCheck Me, Text(Index), KeyAscii

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub SetControlToFlex()
   Dim mCurCol As Integer
   Dim mCurRow As Integer
On Error GoTo Errorhandle
   
   If Tlbaction(TlbHwId).Tag = "" Then
      Exit Sub
   End If

   mCurRow = Flex(FlexHwId).Row
   mCurCol = Flex(FlexHwId).Col
   
   Select Case Flex(FlexHwId).ColKey(Flex(FlexHwId).Col)
   Case "HWBMCODE"
         If oHwId Is Nothing Then
            AddNewRecord
         Else
            oHwId.HwId_HwBmCode = Trim(Flex(FlexHwId).TextMatrix(mCurRow, mCurCol))
            Flex(FlexHwId).TextMatrix(mCurRow, Flex(FlexHwId).ColIndex("HWBMMC")) = oHwId.HwId_HwBmMc
            Flex(FlexHwId).TextMatrix(mCurRow, Flex(FlexHwId).ColIndex("HWDWCODE")) = oHwId.HwId_HwDwCode
            Flex(FlexHwId).TextMatrix(mCurRow, Flex(FlexHwId).ColIndex("HWID_HWDWCONV")) = oHwId.HwId_HwDwConv
         End If
   
   Case "HWDWCODE"
         If Not oHwId Is Nothing Then
            oHwId.HwId_HwDwCode = Trim(Flex(FlexHwId).TextMatrix(mCurRow, mCurCol))
         End If
         
   Case "HWID_HWDWCONV"
         If Not oHwId Is Nothing Then
            oHwId.HwId_HwDwConv = Val(Flex(FlexHwId).TextMatrix(mCurRow, mCurCol))
         End If
         
   Case "HWCKMC"
         If Not oHwId Is Nothing Then
            oHwId.HwId_HwCkMc = Trim(Flex(FlexHwId).TextMatrix(mCurRow, mCurCol))
         End If
   
   Case "HWIDQTY"
         If Not oHwId Is Nothing Then
            oHwId.HwIdQty = Val(Flex(FlexHwId).TextMatrix(Flex(FlexHwId).Row, mCurCol))
            Flex(FlexHwId).TextMatrix(Flex(FlexHwId).Row, Flex(FlexHwId).ColIndex("HWIDAMT")) = oHwId.HwIdAmt
         End If
   
   Case "HWIDPRICE"
         If Not oHwId Is Nothing Then
            oHwId.HwIdPrice = Val(Flex(FlexHwId).TextMatrix(Flex(FlexHwId).Row, mCurCol))
            Flex(FlexHwId).TextMatrix(Flex(FlexHwId).Row, Flex(FlexHwId).ColIndex("HWIDAMT")) = oHwId.HwIdAmt
         End If
   
   Case "HWIDAMT"
         If Not oHwId Is Nothing Then
            oHwId.HwIdAmt = Val(Flex(FlexHwId).TextMatrix(Flex(FlexHwId).Row, mCurCol))
         End If
   
   Case "HWIDBZ"
         If Not oHwId Is Nothing Then
            oHwId.HwIdBz = Trim(Flex(FlexHwId).TextMatrix(Flex(FlexHwId).Row, mCurCol))
         End If
   
   End Select
   
   If UCase(Flex(FlexHwId).ColKey(Flex(FlexHwId).Col)) = "HWIDQTY" Or UCase(Flex(FlexHwId).ColKey(Flex(FlexHwId).Col)) = "HWIDPRICE" Or UCase(Flex(FlexHwId).ColKey(Flex(FlexHwId).Col)) = "HWIDAMT" Then
      gPublicFunction.SumFlexQtyAmt Flex(FlexHwId), "HWIDQTY,HWIDAMT", Text(TxtTotalQty), Text(TxtTotalAmt)
   End If

Exit Sub
Errorhandle:
   Flex(FlexHwId).TextMatrix(mCurRow, mCurCol) = mCurColOldValue
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub AddNewRecord()
   Dim mCurRow As Integer
On Error GoTo Errorhandle

   mCurRow = Flex(FlexHwId).Row

   If Trim(Flex(FlexHwId).TextMatrix(mCurRow, Flex(FlexHwId).Col)) <> "" Then
      Set oHwId = New HwId
      Set oHwId.HwIdh = oHwIdh
      oHwId.HwId_HwBmCode = Trim(Flex(FlexHwId).TextMatrix(mCurRow, Flex(FlexHwId).Col))
      Flex(FlexHwId).TextMatrix(mCurRow, Flex(FlexHwId).ColIndex("HWBMMC")) = oHwId.HwId_HwBmMc
      Flex(FlexHwId).TextMatrix(mCurRow, Flex(FlexHwId).ColIndex("HWDWCODE")) = oHwId.HwId_HwDwCode
      Flex(FlexHwId).TextMatrix(mCurRow, Flex(FlexHwId).ColIndex("HWID_HWDWCONV")) = oHwId.HwId_HwDwConv
      oHwIdh.HwIds.Add oHwId, 0
      Flex(FlexHwId).RowData(Flex(FlexHwId).Rows - 1) = oHwId.HwIdKey
      Flex(FlexHwId).AddItem ""
   End If

Exit Sub
Errorhandle:
   Set oHwId = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Private Sub Form_Resize()
On Error GoTo Errorhandle
   gPublicFunction.ResizeForm Me
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Text_LostFocus(Index As Integer)
On Error GoTo Errorhandle

   Select Case Index
   Case TxtHwIdhDat
         
         If Tlbaction(TlbHwId).Tag <> "" And Trim(Text(TxtHwIdhDat).Text) <> "" Then
            Text(TxtHwIdhDat).Text = gPublicFunction.SetDateFormat(Text(TxtHwIdhDat).Text)
            oHwIdh.HwIdhDat = gPublicFunction.ConvDateToString(Text(TxtHwIdhDat).Text)
            Text(TxtHwIdh_CwqjCode).Text = oHwIdh.HwIdh_CwQjCode
         End If
         
   Case TxtHwIdhDocno
   
           If Tlbaction(TlbHwId).Tag = "" Then
               If Trim(Text(Index).Text) = "" Then
                  Exit Sub
               End If
               
               If Not oHwIdh Is Nothing Then
                  If oHwIdh.HwIdhDocno = Text(TxtHwIdhDocno).Text Then
                     Exit Sub
                  End If
               End If
   
               Set oHwIdh = New HwIdh
               If oHwIdh.Requery(Text(TxtHwIdhDocno).Text) = 1 Then
                   SetValueToControl
               Else
                   Set oHwIdh = Nothing
                   Dim vHwIddocno As String
                   vHwIddocno = Text(TxtHwIdhDocno).Text
                   AddRecord "ADD"
                   Text(TxtHwIdhDocno).Text = vHwIddocno
               End If
        End If

   End Select

Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub Tlbaction_ButtonClick(Index As Integer, ByVal Button As MSComctlLib.Button)
    Dim Action, RecordName As String
On Error GoTo Errorhandle

    Action = (Mid(Button.Key, 1, 3))
    RecordName = Button.Key
    
   If Trim(Flex(FlexHwId).EditText) <> "" Then
      Flex(FlexHwId).TextMatrix(Flex(FlexHwId).Row, Flex(FlexHwId).Col) = Trim(Flex(FlexHwId).EditText)
   End If
   
    Select Case Action
        Case "ADD"
             AddRecord RecordName
        Case "CHG"
             ChgRecord RecordName
        Case "CAN"
             CancelRecord RecordName
        Case "SAV"
             SaveRecord RecordName
        Case "DEL", "DEF"
             DelRecord RecordName
        Case "EXI"
             Unload Me
        Case "FIN"
             ShowBmQuery
        Case Else
            
    End Select
    Exit Sub
Errorhandle:
    MsgBox Err.Description
End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
   Dim mButton As Button
On Error GoTo Errorhandle

   Set mButton = gPublicFunction.GetToolBarButton(Me, KeyCode)
   
   If Not mButton Is Nothing Then
      Tlbaction_ButtonClick TlbHwId, mButton
   End If
  
Exit Sub
Errorhandle:
   MsgBox Err.Description
End Sub

Private Sub ShowBmQuery()
   Dim mCodeType As String
   Dim mQueryValue As String
On Error GoTo Errorhandle

   If Tlbaction(TlbHwId).Tag = "" Then
      Exit Sub
   End If

   If Me.ActiveControl Is Nothing Then
      Exit Sub
   End If
      
   If Me.ActiveControl Is Flex(FlexHwId) Then
   
      Select Case UCase(Flex(FlexHwId).ColKey(Flex(FlexHwId).Col))
      Case "HWBMCODE", "HWDWCODE", "HWCKMC"
            mCodeType = UCase(Flex(FlexHwId).ColKey(Flex(FlexHwId).Col))
      End Select
      
      If mCodeType <> "" Then
         mQueryValue = gPublicFunction.GetBmQueryValue(Me, mCodeType)
         If mQueryValue <> "" Then
            Flex(FlexHwId).TextMatrix(Flex(FlexHwId).Row, Flex(FlexHwId).Col) = mQueryValue
            Flex(FlexHwId).EditCell
            SetControlToFlex
         End If
      End If
      
   Else
   
      Select Case Mid(UCase(Me.ActiveControl.Tag), 4)
      Case "CWQJCODE", "HWIORCCODE"
            mCodeType = Mid(UCase(Me.ActiveControl.Tag), 4)
      End Select
   
      If mCodeType <> "" Then
         mQueryValue = gPublicFunction.GetBmQueryValue(Me, mCodeType)
         If mQueryValue <> "" Then
            Me.ActiveControl.Text = mQueryValue
         End If
      End If
      
   End If
  
Exit Sub
Errorhandle:
   Err.Raise vbObjectError + 1, , Err.Description
End Sub