hwids.cls

制造业产供销与往来系统源码,包括进销存及全部控件！

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "HwIds"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit
Dim OHwIds As Collection

Public Property Get Name() As String
   Name = "HwIds"
End Property

Private Sub Class_Initialize()
   Set OHwIds = New Collection
End Sub

Public Sub Add(oHwId As HwId, Optional Needsave As Integer = 1)
   Dim mKey As Integer
   Dim vHwId As HwId
   For Each vHwId In OHwIds
      If mKey < vHwId.HwIdKey Then
         mKey = vHwId.HwIdKey
      End If
   Next
   oHwId.HwIdKey = mKey + 1
   If Needsave = 1 Then
      oHwId.Save
   End If
   OHwIds.Add Item:=oHwId, Key:=CStr(mKey + 1)
End Sub

Public Sub Remove(Vindex, Optional Needdel As Integer = 1)
 
   Dim oHwId As HwId
   Set oHwId = Item(Vindex)
   If Needdel = 1 And oHwId.HwIdId = 1 Then
      oHwId.Del
   End If
   OHwIds.Remove (Vindex)
   Set oHwId = Nothing
   
End Sub

Public Property Get Count() As Integer
   Count = OHwIds.Count
End Property

Public Function Item(Vindex) As HwId
Attribute Item.VB_UserMemId = 0
   Set Item = OHwIds.Item(Vindex)
End Function

Public Sub ClearAll()
   Dim i, Vcount As Integer
   Vcount = OHwIds.Count
   For i = 1 To Vcount
      OHwIds.Remove (1)
   Next
End Sub

Public Sub Fillbydb(vHwIdh As HwIdh)
   Dim oHwId As HwId
   Dim mRs As DbRs
   Dim mKey As Integer
   Dim mSqlStr As String
On Error GoTo Errorhandle

   ClearAll
   
   mSqlStr = "SELECT HwId_HwIdHNO,HwId_HwBmCode=COALESCE((SELECT HwBmCode FROM HWBMREC WHERE HWBMNO=HwId_HWBMNO),''),HwId_HwBmMc=COALESCE((SELECT HwBmMc FROM HWBMREC WHERE HWBMNO=HwId_HWBMNO),''),HwId_HWBMNO,"
   mSqlStr = mSqlStr & "HwId_HwCkMc=COALESCE((SELECT HwCkMc FROM HWCKREC WHERE HWCKNO=HwId_HWCKNO),''),HwId_HWCKNO,"
   mSqlStr = mSqlStr & "HwId_HwDwCode=COALESCE((SELECT HWDWCode FROM HWDWREC WHERE HWDWNO=HwId_HWDWNO),''),HwId_HWDWNO,HwId_HWDWCONV,"
   mSqlStr = mSqlStr & "HwIdQTY,HwIdPRICE,HwIdAMT,"
   mSqlStr = mSqlStr & "HwIdBZ,HwIdMINO,HwIdMIONO,HwIdNO FROM HwIdREC WHERE HwId_HwIdHNO=" & CStr(vHwIdh.HwIdhNo)
   
   Set mRs = New DbRs
   mRs.Fillbydb mSqlStr
   
   mRs.MoveFirst
   
   mKey = 1
   Do Until mRs.EOF
      Set oHwId = New HwId
      Set oHwId.HwIdh = vHwIdh
      oHwId.HwIdKey = mKey
      oHwId.BatchLet mRs!HwId_HwIdhno, mRs!HwId_HwBmCode, mRs!HwId_HwBmMc, mRs!HwId_HwBmno, _
                      mRs!HwId_HwCkMc, mRs!HwId_HwCkno, mRs!HwId_HwDwCode, mRs!HwId_HwDwno, mRs!HwId_HwDwConv, _
                      mRs!HwIdQty, mRs!HwIdPrice, mRs!HwIdAmt, _
                      mRs!HwIdBz, mRs!HwIdMiNo, mRs!HwIdMioNo, mRs!HwIdNo
      OHwIds.Add Item:=oHwId, Key:=CStr(mKey)
      mRs.MoveNext
      mKey = mKey + 1
   Loop
   
   Set mRs = Nothing

Exit Sub
Errorhandle:
   Set mRs = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Public Function NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
Attribute NewEnum.VB_MemberFlags = "40"
  Set NewEnum = OHwIds.[_NewEnum]
End Function

Private Sub Class_Terminate()
   ClearAll
   Set OHwIds = Nothing
End Sub

Public Sub Save(vHwIdh As HwIdh)
   Dim mNotSaved As Collection
   Dim mHwId As HwId
On Error GoTo Errorhandle
   
   Set mNotSaved = New Collection
   
   For Each mHwId In vHwIdh.HwIds
      If mHwId.HwIdId = -1 Then
         mNotSaved.Add mHwId
      End If
      mHwId.Save
   Next
   
   Set mNotSaved = Nothing
   
Exit Sub
Errorhandle:
   For Each mHwId In mNotSaved
      mHwId.HwIdId = -1
   Next
   Set mNotSaved = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub