arivds.cls

制造业产供销与往来系统源码,包括进销存及全部控件！

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "Arivds"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit
Dim OArivds As Collection

Public Property Get Name() As String
   Name = "Arivds"
End Property

Private Sub Class_Initialize()
   Set OArivds = New Collection
End Sub

Public Sub Add(oArivd As Arivd, Optional Needsave As Integer = 1)
   Dim mKey As Integer
   Dim vArivd As Arivd
   For Each vArivd In OArivds
      If mKey < vArivd.ArivdKey Then
         mKey = vArivd.ArivdKey
      End If
   Next
   oArivd.ArivdKey = mKey + 1
   If Needsave = 1 Then
      oArivd.Save
   End If
   OArivds.Add Item:=oArivd, Key:=CStr(mKey + 1)
End Sub

Public Sub Remove(Vindex, Optional Needdel As Integer = 1)
 
   Dim oArivd As Arivd
   Set oArivd = Item(Vindex)
   If Needdel = 1 And oArivd.ArivdId = 1 Then
      oArivd.Del
   End If
   OArivds.Remove (Vindex)
   Set oArivd = Nothing
   
End Sub

Public Property Get Count() As Integer
   Count = OArivds.Count
End Property

Public Function Item(Vindex) As Arivd
Attribute Item.VB_UserMemId = 0
   Set Item = OArivds.Item(Vindex)
End Function

Public Sub ClearAll()
   Dim i, Vcount As Integer
   Vcount = OArivds.Count
   For i = 1 To Vcount
      OArivds.Remove (1)
   Next
End Sub

Public Sub Fillbydb(vArivdh As Arivdh)
   Dim oArivd As Arivd
   Dim mRs As DbRs
   Dim mKey As Integer
   Dim mSqlStr As String
On Error GoTo Errorhandle

   ClearAll
   
   mSqlStr = "SELECT Arivd_ArivdHNO,Arivd_HwBmCode=COALESCE((SELECT HwBmCode FROM HWBMREC WHERE HWBMNO=Arivd_HWBMNO),''),Arivd_HwBmMc=COALESCE((SELECT HwBmMc FROM HWBMREC WHERE HWBMNO=Arivd_HWBMNO),''),Arivd_HWBMNO,"
   mSqlStr = mSqlStr & "Arivd_HwDwCode=COALESCE((SELECT HWDWCode FROM HWDWREC WHERE HWDWNO=Arivd_HWDWNO),''),Arivd_HWDWNO,Arivd_HWDWCONV,"
   mSqlStr = mSqlStr & "ArivdQTY,ArivdPRICE,ArivdNtAmt,ArivdTAMT,ArivdAMT,"
   mSqlStr = mSqlStr & "Arivd_CWSMCODE=COALESCE((SELECT CWSMCODE FROM CWSMREC WHERE CWSMNO=Arivd_CWSMNO),''),Arivd_CWSMNO,Arivd_CWSMCONV,"
   mSqlStr = mSqlStr & "ArivdBZ,ArivdNO FROM ArivdREC WHERE Arivd_ArivdhNO=" & CStr(vArivdh.ArivdhNo)
   
   Set mRs = New DbRs
   mRs.Fillbydb mSqlStr
   
   mRs.MoveFirst
   
   mKey = 1
   Do Until mRs.EOF
      Set oArivd = New Arivd
      Set oArivd.Arivdh = vArivdh
      oArivd.ArivdKey = mKey
      oArivd.BatchLet mRs!Arivd_Arivdhno, mRs!Arivd_HwBmCode, mRs!Arivd_HwBmMc, mRs!Arivd_HwBmno, _
                      mRs!Arivd_HwDwCode, mRs!Arivd_HwDwno, mRs!Arivd_HwDwConv, _
                      mRs!ArivdQty, mRs!ArivdPrice, mRs!ArivdNtAmt, mRs!ArivdTAmt, mRs!ArivdAmt, _
                      mRs!Arivd_CwSmCode, mRs!Arivd_CwSmno, mRs!Arivd_CwsmConv, _
                      mRs!ArivdBz, mRs!ArivdNo
      OArivds.Add Item:=oArivd, Key:=CStr(mKey)
      mRs.MoveNext
      mKey = mKey + 1
   Loop
   
   Set mRs = Nothing

Exit Sub
Errorhandle:
   Set mRs = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Public Function NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
Attribute NewEnum.VB_MemberFlags = "40"
  Set NewEnum = OArivds.[_NewEnum]
End Function

Private Sub Class_Terminate()
   ClearAll
   Set OArivds = Nothing
End Sub

Public Sub Save(vArivdh As Arivdh)
   Dim mNotSaved As Collection
   Dim mArivd As Arivd
On Error GoTo Errorhandle
   
   Set mNotSaved = New Collection
   
   For Each mArivd In vArivdh.Arivds
      If mArivd.ArivdId = -1 Then
         mNotSaved.Add mArivd
      End If
      mArivd.Save
   Next
   
   Set mNotSaved = Nothing
   
Exit Sub
Errorhandle:
   For Each mArivd In mNotSaved
      mArivd.ArivdId = -1
   Next
   Set mNotSaved = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub