scbcds.cls

制造业产供销与往来系统源码,包括进销存及全部控件！

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "ScBcds"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit
Dim OScBcds As Collection

Public Property Get Name() As String
   Name = "ScBcds"
End Property

Private Sub Class_Initialize()
   Set OScBcds = New Collection
End Sub

Public Sub Add(oScBcd As ScBcd, Optional Needsave As Integer = 1)
   Dim mKey As Integer
   Dim vScBcd As ScBcd
   For Each vScBcd In OScBcds
      If mKey < vScBcd.ScBcdKey Then
         mKey = vScBcd.ScBcdKey
      End If
   Next
   oScBcd.ScBcdKey = mKey + 1
   If Needsave = 1 Then
      oScBcd.Save
   End If
   OScBcds.Add Item:=oScBcd, Key:=CStr(mKey + 1)
End Sub

Public Sub Remove(Vindex, Optional Needdel As Integer = 1)
 
   Dim oScBcd As ScBcd
   Set oScBcd = Item(Vindex)
   If Needdel = 1 And oScBcd.ScBcdId = 1 Then
      oScBcd.Del
   End If
   OScBcds.Remove (Vindex)
   Set oScBcd = Nothing
   
End Sub

Public Property Get Count() As Integer
   Count = OScBcds.Count
End Property

Public Function Item(Vindex) As ScBcd
Attribute Item.VB_UserMemId = 0
   Set Item = OScBcds.Item(Vindex)
End Function

Public Sub ClearAll()
   Dim i, Vcount As Integer
   Vcount = OScBcds.Count
   For i = 1 To Vcount
      OScBcds.Remove (1)
   Next
End Sub

Public Sub Fillbydb(vScBcdh As ScBcdh)
   Dim oScBcd As ScBcd
   Dim mRs As DbRs
   Dim mKey As Integer
   Dim mSqlStr As String
On Error GoTo ErrorHandle

   ClearAll
   
   mSqlStr = "SELECT ScBcd_ScBcdHNO,ScBcd_SCDDOCNO=COALESCE((SELECT SCDDOCNO FROM SCDREC WHERE SCDNO=ScBcd_SCDNO),''),ScBcd_SCDNO,"
   mSqlStr = mSqlStr & "ScBcd_SCDQTY=COALESCE((SELECT SCDQTY FROM SCDREC WHERE SCDNO=ScBcd_SCDNO),0),ScBcd_SCDWQTY=COALESCE((SELECT SCDWQTY FROM SCDREC WHERE SCDNO=ScBcd_SCDNO),0),"
   mSqlStr = mSqlStr & "ScBcd_HwBmCode=COALESCE((SELECT HwBmCode FROM HWBMREC WHERE HWBMNO=ScBcd_HWBMNO),''),ScBcd_HwBmMc=COALESCE((SELECT HwBmMc FROM HWBMREC WHERE HWBMNO=ScBcd_HWBMNO),''),ScBcd_HWBMNO,"
   mSqlStr = mSqlStr & "ScBcd_HwCkMc=COALESCE((SELECT HwCkMc FROM HWCKREC WHERE HWCKNO=ScBcd_HWCKNO),''),ScBcd_HWCKNO,"
   mSqlStr = mSqlStr & "ScBcd_HwDwCode=COALESCE((SELECT HWDWCode FROM HWDWREC WHERE HWDWNO=ScBcd_HWDWNO),''),ScBcd_HWDWNO,ScBcd_HWDWCONV,"
   mSqlStr = mSqlStr & "ScBcdQTY,ScBcdPRICE,ScBcdAMT,ScBcdBZ,ScBcdMIONO,ScBcdNO FROM ScBcdREC WHERE ScBcd_ScBcdHNO=" & CStr(vScBcdh.ScBcdhNo)
   
   Set mRs = New DbRs
   mRs.Fillbydb mSqlStr
   
   mRs.MoveFirst
   
   mKey = 1
   Do Until mRs.EOF
      Set oScBcd = New ScBcd
      Set oScBcd.ScBcdh = vScBcdh
      oScBcd.ScBcdKey = mKey
      oScBcd.BatchLet mRs!ScBcd_ScBcdhno, mRs!ScBcd_Scdno, mRs!ScBcd_ScdDocno, mRs!ScBcd_HwBmCode, mRs!ScBcd_HwBmMc, mRs!ScBcd_HwBmno, _
                        mRs!ScBcd_HwCkMc, mRs!ScBcd_HwCkno, mRs!ScBcd_HwDwCode, mRs!ScBcd_HwDwno, mRs!ScBcd_HwDwConv, _
                        mRs!ScBcd_ScdQty, mRs!ScBcd_ScdWQty, mRs!ScBcdQty, mRs!ScBcdPrice, mRs!ScBcdAmt, mRs!ScBcdBz, mRs!ScBcdMioNo, mRs!ScBcdNo
      OScBcds.Add Item:=oScBcd, Key:=CStr(mKey)
      mRs.MoveNext
      mKey = mKey + 1
   Loop
   
   Set mRs = Nothing

Exit Sub
ErrorHandle:
   Set mRs = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Public Function NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
Attribute NewEnum.VB_MemberFlags = "40"
  Set NewEnum = OScBcds.[_NewEnum]
End Function

Private Sub Class_Terminate()
   ClearAll
   Set OScBcds = Nothing
End Sub

Public Sub Save(vScBcdh As ScBcdh)
   Dim mNotSaved As Collection
   Dim mScBcd As ScBcd
On Error GoTo ErrorHandle
   
   Set mNotSaved = New Collection
   
   For Each mScBcd In vScBcdh.ScBcds
      If mScBcd.ScBcdId = -1 Then
         mNotSaved.Add mScBcd
      End If
      mScBcd.Save
   Next
   
   Set mNotSaved = Nothing
   
Exit Sub
ErrorHandle:
   For Each mScBcd In mNotSaved
      mScBcd.ScBcdId = -1
   Next
   Set mNotSaved = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub