sysugprivs.cls

制造业产供销与往来系统源码,包括进销存及全部控件！

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "SysUgPrivs"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit

Dim OSysUgPrivs As Collection

Public Property Get Count() As Integer

Count = OSysUgPrivs.Count
    
End Property

Public Sub Add(OSysUgPriv As SysUgPriv)

Dim vKey As Integer, vSysUgPriv As SysUgPriv

For Each vSysUgPriv In OSysUgPrivs
   If vSysUgPriv.SysUgPriv_Key > vKey Then
      vKey = vSysUgPriv.SysUgPriv_Key
   End If
Next

vKey = vKey + 1

OSysUgPriv.SysUgPriv_Key = vKey
OSysUgPrivs.Add OSysUgPriv, CStr(vKey)

End Sub

Public Function Item(Vindex) As SysUgPriv
Attribute Item.VB_UserMemId = 0

   Set Item = OSysUgPrivs.Item(Vindex)

End Function

Public Sub Remove(Vindex)
   
OSysUgPrivs.Remove (Vindex)
      
End Sub

Public Sub ClearAll()

Dim i, Vcount As Integer
Vcount = OSysUgPrivs.Count

For i = 1 To Vcount
   OSysUgPrivs.Remove (1)
Next

End Sub

Public Sub Fillbydb(vSysUg As SysUg, Optional Wherestr As String = "", Optional Orderstr As String = "SysUgPrivCODE")
   Dim OSysUgPriv As SysUgPriv
   Dim Rs As DbRs
   Dim SqlStr As String
   Dim vKey As Integer
On Error GoTo ErrorHandle

   ClearAll
      
   Set Rs = New DbRs
   Rs.Fillbydb "SYSUGPRIVREC_LIST " & "0," & CStr(vSysUg.SysUgNo)
   
   Rs.MoveFirst
   
   vKey = 1
   
   Do While Not Rs.EOF
      Set OSysUgPriv = New SysUgPriv
      Set OSysUgPriv.Parent = vSysUg
      OSysUgPriv.SysUgPriv_Key = vKey
      OSysUgPriv.BatchLet Rs!SysUgPriv_SysUgNo, Rs!SysxtjgNo, Rs!SysUgPriv_SysFormNo, Rs!SysUgPriv_SysFormCode, Rs!SysUgPriv_SysFormMc, Rs!SysUgPrivNo, Rs!SelectFlg
      If Rs!SelectFlg = 0 Then
         OSysUgPriv.SysUgPriv_id = -1
      End If
      OSysUgPrivs.Add OSysUgPriv, CStr(vKey)
      vKey = vKey + 1
      Rs.MoveNext
   Loop
   
   Set Rs = Nothing

Exit Sub
ErrorHandle:
   Set Rs = Nothing
   Err.Raise vbObjectError + 1, , Err.Description
End Sub

Public Function NewEnum() As IUnknown
Attribute NewEnum.VB_UserMemId = -4
Attribute NewEnum.VB_MemberFlags = "40"

  Set NewEnum = OSysUgPrivs.[_NewEnum]
  
End Function

Private Sub Class_Initialize()

Set OSysUgPrivs = New Collection

End Sub

Private Sub Class_Terminate()

Set OSysUgPrivs = Nothing

End Sub

Public Property Get Name() As String

Name = "SysUgPrivs"

End Property

Public Sub DbSave()
   Dim mNotSaved As Collection
   Dim mNotDeled As Collection
   Dim mSysUgPriv As SysUgPriv
On Error GoTo ErrorHandle
   
   Set mNotSaved = New Collection
   Set mNotDeled = New Collection
      
   For Each mSysUgPriv In OSysUgPrivs
      If mSysUgPriv.SelectFlg = 1 Then
         If mSysUgPriv.SysUgPriv_id = -1 Then
            mNotSaved.Add mSysUgPriv
         End If
         mSysUgPriv.DbSave
      Else
         If mSysUgPriv.SysUgPriv_id = 1 Then
            mNotDeled.Add mSysUgPriv
            mSysUgPriv.DbDel
            mSysUgPriv.SysUgPriv_id = -1
         End If
      End If
   Next
   
   Set mNotSaved = Nothing
   Set mNotDeled = Nothing

Exit Sub
ErrorHandle:
   For Each mSysUgPriv In mNotSaved
      mSysUgPriv.SysUgPriv_id = -1
   Next
   For Each mSysUgPriv In mNotDeled
      mSysUgPriv.SysUgPriv_id = 1
   Next
   Set mNotSaved = Nothing
   Set mNotDeled = Nothing
   Err.Raise vbObjectError + 1, , gDbCommon.Conn.Errors(0)
End Sub