export-class.ulp

老外的PCB设计软件,是免费的.可以上网更新.

#usage "<b>Export Net-Classes</b>\n"
       "<p>"
       "<author>Author: [e-mail]</author>"

// THIS PROGRAM IS PROVIDED AS IS AND WITHOUT WARRANTY OF ANY KIND, EXPRESSED OR IMPLIED

string grid[] = { "MIC", "MM", "MIL", "INCH" };
int Gridval = 1;              // 0=mic 1=mm 2=mil 3=inch    ***
                              // choose the value for the units you're working with

string cmd, s;
string projectm;

real u2u(int val) {
  switch(Gridval) {
    case 0 : return u2mic(val);
    case 1 : return u2mm(val);
    case 2 : return u2mil(val);
    case 3 : return u2inch(val);
  }
}

void savescr(string projectname) {
  string file = dlgFileSave("save CLASS script", filesetext(projectname, "-class.scr"), "*.scr");
  if (file) {
    output(file, "wt" ) printf("%s", cmd);
    exit(0);
  }
  else return;
}

void menue(string projectname) {
  int Result = dlgDialog("Export Net CLASSes") {
     dlgStretch(0);
     dlgHBoxLayout dlgSpacing(500);
     dlgHBoxLayout {
       dlgVBoxLayout dlgSpacing(200);
       dlgTextEdit(cmd);
     }
     dlgStretch(0);
     dlgHBoxLayout {
        dlgStretch(0);
        dlgPushButton("+&Cancel") dlgAccept();
        dlgPushButton("&Save script") savescr(projectname);
        dlgStretch(1);
        }
     dlgStretch(0);
     };
  if (Result == 0) exit (0);
  return;
  }

void class(UL_CLASS C) {
  if (C.name) {
    sprintf(s, "CLASS %d '%s' %.4f %.4f %.4f;\n", C.number, C.name, u2u(C.width), u2u(C.clearance), u2u(C.drill) );
    cmd += s;
  }
}

// main
if (board) board(B) {
   projectm = B.name;
   sprintf(cmd, "# export from: %s\nGRID %s;\n", B.name, grid[Gridval] );
   B.classes(C) class(C);
}

else if (schematic) schematic(S) {
   projectm = S.name;
   sprintf(cmd, "# export from %s\nGRID %s;\n", S.name, grid[Gridval] );
   S.classes(C) class(C);
}

else if (library) dlgMessageBox("start this ULP in Board or Schematic", "OK");

cmd += "GRID LAST;\nCLASS";
menue(projectm);