configure.ac

机器人足球AI设计比赛

#XuYuan <[e-mail]> 2005-08-08
# Process this file with autoconf to produce a configure script.
AC_INIT([SEU-3D], 0.3.c.release-5v5, [[e-mail]])
AC_CONFIG_HEADER([config.h])
AC_CONFIG_AUX_DIR([config.aux])

AM_INIT_AUTOMAKE([gnu subdir-objects 1.7])
AC_LANG([C++])
AM_ENABLE_SHARED(yes)
AM_ENABLE_STATIC(no)


rcss_prefix=\"$prefix\"
test "$rcss_prefix" = \"NONE\" && rcss_prefix=\"$ac_default_prefix\"
AC_DEFINE_UNQUOTED(PREFIX, $rcss_prefix, [Define the install prefix. Needed by the libraries to check for ruby scripts.])

# Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AM_PROG_CC_C_O
AC_PROG_INSTALL
AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL
AC_PROG_AWK
AC_CHECK_PROG([DOXYGEN], [doxygen], [yes], [no])
AM_CONDITIONAL(DOXYGEN, test x$DOXYGEN = xyes)
AC_CHECK_PROG([HAVE_DOT], [dot], [YES], [NO])
AC_PATH_PROG([PERL], [perl], [perl])


# Checks for libraries.
TMP_LIBS=$LIBS
AC_CHECK_LIB(dl, dlopen, [AC_SUBST(SALT_LIBADD, [-ldl])],
    	     [AC_CHECK_FUNC(dlopen, [], [AC_MSG_ERROR([cannot find required library libdl or dlopen() function.])]
	    )])
LIBS=$TMP_LIBS
#AC_CHECK_LIB(pthread, pthread_create)

# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([poll.h])
AC_CHECK_HEADERS([arpa/nameser.h])
AC_CHECK_HEADERS([resolv.h])
AC_CHECK_HEADERS([float.h limits.h malloc.h memory.h stdlib.h string.h])

AC_CHECK_HEADER([boost/version.hpp],,
	AC_MSG_ERROR([boost library not found. Please specify the location 
of the boost header directory using the CPPFLAGS environment variable]))
AC_CHECK_HEADERS([hash_map],,
	AC_MSG_NOTICE(['hash_map' will be substituted by 'map'. If you need hash_map install stlport]))

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_TYPE_SIZE_T

AC_CHECK_TYPES([socklen_t], [], [], [
#include <sys/types.h>
#include <sys/socket.h>
])

# Checks for library functions.
AC_FUNC_ALLOCA
# the FUNC_MEMCMP macro has a bug when used with c++
# (see http://mail.gnu.org/archive/html/autoconf-patches/2003-05/msg00042.html)
# the workaround is to switch back to C for the test
AC_LANG([C])
AC_FUNC_MEMCMP
AC_LANG([C++])

AC_FUNC_SETVBUF_REVERSED
AC_FUNC_VPRINTF
#AC_CONFIG_LIBOBJ_DIR(./utility/libobj/)
AC_REPLACE_FUNCS([_vsnprintf])
AC_CHECK_FUNCS([atexit floor gethostname inet_ntoa memset pow socket sqrt strchr strrchr strstr strupr])

AC_SUBST(NET_LIBS)
AC_CHECK_LIB(socket, socket, [NET_LIBS="-lsocket"])
AC_CHECK_LIB(nsl, gethostbyname, [NET_LIBS="$NET_LIBS -lnsl"])
#AC_CHECK_LIB(posix4, sched_yield, [NET_LIBS="$NET_LIBS -lposix4"])
AC_CHECK_LIB(resolv, hstrerror, [NET_LIBS="$NET_LIBS -lresolv"])
RCSS_BOOST_REGEX([rcss_have_boost_regex=yes],[rcss_have_boost_regex=no])
if test "$rcss_have_boost_regex" = no; then
	AC_MSG_WARN([the ZIP filesystem plugin cannot be build])
fi
AM_CONDITIONAL(HAVE_BOOST_REGEX, test $rcss_have_boost_regex = yes)

AM_CONDITIONAL(DEBUG, test x$debug = xtrue)

# create Makefiles and other configuration files
AC_CONFIG_FILES([Makefile \
		utility/Makefile \
		utility/sexpr/Makefile \
		src/Makefile \
		doc/Makefile ])
AC_OUTPUT