modimage.bas

在VB中开发的连接SQL的图书管理系统。

Attribute VB_Name = "modImage"
Const CHUNKSIZE As Long = 100
Const BLOCKSIZE As Long = 100
Const TEMPFILE As String = "TempFile.tmp"
Const POS As Long = 6   '字段位置

Dim byteData() As Byte  '定义数据块数组
Dim DiskFile As String  '图像文件名
Dim NumBlocks As Long   '定义数据块个数
Dim FileLength As Long  '标识文件长度
Dim LeftOver As Long    '定义剩余字节长度
Dim SourceFile As Long  '定义自由文件号
Dim byteChunk() As Byte
Dim i As Long           '定义循环变量

'保存图片
Public Sub SaveImage(ByVal ImageFile As String, ByVal SQLStmt As String)
  If SQLStmt = "" Then
    Exit Sub
  End If
  If ImageFile = "" Then
    Exit Sub
  End If
  '提供一个尚未使用的文件号
  SourceFile = FreeFile
  '打开文件
  Open ImageFile For Binary Access Read As SourceFile
  '得到文件长度
  FileLength = LOF(SourceFile)
  '判断文件是否存在
  If FileLength = 0 Then
    Close SourceFile
    MsgBox DiskFile + "无内容或不存在!", vbInformation, "信息提示"
  Else
    NumBlocks = FileLength \ BLOCKSIZE '得到数据块的个数
    LeftOver = FileLength Mod BLOCKSIZE '得到剩余字节数
    '定义RecordSet对象
    Dim rs As New ADODB.Recordset
    Set rs = SQLQuery(SQLStmt)
    rs.Fields(POS).Value = Null
    ReDim byteData(BLOCKSIZE) '重新定义数据块的大小
    For i = 1 To NumBlocks
      Get SourceFile, , byteData() '读到内存块中
      rs.Fields(POS).AppendChunk byteData()  '写入FLD
    Next i
    ReDim byteData(LeftOver) '重新定义数据块的大小
    Get SourceFile, , byteData() '读到内存块中
    rs.Fields(POS).AppendChunk byteData()  '写入FLD
    Close SourceFile '关闭源文件
    rs.Update
  End If
  
  '断开连接
  DBDisconnect
End Sub

'删除图片
Public Sub DelImage(Image1 As Image, ByVal SQLStmt As String)
  '定义RecordSet对象
  Dim rs As New ADODB.Recordset
  
  Set rs = SQLQuery(SQLStmt)
  rs.Fields(POS).AppendChunk ""
  rs.Update
  
  '断开连接
  DBDisconnect
End Sub

'显示图片
Public Sub ShowImage(Image1 As Image, ByVal SQLStmt As String)
  Erase byteChunk()
  '定义RecordSet对象
  Dim rs As New ADODB.Recordset
  Set rs = SQLQuery(SQLStmt)
  FieldSize = rs.Fields(POS).ActualSize
  If FieldSize <= 0 Then
    Image1.Picture = LoadPicture("")
    Exit Sub
  End If
  '提供一个尚未使用的文件号
  SourceFile = FreeFile
  '打开文件
  Open TEMPFILE For Binary Access Write As SourceFile
  '计算数据块
  NumBlocks = FieldSize \ BLOCKSIZE
  LeftOver = FieldSize Mod BLOCKSIZE '得到剩余字节数
  '分块读取图像数据，并写入到文件中
  If LeftOver <> 0 Then
    ReDim byteChunk(LeftOver)
    byteChunk() = rs.Fields(POS).GetChunk(LeftOver)
    Put SourceFile, , byteChunk()
  End If
  For i = 1 To NumBlocks
    ReDim byteChunk(BLOCKSIZE)
    byteChunk() = rs.Fields(POS).GetChunk(BLOCKSIZE)
    Put SourceFile, , byteChunk()
  Next i
  Close SourceFile
  '将文件装入到Image1控件中
  Image1.Picture = LoadPicture(TEMPFILE)
  '删除临时文件
  Kill (TEMPFILE)
  
  '断开连接
  DBDisconnect
End Sub