ks.supply.asp

本系统是根据科汛系统编写的程序

<!--#include file="KS.PublicCls.asp"-->
<%

Class UserCls
			Private KS,I  
			'---------定义会员全局变量开始---------------
			Public ID,GroupID,UserName,PassWord,Question,Answer,Email
			Public RealName,Sex,Birthday,IDCard,OfficeTel,HomeTel,Mobile,Fax
			Public Province,City,Address,Zip,HomePage,QQ,ICQ,MSN,UC,UserFace,FaceWidth,FaceHeight,Sign,Privacy,CheckNum,RegDate
			Public JoinDate,LastLoginTime,LastLoginIP,LoginTimes,Money,Score,Point,locked,RndPassword,UserType
			Public ChargeType,Edays,BeginDate
			'---------定义会员全局变量结束---------------
			
			Private Sub Class_Initialize()
			  Set KS=New PublicCls
			End Sub
			Private Sub Class_Terminate()
			 Set KS=Nothing
			End Sub
		   '**************************************************
			'函数名：UserLoginChecked
			'作  用：判断用户是否登录
			'返回值：true或false
			'**************************************************
			Public Function UserLoginChecked()
                 on error resume next
				UserName = KS.R(Trim(KS.C("UserName")))
				PassWord= KS.R(Trim(KS.C("Password")))
				RndPassword=KS.R(Trim(KS.C("RndPassword")))
				
				IF UserName="" Then
				   UserLoginChecked=false
				   Exit Function
				Else
					Dim UserRs:Set UserRS=Server.CreateOBject("ADODB.RECORDSET")
					UserRS.Open "Select * From KS_User Where UserName='" & UserName & "' And PassWord='" & PassWord & "'",Conn,2,3
					IF UserRS.Eof And UserRS.Bof Then
					  UserLoginChecked=false
					Else
					  If KS.Setting(35)=1 And RndPassword<>UserRS("RndPassword") Then
				         UserLoginChecked=false
						 Response.Write ("<script>alert('发现有人正在使用你的账号，你被迫退出！');parent.location.href='" & KS.GetDomain & "User/UserLogout.asp';</script>")
					     Response.end
					  End If
						  UserLoginChecked=true
						  for I=0 to UserRS.fields.count-1
							if lcase(UserRS.Fields(i).Name)="sign" then
							  Sign=UserRS.Fields(i).Value
							else
							 Execute(UserRS.Fields(i).Name&"=ForValue("""&trim(UserRS.Fields(i).Value)&""")")
							end if
						  Next
					End if
					UserRS.Close:Set UserRS=Nothing
			   End IF
			End Function
			
			Public Property Get GetEdays()
					GetEdays = Edays-DateDiff("D",BeginDate,now())
			End Property

			
		    Public Function ForValue(s)
					If trim(s)="" Then ForValue=""
					ForValue=s
			End Function
			Sub InnerLocation(msg)
				Response.Write "<script language=""JavaScript"">locationid.innerHTML = """ & msg & """;</script>"
			End Sub
			
			'用户上传目录
			Function GetUserFolder(UserName)
			   Dim Ce:Set Ce=new CtoeCls
			   UserName=Ce.CTOE(KS.R(UserName))
			   Set Ce=Nothing

			   GetUserFolder=KS.Setting(3)&KS.Setting(91)&"User/" & username & "/"

			End Function
			'返回专栏选择框
		  Function UserClassOption(TypeID,Sel)
		    Dim RS:Set RS=Server.CreateObject("ADODB.RECORDSET")
			RS.Open "Select ClassID,ClassName From KS_UserClass Where UserName='" & UserName & "' And TypeID="&TypeID,Conn,1,1
			Do While Not RS.Eof
			  If Sel=RS(0) Then
			  UserClassOption=UserClassOption & "<option value=""" & RS(0) & """ selected>" & RS(1) & "</option>"
			  Else
			  UserClassOption=UserClassOption & "<option value=""" & RS(0) & """>" & RS(1) & "</option>"
			  End iF
			  RS.MoveNext
			Loop
			RS.Close:Set RS=Nothing
		  End Function
			
			'返回相应模型的自定义字段名称数组(仅限会员中心调用)
		   Function KS_D_F_Arr(ChannelID)
		      Dim KS_RS_Obj:Set KS_RS_Obj=Server.CreateObject("ADODB.RECORDSET")
			  KS_RS_Obj.Open "Select FieldName,Title,Tips,FieldType,DefaultValue,Options,MustFillTF,Width,FieldID From KS_Field Where ChannelID=" & ChannelID &" And ShowOnForm=1 And ShowOnUserForm=1 Order By OrderID Asc",Conn,1,1
			 If Not KS_RS_Obj.Eof Then
			  KS_D_F_Arr=KS_RS_Obj.GetRows(-1)
			 Else
			  KS_D_F_Arr=""
			 End If
			 KS_RS_Obj.Close:Set KS_RS_Obj=Nothing
		   End Function

		   '取得会员中心信息添加时的自定义字段
		   Function KS_D_F(ChannelID,ByVal UserDefineFieldValueStr)
		      Dim I,K,F_Arr,O_Arr,F_Value
			    F_Arr=KS_D_F_Arr(ChannelID)
                If UserDefineFieldValueStr<>"0" And UserDefineFieldValueStr<>""  Then UserDefineFieldValueStr=Split(UserDefineFieldValueStr,"||||")
              If IsArray(F_Arr) Then
				For I=0 To Ubound(F_Arr,2)
				    KS_D_F=KS_D_F & "<tr  class=""tdbg"" height=""25""><td align=""center"">" & F_Arr(1,I) & "：</td>"
					KS_D_F=KS_D_F & " <td>"
					If IsArray(UserDefineFieldValueStr) Then
					   F_Value=UserDefineFieldValueStr(I)
					 Else
					   F_Value=F_Arr(4,I)
					 End If

				   Select Case F_Arr(3,I)
				     Case 2
				       KS_D_F=KS_D_F & "　 <textarea style=""width:" & F_Arr(7,i) & """ rows=""5"" class=""textbox"" name=""" & F_Arr(0,i) & """>" & F_Value & "</textarea>"
					 Case 3
					  KS_D_F=KS_D_F & "　 <select class=""textbox"" style=""width:" & F_Arr(7,i) & """ name=""" & F_Arr(0,I) & """>"
					   O_Arr=Split(F_Arr(5,I),vbcrlf)
					   For K=0 To Ubound(O_Arr)
					     If F_Value=O_Arr(K) Then
						  KS_D_F=KS_D_F & "<option value=""" & O_Arr(K)& """ selected>" & O_Arr(K) & "</option>"
						 Else
					      KS_D_F=KS_D_F & "<option value=""" & O_Arr(K)& """>" & O_Arr(K) & "</option>"
						 End If
					   Next
					  KS_D_F=KS_D_F & "</select>"
					 Case 6
					   O_Arr=Split(F_Arr(5,I),vbcrlf)
					   For K=0 To Ubound(O_Arr)
					     If F_Value=O_Arr(K) Then
						  KS_D_F=KS_D_F & "<input type=""radio"" name=""" & F_Arr(0,I) & """ value=""" & O_Arr(K)& """ checked>" & O_Arr(K)
						 Else
						  KS_D_F=KS_D_F & "<input type=""radio"" name=""" & F_Arr(0,I) & """ value=""" & O_Arr(K)& """>" & O_Arr(K)
						 End If
					   Next
					 Case 7
					   O_Arr=Split(F_Arr(5,I),vbcrlf)
					   For K=0 To Ubound(O_Arr)
					     If KS.FoundInArr(F_Value,O_Arr(K),",")=true Then
						  KS_D_F=KS_D_F & "<input type=""checkbox"" name=""" & F_Arr(0,I) & """ value=""" & O_Arr(K)& """ checked>" & O_Arr(K) & ""
						 Else
						  KS_D_F=KS_D_F & "<input type=""checkbox"" name=""" & F_Arr(0,I) & """ value=""" & O_Arr(K)& """>" & O_Arr(K) 
						 End If
					   Next
					 Case Else
					   KS_D_F=KS_D_F & "　 <input type=""text"" class=""textbox"" style=""width:" & F_Arr(7,i) & """ name=""" & F_Arr(0,i) & """ value=""" & F_Value & """>"
				   End Select
				   If F_Arr(6,I)=1 Then KS_D_F=KS_D_F & "<font color=red> * </font>"
				   KS_D_F=KS_D_F & " <span style=""color:blue;margin-top:5px"">" &  F_Arr(2,I) & "</span>"
				   if F_Arr(3,I)=9 Then KS_D_F=KS_D_F & "<div><iframe id='UpPhotoFrame' name='UpPhotoFrame' src='User_UpFile.asp?Type=Field&FieldID=" & F_Arr(8,I) & "&ChannelID=" & ChannelID &"' frameborder=0 scrolling=no width='100%' height='26'></iframe></div>"
				   KS_D_F=KS_D_F & "   </td>"
				   KS_D_F=KS_D_F & "</tr>"
				Next
			End If
		   End Function
           '头部
		   Sub Head()
		   %>
		   <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
			<html>
			<head>
			<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
			<title>用户管理中心</title>
			<link href="images/css.css" type="text/css" rel="stylesheet" />
			</head>
			<body leftmargin="0" bottommargin="0" rightmargin="0" topmargin="0">
			<table border="0" align="center" width="98%" cellspacing="1" cellpadding="0" class="border">
				<tr class="title">		
					<td height="23">&nbsp;<img src="images/m_list_34.gif" align="absmiddle">&nbsp;<font style="font-size:12px;">当前操作：供求系统 >> 发布供求信息</font></td>
				</tr>
			</table>
		   <%
		   End Sub
End Class
%> 
<%
'==================================================
'邮箱: [e-mail]		
'网站: www.zxzyw.cn
'==================================================
%>