admin_mov_function.asp

重庆宽频P2P电影小偷程序,可以做一个大型的电影站了

<%
'==================================================
'过程名：ShowClassItem
'作  用：显示栏目名称
'参  数：ClassID ------栏目ID
'==================================================
Sub ShowClassItem(ClassID)   
   Dim SqlC,RsC   
   Sqlc ="Select top 1 ClassName from ArticleClass Where ClassID=" & ClassID   
   Set RsC=server.CreateObject("adodb.recordset")   
   RsC.Open SqlC,Conn,1,1   
   If RsC.Eof And RsC.Bof Then   
      Response.Write "无指定栏目"   
   Else   
      Response.Write RsC("ClassName")
   End if   
   RsC.Close   
   Set RsC=Nothing   
End Sub  

'==================================================
'过程名：ShowSpecialItem
'作  用：显示专题名称
'参  数：SpecialID ------专题ID
'==================================================
Sub ShowSpecialItem(SpecialID)   
   Dim Sqlc,Rsc   
   Sqlc ="select top 1 SpecialName from Special Where SpecialID=" & SpecialID   
   Set Rsc=server.CreateObject("adodb.recordset")   
   Rsc.open Sqlc,Conn,1,1   
   If Rsc.Eof and Rsc.Bof then   
      Response.write "无指定专题"   
   Else   
      Response.Write Rsc("SpecialName")
   End if   
   Rsc.Close   
   Set Rsc=Nothing   
End Sub  

'==================================================
'过程名：ShowItemName
'作  用：显示项目名称
'参  数：ItemID ------项目ID
'==================================================
Sub ShowItemName(ItemID)   
   Dim Sqlc,Rsc
   if ItemID=0 then
     Response.write "公用项目"
   Else
  	 Sqlc ="select top 1 ItemName from Item Where ItemID=" & ItemID   
  	 Set Rsc=server.CreateObject("adodb.recordset")   
  	 Rsc.open Sqlc,ConnItem,1,1   
  	 If Rsc.Eof and Rsc.Bof then   
  	    Response.write "无指定项目"   
  	 Else   
  	    Response.Write Rsc("ItemName")
  	 End if   
  	 Rsc.Close   
  	 Set Rsc=Nothing   
   End if
End Sub  

'==================================================
'过程名：ShowItem_Option
'作  用：显示项目选项
'参  数：ItemID ------项目ID
'==================================================
Sub ShowItem_Option(ItemID)   
   Dim SqlI,RsI  
   SqlI ="select ItemID,ItemName from Item order by ItemID desc"   
   Set RsI=server.CreateObject("adodb.recordset")   
   RsI.Open SqlI,ConnItem,1,1
   Response.write "<select Name=""ItemID"" ID=""ItemID"">"   
   If RsI.Eof and RsI.Bof Then
      Response.write "<option value="""">请添加项目</option>"   
   Else   
      Response.write "<option value="""">请选择项目</option>"
      Do while not RsI.Eof   
         Response.Write "<option value=" & """" & RsI("ItemID") & """" & "" 
         If ItemID=RsI("ItemID") Then
            Response.Write " Selected"
         End If
         Response.Write ">" & RsI("ItemName")
         Response.Write "</option>"  
      RsI.Movenext   
      Loop   
   End if
   Response.write "<option value=""0"""
   if ItemID=0 then
       Response.Write " Selected"
   End if
   Response.write ">公用项目</option></select>"
   RsI.Close   
   Set RsI=Nothing   
End sub   

'==================================================
'函数名：GetHttpPage
'作  用：获取网页源码
'参  数：HttpUrl ------网页地址
'==================================================
Function GetHttpPage(HttpUrl)
   If IsNull(HttpUrl)=True Or Len(HttpUrl)<18 Or HttpUrl="$False$" Then
      GetHttpPage="$False$"
      Exit Function
   End If
   Dim Http
   Set Http=server.createobject("MSXML2.XMLHTTP")
   Http.open "GET",HttpUrl,False
   Http.Send()
   If Http.Readystate<>4 then
      Set Http=Nothing 
      GetHttpPage="$False$"
      Exit function
   End if
   GetHTTPPage=bytesToBSTR(Http.responseBody,"GB2312")
   Set Http=Nothing
   If Err.number<>0 then
      Err.Clear
   End If
End Function

'==================================================
'函数名：BytesToBstr
'作  用：将获取的源码转换为中文
'参  数：Body ------要转换的变量
'参  数：Cset ------要转换的类型
'==================================================
Function BytesToBstr(Body,Cset)
   Dim Objstream
   Set Objstream = Server.CreateObject("adodb.stream")
   objstream.Type = 1
   objstream.Mode =3
   objstream.Open
   objstream.Write body
   objstream.Position = 0
   objstream.Type = 2
   objstream.Charset = Cset
   BytesToBstr = objstream.ReadText 
   objstream.Close
   set objstream = nothing
End Function

'==================================================
'函数名：PostHttpPage
'作  用：登录
'==================================================
Function PostHttpPage(RefererUrl,PostUrl,PostData) 
    Dim xmlHttp 
    Dim RetStr      
    Set xmlHttp = CreateObject("Msxml2.XMLHTTP")  
    xmlHttp.Open "POST", PostUrl, False
    XmlHTTP.setRequestHeader "Content-Length",Len(PostData) 
    xmlHttp.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
    xmlHttp.setRequestHeader "Referer", RefererUrl
    xmlHttp.Send PostData 
    If Err.Number <> 0 Then 
        Set xmlHttp=Nothing
        PostHttpPage = "$False$"
        Exit Function
    End If
    PostHttpPage=bytesToBSTR(xmlHttp.responseBody,"GB2312")
    Set xmlHttp = nothing
End Function 

'==================================================
'函数名：UrlEncoding
'作  用：转换编码
'==================================================
Function UrlEncoding(DataStr)
    Dim StrReturn,Si,ThisChr,InnerCode,Hight8,Low8
    StrReturn = ""
    For Si = 1 To Len(DataStr)
        ThisChr = Mid(DataStr,Si,1)
        If Abs(Asc(ThisChr)) < &HFF Then
            StrReturn = StrReturn & ThisChr
        Else
            InnerCode = Asc(ThisChr)
            If InnerCode < 0 Then
               InnerCode = InnerCode + &H10000
            End If
            Hight8 = (InnerCode  And &HFF00)\ &HFF
            Low8 = InnerCode And &HFF
            StrReturn = StrReturn & "%" & Hex(Hight8) &  "%" & Hex(Low8)
        End If
    Next
    UrlEncoding = StrReturn
End Function

'==================================================
'函数名：GetBody
'作  用：截取字符串
'参  数：ConStr ------将要截取的字符串
'参  数：StartStr ------开始字符串
'参  数：OverStr ------结束字符串
'参  数：IncluL ------是否包含StartStr
'参  数：IncluR ------是否包含OverStr
'==================================================
Function GetBody(ConStr,StartStr,OverStr,IncluL,IncluR)
   If ConStr="$False$" or ConStr="" or IsNull(ConStr)=True Or StartStr="" or IsNull(StartStr)=True Or OverStr="" or IsNull(OverStr)=True Then
      GetBody="$False$"
      Exit Function
   End If

   Dim Start,Over
   Start = InStrB(1, ConStr, StartStr, vbBinaryCompare)
   If Start<=0 then
      GetBody="$False$"
      Exit Function
   Else
      If IncluL=False Then
         Start=Start+LenB(StartStr)
      End If
   End If
   Over=InStrB(Start,ConStr,OverStr,vbBinaryCompare)
   If Over<=0 Or Over<=Start then
      GetBody="$False$"
      Exit Function
   Else
      If IncluR=True Then
         Over=Over+LenB(OverStr)
      End If
   End If
   GetBody=MidB(ConStr,Start,Over-Start)
End Function


'==================================================
'函数名：GetArray
'作  用：提取链接地址，以$Array$分隔
'参  数：ConStr ------提取地址的原字符
'参  数：StartStr ------开始字符串
'参  数：OverStr ------结束字符串
'参  数：IncluL ------是否包含StartStr
'参  数：IncluR ------是否包含OverStr
'==================================================
Function GetArray(Byval ConStr,StartStr,OverStr,IncluL,IncluR)
   If ConStr="$False$" or ConStr="" Or IsNull(ConStr)=True or StartStr="" Or OverStr="" or  IsNull(StartStr)=True Or IsNull(OverStr)=True Then
      GetArray="$False$"
      Exit Function
   End If
   Dim TempStr,TempStr2,objRegExp,Matches,Match
   ConStr=Replace(ConStr,"[","Kk51K2k1K5k2Dd21DdD32d1Hh2Hh32Hh23AED3DGSDGE")
   ConStr=Replace(ConStr,"]","TTTasdgsdg4555DGhDgTTddddgode02")
   StartStr=Replace(StartStr,"[","Kk51K2k1K5k2Dd21DdD32d1Hh2Hh32Hh23AED3DGSDGE")
   StartStr=Replace(StartStr,"]","TTTasdgsdg4555DGhDgTTddddgode02")
   OverStr=Replace(OverStr,"[","Kk51K2k1K5k2Dd21DdD32d1Hh2Hh32Hh23AED3DGSDGE")
   OverStr=Replace(OverStr,"]","TTTasdgsdg4555DGhDgTTddddgode02")
   Set objRegExp = New Regexp 
   objRegExp.IgnoreCase = True 
   objRegExp.Global = True
   objRegExp.Pattern = "("&StartStr&").+?("&OverStr&")"
   Set Matches =objRegExp.Execute(ConStr) 
   For Each Match in Matches
      If TempStr<>"" then 
         TempStr=TempStr & "$Array$" & Match.Value
      Else
         TempStr=Match.Value
      End if
   Next 
   Set Matches=nothing
   Set objRegExp=nothing
   If IncluL=False then
      TempStr=Replace(TempStr,StartStr,"")
   End if
   If IncluR=False then
      TempStr=Replace(TempStr,OverStr,"")
   End if
   TempStr=Replace(TempStr,"""","")
   TempStr=Replace(TempStr,"'","")
   If TempStr="" then
      GetArray="$False$"
   Else
      GetArray=TempStr
   End if
End Function


'==================================================
'函数名：DefiniteUrl
'作  用：将相对地址转换为绝对地址
'参  数：PrimitiveUrl ------要转换的相对地址
'参  数：ConsultUrl ------当前网页地址
'==================================================
Function DefiniteUrl(Byval PrimitiveUrl,Byval ConsultUrl)
   Dim ConTemp,PriTemp,Pi,Ci,PriArray,ConArray
   If PrimitiveUrl="" or ConsultUrl="" or PrimitiveUrl="$False$" Then
      DefiniteUrl="$False$"
      Exit Function
   End If
   If Left(ConsultUrl,7)<>"HTTP://" And Left(ConsultUrl,7)<>"http://" Then
      ConsultUrl= "http://" & ConsultUrl
   End If
   ConsultUrl=Replace(ConsultUrl,"://",":\\")
   If Right(ConsultUrl,1)<>"/" Then
      If Instr(ConsultUrl,"/")>0 Then
         If Instr(Right(ConsultUrl,Len(ConsultUrl)-InstrRev(ConsultUrl,"/")),".")>0 then   
         Else
            ConsultUrl=ConsultUrl & "/"
         End If
      Else
         ConsultUrl=ConsultUrl & "/"
      End If
   End If
   ConArray=Split(ConsultUrl,"/")
   If Left(PrimitiveUrl,7) = "http://" then
      DefiniteUrl=Replace(PrimitiveUrl,"://",":\\")
   ElseIf Left(PrimitiveUrl,1) = "/" Then
      DefiniteUrl=ConArray(0) & PrimitiveUrl
   ElseIf Left(PrimitiveUrl,2)="./" Then
      DefiniteUrl=ConArray(0) & Right(PrimitiveUrl,Len(PrimitiveUrl)-1)
   ElseIf Left(PrimitiveUrl,3)="../" then
      Do While Left(PrimitiveUrl,3)="../"
         PrimitiveUrl=Right(PrimitiveUrl,Len(PrimitiveUrl)-3)
         Pi=Pi+1
      Loop            
      For Ci=0 to (Ubound(ConArray)-1-Pi)
         If DefiniteUrl<>"" Then
            DefiniteUrl=DefiniteUrl & "/" & ConArray(Ci)
         Else
            DefiniteUrl=ConArray(Ci)
         End If
      Next
      DefiniteUrl=DefiniteUrl & "/" & PrimitiveUrl
   Else
      If Instr(PrimitiveUrl,"/")>0 Then
         PriArray=Split(PrimitiveUrl,"/")
         If Instr(PriArray(0),".")>0 Then
            If Right(PrimitiveUrl,1)="/" Then
               DefiniteUrl="http:\\" & PrimitiveUrl
            Else
               If Instr(PriArray(Ubound(PriArray)-1),".")>0 Then 
                  DefiniteUrl="http:\\" & PrimitiveUrl
               Else
                  DefiniteUrl="http:\\" & PrimitiveUrl & "/"
               End If
            End If      
         Else
            If Right(ConsultUrl,1)="/" Then   
               DefiniteUrl=ConsultUrl & PrimitiveUrl
            Else
               DefiniteUrl=Left(ConsultUrl,InstrRev(ConsultUrl,"/")) & PrimitiveUrl
            End If
         End If
      Else
         If Instr(PrimitiveUrl,".")>0 Then
            If Right(ConsultUrl,1)="/" Then
               If right(PrimitiveUrl,3)=".cn" or right(PrimitiveUrl,3)="com" or right(PrimitiveUrl,3)="net" or right(PrimitiveUrl,3)="org" Then
                  DefiniteUrl="http:\\" & PrimitiveUrl & "/"
               Else
                  DefiniteUrl=ConsultUrl & PrimitiveUrl
               End If
            Else
               If right(PrimitiveUrl,3)=".cn" or right(PrimitiveUrl,3)="com" or right(PrimitiveUrl,3)="net" or right(PrimitiveUrl,3)="org" Then
                  DefiniteUrl="http:\\" & PrimitiveUrl & "/"
               Else
                  DefiniteUrl=Left(ConsultUrl,InstrRev(ConsultUrl,"/")) & "/" & PrimitiveUrl
               End If
            End If
         Else
            If Right(ConsultUrl,1)="/" Then
               DefiniteUrl=ConsultUrl & PrimitiveUrl & "/"
            Else
               DefiniteUrl=Left(ConsultUrl,InstrRev(ConsultUrl,"/")) & "/" & PrimitiveUrl & "/"
            End If         
         End If
      End If
   End If
   If Left(DefiniteUrl,1)="/" then
     DefiniteUrl=Right(DefiniteUrl,Len(DefiniteUrl)-1)
   End if
   If DefiniteUrl<>"" Then
      DefiniteUrl=Replace(DefiniteUrl,"//","/")
      DefiniteUrl=Replace(DefiniteUrl,":\\","://")
   Else
      DefiniteUrl="$False$"
   End If
End Function

'==================================================
'函数名：ReplaceSaveRemoteFile
'作  用：替换、保存远程文件
'参  数：ConStr ------ 要替换的字符串
'参  数：StarStr ----- 前导
'参  数：OverStr ----- 
'参  数：IncluL ------ 
'参  数：IncluR ------ 
'参  数：SaveTf ------ 是否保存文件，False不保存，True保存
'参  数：SaveFilePath- 保存文件夹
'参  数: TistUrl------ 当前网页地址
'==================================================
Function ReplaceSaveRemoteFile(ConStr,StartStr,OverStr,IncluL,IncluR,SaveTf,SaveFilePath,TistUrl)
   If IsObjInstalled("Scripting.FileSystemObject")=False then'没有安装组件
      SaveTf=False
   End if
   If ConStr="$False$" or ConStr="" Then
      ReplaceSaveRemoteFile="$False$"
      Exit Function
   End If
   Dim TempStr,TempStr2,ReF,Matches,Match,Tempi,TempArray,TempArray2,OverTypeArray

   Set ReF = New Regexp 
   ReF.IgnoreCase = True 
   ReF.Global = True
   ReF.Pattern = "("&StartStr&").+?("&OverStr&")"
   Set Matches =ReF.Execute(ConStr) 
   For Each Match in Matches
      If Instr(TempStr,Match.Value)=0 Then
         If TempStr<>"" then 
            TempStr=TempStr & "$Array$" & Match.Value
         Else
            TempStr=Match.Value
         End if
      End If
   Next 
   Set Matches=nothing
   Set ReF=nothing
   If TempStr="" or IsNull(TempStr)=True Then
      ReplaceSaveRemoteFile=ConStr
      Exit function
   End if
   If IncluL=False then
      TempStr=Replace(TempStr,StartStr,"")
   End if
   If IncluR=False then
      If Instr(OverStr,"|")>0 Then
         OverTypeArray=Split(OverStr,"|")
         For Tempi=0 To Ubound(OverTypeArray) 
            TempStr=Replace(TempStr,OverTypeArray(Tempi),"")
         Next
      Else
         TempStr=Replace(TempStr,OverStr,"")
      End If  
   End if
   TempStr=Replace(TempStr,"""","")
   TempStr=Replace(TempStr,"'","")

   Dim RemoteFile,RemoteFileurl,SaveFileName,SaveFileType,ArrSaveFileName,RanNum
   SaveFilePath="UploadFiles/" & year(now) & "-" & month(now)
   If Right(SaveFilePath,1)="/" then
      SaveFilePath=Left(SaveFilePath,Len(SaveFilePath)-1)
   End If
   If SaveTf=True then
      If CheckDir2(SaveFilePath)=False Then
         If MakeNewsDir2(SaveFilePath)=False Then
            SaveTf=False
         End If
      End If
   End If
 
   SaveFilePath=SaveFilePath & "/"

   '图片转换/保存
   TempArray=Split(TempStr,"$Array$")
   For Tempi=0 To Ubound(TempArray)
      RemoteFileurl=DefiniteUrl(TempArray(Tempi),TistUrl)
      If RemoteFileurl<>"$False$" And SaveTf=True Then'保存图片
	    ArrSaveFileName = Split(RemoteFileurl,".")
	    SaveFileType=ArrSaveFileName(Ubound(ArrSaveFileName))'文件类型
	    RanNum=Int(900*Rnd)+100
	    SaveFileName = SaveFilePath&year(now)&month(now)&day(now)&hour(now)&minute(now)&second(now)&ranNum&"."&SaveFileType	               
	    Call SaveRemoteFile(SaveFileName,RemoteFileurl)
            ConStr=Replace(ConStr,TempArray(Tempi),SaveFileName)
      ElseIf RemoteFileurl<>"$False$" and SaveTf=False Then'不保存图片
            SaveFileName=RemoteFileUrl