configure.in

一个小巧的嵌入式图形系统wGUI, 可以用VC编译

dnl Process this file with autoconf to produce a configure script.
AC_INIT(includes/wgui.h)
AM_CONFIG_HEADER(includes/wgui_config.h:includes/wgui_config.h.in)

WGUI_VERSION_MAJOR=0
WGUI_VERSION_MINOR=3
WGUI_VERSION_REVISION=0
WGUI_VERSION=$WGUI_VERSION_MAJOR.$WGUI_VERSION_MINOR.$WGUI_VERSION_REVISION
VERSION=$WGUI_VERSION
PACKAGE=wGui

AC_SUBST(WGUI_VERSION_MAJOR)
AC_SUBST(WGUI_VERSION_MINOR)
AC_SUBST(WGUI_VERSION_REVISION)
AC_SUBST(WGUI_VERSION)
AC_SUBST(VERSION)
AC_SUBST(PACKAGE)

AM_INIT_AUTOMAKE($PACKAGE, $WGUI_VERSION)


dnl Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AC_PROG_RANLIB
AC_PROG_MAKE_SET
AC_PROG_INSTALL
AC_PROG_LN_S


dnl Add verbose warnings by default, and allow ANSI compliance checking
AC_ARG_ENABLE(strict-ansi,
[  --enable-strict-ansi    Enable strict ANSI compliance build
[default=no]],
              , enable_strict_ansi=no)
if test x$ac_cv_prog_gcc = xyes; then
    CFLAGS="$CFLAGS -Wall"
    if test x$enable_strict_ansi = xyes; then
        CFLAGS="$CFLAGS -ansi -pedantic"
    fi
fi


dnl Checks for libraries.
SDL_VERSION=1.2.0
AM_PATH_SDL($SDL_VERSION,
            :,
            AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!])
)


ft2test=yes
AC_ARG_ENABLE(ft2test,
	[  --disable-ft2test       disable the freetype check],
	ft2test=no
)

if test "$ft2test" = "yes"; then

    dnl Check for freetype2 with a reasonable fallback in case
    dnl freetype-config is missing.

    have_freetype=no
    AC_PATH_PROG(freetype_config,freetype-config,no)
    if test "$ac_cv_path_freetype_config" != "no"; then
    	have_freetype=yes
	FREETYPE_CFLAGS="`$ac_cv_path_freetype_config --cflags`"
	FREETYPE_LIBS="`$ac_cv_path_freetype_config --libs`"
    else
	AC_CHECK_LIB(freetype,FT_Init_FreeType,have_freetype=yes)
	AC_CHECK_HEADER(ft2build.h,have_ft2build=yes)
	if test "$have_ft2build" != "yes"; then
	    have_freetype="no"
	elif test "$have_freetype" = "yes"; then
	    FREETYPE_LIBS="-lfreetype"
	    ft2inc="no"
	    AC_MSG_CHECKING(freetype2 include directory)
	    if test -d /usr/local/include/freetype2; then
		ft2inc="/usr/local/include/freetype2"
	    elif test -d /usr/include/freetype2; then
		ft2inc="/usr/include/freetype2"
	    fi
	    AC_MSG_RESULT($ft2inc)
	    FREETYPE_CFLAGS="-I$ft2inc"
	fi
    fi

    if test x$have_freetype = xno; then
	AC_MSG_ERROR([*** Unable to find the FreeType 2 library
(http://www.freetype.org/)])
    fi

fi


dnl The composite lib and cflags
WGUI_CFLAGS="$CFLAGS $FREETYPE_CFLAGS $SDL_CFLAGS"
WGUI_LIBS="$LIBS $FREETYPE_LIBS $SDL_LIBS -L../src -lwguid"
WGUI_INCLUDES="$FREETYPE_INCLUDES $SDL_INCLUDES"
AC_SUBST(WGUI_CFLAGS)
AC_SUBST(WGUI_LIBS)
AC_SUBST(WGUI_INCLUDES)


dnl Checks for header files.


dnl Checks for typedefs, structures, and compiler characteristics.


dnl Checks for library functions.


dnl Now generate the Makefiles
AC_OUTPUT([
Makefile
includes/Makefile
src/Makefile
tests/Makefile
docs/Makefile
fonts/Makefile
])