vcr.bas

该文件包含一些关于软件的知识,里面有一些比较经典的东西,值得大家去卡看.

Attribute VB_Name = "VCRModule"
'**********************************************
' 目的： 用于 VCR 示例应用程序的通用模块。
' 包含了一些共享的模块。
'**********************************************
Option Explicit

' 初始化 recorder 类
Public Recorder As New clsRecorder

'**********************************************
' 目的：  基于当前的模式，使 VCR 窗体
'         上的按钮有效或无效。
' 输入：  Button: 调用过程的命令按钮。
'**********************************************
Sub ButtonManager(Button As Control)
    Dim vntControl As Variant   ' 控件的值
    
    ' 确定按下了哪个功能按钮
    ' 并更新所有的按钮和 Recorder 类
    Select Case Button
        Case frmVCR.cmdPlay, frmVCR.cmdForward, frmVCR.cmdRewind
            frmVCR.cmdPause.Enabled = True
            frmVCR.cmdStop.Enabled = True
            frmVCR.cmdRec.Enabled = False
            frmVCR.cmdDown.Enabled = False
            frmVCR.cmdUp.Enabled = False
            Recorder.Enabled = False
        Case frmVCR.cmdRec
            frmVCR.cmdPause.Enabled = True
            frmVCR.cmdStop.Enabled = True
            frmVCR.cmdPlay.Enabled = False
            frmVCR.cmdForward.Enabled = False
            frmVCR.cmdRewind.Enabled = False
            frmVCR.cmdDown.Enabled = False
            frmVCR.cmdUp.Enabled = False
            Recorder.Enabled = False
        Case frmVCR.cmdPause
            frmVCR.cmdPause.Enabled = False
        Case frmVCR.cmdStop
            frmVCR.cmdStop.Enabled = False
            frmVCR.cmdPause.Enabled = False
            frmVCR.cmdRec.Enabled = True
            frmVCR.cmdPlay.Enabled = True
            frmVCR.cmdForward.Enabled = True
            frmVCR.cmdRewind.Enabled = True
            frmVCR.cmdDown.Enabled = True
            frmVCR.cmdUp.Enabled = True
            Recorder.Enabled = True
    End Select
    ' 把按钮赋值给与其相关的 shape 控件
    vntControl = Button.Name
    vntControl = Right$(vntControl, Len(vntControl) - 3)
    vntControl = "shp" & vntControl
    ' 调用更新指示灯的过程
    HighlightButton vntControl
End Sub
'**********************************************
' 目的：  基于当前的模式，使 VCR 上
'         的 shape 控件有效或无效。
' 输入：  MyControl: 传递给过程的 Shape 控件。
'**********************************************
Sub HighlightButton(MyControl As Variant)
    Dim i As Integer    ' 计数器变量
    
    ' 遍历 Controls 集合
    For i = 0 To frmVCR.Controls.Count - 1
        ' 测试 Shape 控件
        If TypeOf frmVCR.Controls(i) Is Shape Then
            ' 如果是传入的控件，使其可见；
            ' 否则，使其不可见。
            If frmVCR.Controls(i).Name = MyControl Then
                frmVCR.Controls(i).Visible = True
            Else
                frmVCR.Controls(i).Visible = False
            End If
        End If
    Next
End Sub
'**********************************************
' 目的：  存储最后使用的频道号，
'         录像之后就可以恢复它。
' 输入：  Channel: 传递给过程的频道号。
' 返回：  存储在静态变量中的频道。
'**********************************************
Function SaveChannel(Channel As Variant) As Integer
    Static intChannel As Integer '存储频道
    
    ' 将值赋给静态变量
    If Channel <> 0 Then
        intChannel = Channel
    End If
    
    ' 返回频道号
    SaveChannel = intChannel
End Function