configure.in

PGP.Corporation.PGP.SDK.v3.7.2.rar 此前从本站下载的那个缺少几个lib文件

dnl ________________________________________________________________________
dnl     Copyright (C) 2005 PGP Corporation
dnl     All rights reserved.
dnl 
dnl     $Id: configure.in 37731 2005-08-11 20:10:34Z vinnie $
dnl ________________________________________________________________________

AC_INIT()
AC_CONFIG_AUX_DIR(.)
AC_CANONICAL_HOST
SHELL=/bin/sh

case "$host" in                                     
*-*-solaris*)                                                 
    PGPARCH=PGP_UNIX_SOLARIS
    OS=solaris
    SOEXT=so
    LARGEFILEDEFS="-DHAVE_64BIT_FILES=1"
    DEFINES=
    LDFLAGS=
    SOCKETLIB="-lsocket -lnsl"
    RTLIB=-lrt
    ICONVLIB=-liconv
    MATHLIB=-lm
    DYNAMICOPT=
    STATICOPT=
    STATICSTART=-Wl,-Bstatic
    STATICEND=-Wl,-Bdynamic
    ;;                                              
*-*-linux*)                                          
    PGPARCH=PGP_UNIX_LINUX
    OS=linux
    SOEXT=so
    LARGEFILEDEFS="-DHAVE_64BIT_FILES=1 -D_LARGEFILE_SOURCE=1 -D_LARGEFILE64_SOURCE=1"
    DEFINES="-D_GNU_SOURCE=1 -D_USE_UNIX98=1"
    LDFLAGS=
    MATHLIB=-lm
    DYNAMICOPT=
    STATICOPT=-static
    STATICSTART=
    STATICEND=
    ;;                                              
*-*-aix*)                                           
    PGPARCH=PGP_UNIX_AIX
    OS=aix
    SOEXT=so
    LARGEFILEDEFS="-DHAVE_64BIT_FILES=1 -D_LARGE_FILE_API=1 -D_LARGE_FILES=1"
    DEFINES="-D_UNIX98=1 -D_XOPEN_SOURCE=500"
    LDFLAGS=-Wl,-brtl
    MATHLIB=-lm
    DYNAMICOPT=-Wl,-brtl
    STATICOPT=
    STATICSTART=-Wl,-bstatic
    STATICEND=-Wl,-bdynamic
    ;;
*-*-hpux*)
    PGPARCH=PGP_UNIX_HPUX
    OS=hpux
    SOEXT=sl
    LARGEFILEDEFS="-D_LARGEFILE64_SOURCE=1 -D_FILE_OFFSET_BITS=64"
    DEFINES="-D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE_EXTENDED=1"
    LDFLAGS=
    GCCLIB="-lgcc -lc"
    MATHLIB=-lm
    DYNAMICOPT=
    STATICOPT=-static
    STATICSTART=
    STATICEND=
    ;;
*-*-darwin*)
    PGPARCH=PGP_UNIX_DARWIN
    OS=osx
    SOEXT=so
    LARGEFILEDEFS=
    DEFINES="-DHAVE_PRAGMA_MARK=1"
    LDFLAGS=
    ;;
*)
    PGPARCH=PGP_UNIX_UNKNOWN
    OS=""
    ;;                                              
esac                                                

AC_SUBST(PGPARCH)                                   
AC_SUBST(OS)                                   
AC_SUBST(SOEXT)
AC_SUBST(LARGEFILEDEFS)
AC_SUBST(DEFINES)
AC_SUBST(LDFLAGS)

AC_SUBST(SOCKETLIB)
AC_SUBST(RTLIB)
AC_SUBST(MATHLIB)
AC_SUBST(GCCLIB)
AC_SUBST(ICONVLIB)

AC_SUBST(DYNAMICOPT)
AC_SUBST(STATICOPT)
AC_SUBST(STATICSTART)
AC_SUBST(STATICEND)

AC_PREFIX_DEFAULT(/usr)
sysconfdir=/etc

ARCH=$host_cpu
AC_SUBST(ARCH)

case "$ARCH" in
x86_64)
    LIBDIR=lib64
    ;;
*)
    LIBDIR=lib
    ;;
esac
AC_SUBST(LIBDIR)

dnl autoconf doesn't seem to handle having the configure script in a
dnl directory other than the root source dir, so we have to kludge this
dnl a bit.  We'll use @BUILDDIR@ instead of @top_srcdir@.
dnl Unfortunately, this means that configure will have to be re-run if we
dnl ever rename any directories in the path to the source.

BUILDDIR=`pwd`
AC_SUBST(BUILDDIR)

TOPDIR=`(cd ../../../../..; pwd)`
AC_SUBST(TOPDIR)

AC_PROG_CC
AC_PROG_CXX

# Check cc version
AC_MSG_CHECKING(compiler version)
CC_VERSION=`$CC -dumpversion`
case "$CC_VERSION" in
2.*.*)
    GCC2=yes
    ;;
3.*.*)
    GCC3=yes
    ;;
esac
AC_MSG_RESULT($CC_VERSION)

AC_CHECK_PROG(TEST,test,/bin/test,test,/bin/)

#
# Compiler options
#
AC_MSG_CHECKING(for compiler options)
if test "$GCC3" = "yes" ; then
  COPTS="$COPTS -fno-strict-aliasing"
fi
AC_MSG_RESULT(${COPTS-none})
AC_SUBST(COPTS)

DEBUGOPT="-O0 -g"
AC_SUBST(DEBUGOPT)

NONDEBUGOPT="-O3"
AC_SUBST(NONDEBUGOPT)

AC_MSG_CHECKING(for useful warning options (\$WARN))
if test "$WARN+set" != set; then
  WARN="-Wall -W -Wpointer-arith"
fi
AC_MSG_RESULT(${WARN-none})
AC_SUBST(WARN)

#
# Check for libraries
#
AC_CHECK_LIB(pthreads, pthread_mutex_init, THREADLIB="-lpthreads",
  AC_CHECK_LIB(pthread, pthread_mutex_init, THREADLIB="-lpthread",
    AC_CHECK_LIB(thread, thread_create, THREADLIB="-lthread")))
AC_SUBST(THREADLIB)

AC_CHECK_LIB(dl, dlopen, DLLIB="-ldl")
AC_SUBST(DLLIB)

# Look for where the binary PGPsdk libs are.  They could be in
# the current source tree (as if we just checked it out of CVS)
# or in a standard system place (such as /usr/lib), or it might still
# be sitting in our RPM BUILD tree, left over from just building 
# the pgplibs package.
AC_MSG_CHECKING(for PGPsdk)
SDKPRODUCT=0
dnl Fist check in the current source tree
if test -f $TOPDIR/libs2/pgpsdk/configure.in; then
    SDKLIBDIR=`(cd $TOPDIR/libs2/pgpsdk/unix; pwd)`
dnl Then check the SDK product
elif test -f ../../libraries/debug/libPGPsdk.a; then
    SDKLIBDIR=`(cd ../../libraries; pwd)`
    SDKPRODUCT=1
dnl Then check standard system locations: /lib, /usr/lib, etc.
elif test -f /$LIBDIR/libPGPsdk.a; then
    SDKLIBDIR=/$LIBDIR
elif test -f /usr/$LIBDIR/libPGPsdk.a; then
    SDKLIBDIR=/usr/$LIBDIR
elif test -f /usr/local/$LIBDIR/libPGPsdk.a; then
    SDKLIBDIR=/usr/local/$LIBDIR
dnl Then check if it's in the RPM BUILD tree
elif test -f $RPMTOPDIR/BUILD/pgplibs*/libs2/pgpsdk/unix/libPGPsdk.a; then
    SDKLIBDIR=`echo $RPMTOPDIR/BUILD/pgplibs*/libs2/pgpsdk/unix`
dnl Then print an error since we couldn't find it anywhere
else
    AC_MSG_ERROR(unable to find PGPsdk!)
fi
AC_SUBST(SDKLIBDIR)
AC_SUBST(SDKPRODUCT)
AC_MSG_RESULT($SDKLIBDIR)


AC_OUTPUT(Makefile)