is_email.asp

来自「asp酒店房间预约系统设计＋论文 本酒店房间预约系统按照用户部分和管理员部分划」· ASP 代码 · 共 49 行

<%
'电子邮件规则判定函数------------------
function is_email(email)
	dim names, name, i, c
	is_email = true
	'将字符串变量email以“@”为界分割成数组-------------
	names = Split(email, "@")
	'判断是否有且只有一个“@”-------------
	if UBound(names) <> 1 then
		is_email = false
		exit function
	end if
	for each name in names
		'判断“@”前后是否均不为空-------------
		if Len(name) <= 0 then
			is_email = false
			exit function
		end if
		'是否含有非数字、字母或下划线的非法字符-------------
		for i = 1 to Len(name)
			c = Lcase(Mid(name, i, 1))
			if InStr("abcdefghijklmnopqrstuvwxyz_-.", c) <= 0 and not IsNumeric(c) then
				is_email = false
				exit function
			end if
		next
		'是否有“.”存在于用户名或服务器地址的最左侧或最右侧-------------
		if Left(name, 1) = "." or Right(name, 1) = "." then
			is_email = false
			exit function
		end if
	next
	'是否存在符号“.”------------
	if InStr(names(1), ".") <= 0 then
		is_email = false
		exit function
	end if
	'邮件服务器地址是否合法------------
	i = Len(names(1)) - InStrRev(names(1), ".")
	if i <> 2 and i <> 3 then
		is_email = false
		exit function
	end if
	'是否存在非法符号串“..”------------
	if InStr(email, "..") > 0 then
		is_email = false
	end if
end function
%>