wlan-lat

柯老师网站上找到的

#!/bin/tcsh
#
# works on a trace file produced by ns
# outputs layer-to-layer per-packet latency for a given flow,
# indexed by the send time for the packet

if ( $#argv != 3 ) then
  echo usage:
  echo "      " $0 \<scenario\> \<flow id\> \<layer\>
  exit 1
endif

set scenario = $1
set flow = $2
set layer = $3
set sendlayer = $layer
if ( $layer == 'MAC' ) then
  set sendlayer = IFQ
endif

set tracefile = $scenario.tr
set tmpfile = `mktemp /tmp/latency.sendtimes.XXXXXX`
set outfile = $scenario.$flow.lat
rm -f $outfile
touch $outfile

# determine the first packet for a flow based on the first pkt
# received at the agent layer
set pkt = `egrep "^r .*\-Nl AGT .*\-If $flow " $tracefile | head -1 | gawk '{print $43;}'`

# determine the sender/receiver based on the first packet exchanged
# the true receiver is the last node to receive the packet
set snode = `egrep "^s .*\-Nl $layer .*\-If $flow .*\-Ii $pkt " $tracefile | head -1 | gawk '{print $9;}'`
set rnode = `egrep "^r .*\-Nl $layer .*\-If $flow .*\-Ii $pkt " $tracefile | tail -1 | gawk '{print $9;}'`

# determine per-packet send times; use the first transmission
# time if there are retransmissions
egrep "^s .*\-Ni $snode .*\-Nl $sendlayer .*\-If $flow " $tracefile | gawk '{print $43, $3;}' | sort -k1,1g -u >> $tmpfile

# determine per-packet recv times, match them to send times
# based on the packet id, and compute latency; use the time
# of the first recv if there were retransmissions
egrep "^r .*\-Ni $rnode .*\-Nl $layer .*\-If $flow " $tracefile | gawk '{print $43, $3;}' | sort -k1,1g -u | \
gawk -v sendfile=$tmpfile -v outfile=$outfile '{		\
	pkt = $1;						\
	rtime = $2;						\
	getline < sendfile;					\
	while ($1 < pkt) { getline < sendfile };		\
	if ($1 > pkt) { print "FATAL ERROR"; exit 1 };		\
	printf "%.9f %.9f\n", $2, (rtime - $2) >> outfile;	\
}'

# run latstats tool on the outfile
gawk '{print $2;}' $outfile | latstats | gawk '{print "Latency", $0}'

# cleanup
rm $tmpfile