wlan-stats

柯老师网站上找到的

#!/bin/tcsh
#
# basically a wrapper around other wlan-* scripts
# works on a trace file produced by ns
# generates latency and bw stats for each identifiable flow
# outputs channel utilization stats also

if ( $#argv < 1 || $#argv > 2 ) then
  echo usage:
  echo "      " $0 \<scenario name\> "[<"interval size for instantaneous bw">" = 0.25"]"
  exit 1
endif

set scenario = $1
set tracefile = $scenario.tr
set interval = 0.25
if ( $#argv == 2 ) then
  set interval = $2
endif

set outfile = $scenario.stats
rm -f $outfile

echo Identifying various flows for scenario $scenario
echo ------------------------------
foreach flow ( `egrep "^s .*\-Nl AGT .*\-If " $tracefile | gawk '{ print $41; }' | sort -gu` )
  echo Flow $flow | tee -a $outfile
  echo No. of IFQ drops = `egrep "^d .*\-Nl IFQ \-Nw IFQ .*\-If $flow " $tracefile | wc -l` | tee -a $outfile
  echo No. of MAC drops = `egrep "^d .*\-Nl MAC \-Nw RET .*\-If $flow " $tracefile | wc -l` | tee -a $outfile
  wlan-bw $scenario $flow $interval | tee -a $outfile
  wlan-lat $scenario $flow AGT | tee -a $outfile
  wlan-latdist $scenario $flow
  echo ------------------------------ | tee -a $outfile
end

echo Channel Utilization Stats: | tee -a $outfile
wlan-chutil $scenario | tee -a $outfile
echo ------------------------------ | tee -a $outfile

echo Goodput Stats: | tee -a $outfile
wlan-goodput $scenario $interval | tee -a $outfile