combobox.asm

windows汇编语言程序设计 吴中平著 一书所附所有源代码。 该书重点讲解了Windows环境下汇编语言程序设计的基本原理及其实现过程

include .\head.inc
WinMain proto :DWORD,:DWORD,:DWORD,:DWORD
LISTITEM STRUCT 
      db 8 dup (0)
LISTITEM ENDS
.data
ClassName                       db "ComboBoxClass",0
TitleName                        db "组合框控件子窗口",0
ButtonClassName              db "BUTTON",0
ComboBoxClassName       db "COMBOBOX",0
PushButtonText                db "确定",0
ComboBox1                      LISTITEM   <"北京市">,<"天津">,<"南京市">,<"沈阳市">,<"广州市">,<"西安市">,<"成都">,<"上海市">,<"武汉">
COMBOBOXNUM=($-ComboBox1)/sizeof LISTITEM

.data?
hInstance                 HINSTANCE ?
hwndButtonPush       HWND ?
hwndComboBox1      HWND ?
Buffer                       db 20 dup(?)
.const
ID_BUTTON_PUSH     equ 1
ID_COMBOBOX1        equ 2
.code
start:
   invoke GetModuleHandle, NULL
   mov    hInstance,eax
   invoke WinMain, NULL,NULL,NULL, SW_SHOWDEFAULT
   invoke ExitProcess,eax

WinMain proc hInst:HINSTANCE,hPrevInst:HINSTANCE,CmdLine:LPSTR,CmdShow:DWORD
  LOCAL wc:WNDCLASSEX
   LOCAL msg:MSG
   LOCAL hwnd:HWND
   mov   wc.cbSize,SIZEOF WNDCLASSEX
   mov   wc.style, CS_HREDRAW or CS_VREDRAW or CS_DBLCLKS
   mov   wc.lpfnWndProc, OFFSET WndProc
   mov   wc.cbClsExtra,NULL
   mov   wc.cbWndExtra,NULL
   mov   eax, hInstance
   mov   wc.hInstance,eax
   invoke GetStockObject,WHITE_BRUSH 
   mov   wc.hbrBackground,eax
   mov   wc.lpszMenuName,NULL
   mov   wc.lpszClassName,OFFSET ClassName
   invoke LoadIcon,NULL,IDI_ASTERISK
   mov   wc.hIcon,eax
   mov   wc.hIconSm,0
   invoke LoadCursor,NULL,IDC_HAND
   mov   wc.hCursor,eax
   invoke RegisterClassEx, addr wc
   invoke CreateWindowEx,WS_EX_CLIENTEDGE+WS_EX_APPWINDOW,addr ClassName,\
      addr TitleName,WS_OVERLAPPEDWINDOW,CW_USEDEFAULT,CW_USEDEFAULT,400,300,\
      NULL,NULL,hInst,NULL
   mov   hwnd,eax
   invoke ShowWindow,hwnd,CmdShow
   invoke UpdateWindow,hwnd
   .while TRUE
      invoke GetMessage, addr msg,NULL,0,0
      .BREAK .IF (!eax)
      invoke TranslateMessage,addr msg
      invoke DispatchMessage, addr msg
   .endw
   mov eax,msg.wParam
   ret
WinMain endp

WndProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
   .if uMsg==WM_DESTROY
      invoke PostQuitMessage,NULL
   .elseif uMsg==WM_CREATE 
      invoke CreateWindowEx,WS_EX_CLIENTEDGE, ADDR ComboBoxClassName,addr TitleName,\
         WS_VISIBLE  or WS_CHILD or WS_VSCROLL or  CBS_SIMPLE,20,40,100,100,hWnd,ID_COMBOBOX1,hInstance,NULL  
      mov hwndComboBox1,eax                 
      mov ecx,COMBOBOXNUM
      push esi
      lea esi,ComboBox1 
loopadd:
         push ecx 
         invoke SendMessage,hwndComboBox1,CB_ADDSTRING,NULL,esi
         add esi,sizeof LISTITEM
         pop ecx
      loop loopadd
      pop esi
      invoke SendMessage,hwndComboBox1,CB_SETCURSEL,0,0
      invoke CreateWindowEx,NULL, ADDR ButtonClassName,addr PushButtonText,\
                       WS_VISIBLE or WS_CHILD  or  BS_DEFPUSHBUTTON or BS_VCENTER, 120,190,80,20,hWnd,ID_BUTTON_PUSH,hInstance,NULL
      mov hwndButtonPush,eax             
   .elseif uMsg==WM_COMMAND
      mov eax,wParam
      .if lParam
         .if ax==ID_BUTTON_PUSH
            shr eax,16
            .if ax==BN_CLICKED
               invoke SendMessage,hwndComboBox1,CB_GETCURSEL,0,0
               invoke SendMessage,hwndComboBox1, CB_GETLBTEXT ,eax,addr Buffer
               invoke MessageBox,hWnd,addr Buffer,addr TitleName,MB_OK 
            .endif
         .endif 
      .endif
   .else
      invoke DefWindowProc,hWnd,uMsg,wParam,lParam
      ret
   .endif
   xor    eax,eax
   ret
WndProc endp
end start